formule avec si

M

Monique

Nous a quitté

Repose en paix

• 9 Août 2006

• #2

Re : formule avec si

Bonjour,

à essayer

=SI(SOMME(SI(ESTNUM(TROUVE("m";I$6:AL$6));(MOD(COLONNE(I$6:AL$6)-2;7)<2)*(SUBSTITUE(I$6:AL$6;"m";0)*1<=11)*(SUBSTITUE(I$6:AL$6;"m";0)*1>=1)));"oui";"non")

Formule matricielle, à valider par ctrl maj et entrée.

Edit
Tu enlèveras les espaces dans "COLONNE" et "SUBSTITUE"

 

Vote positif 0 Vote négatif

C

caline

XLDnaute Occasionnel

• 9 Août 2006

• #3

Re : formule avec si

Monique

bonsoir j'ai essayé mais cela ne fonctionne pas

merci a plus tard
car tes conseils m'ont déjà beaucoup aidés

 

Vote positif 0 Vote négatif

M

Monique

Nous a quitté

Repose en paix

• 9 Août 2006

• #4

Re : formule avec si

Re,

Tu peux joindre un petit bout de fichier, STP ?
Merci.

 

Vote positif 0 Vote négatif

C

caline

XLDnaute Occasionnel

• 9 Août 2006

• #5

Re : formule avec si

Monique , je pense que je vais utilisé le =(+(NB.SI($I9;"M*"))*1)+(+(NB.SI($J9;"M*"))*1)+(+(NB.SI($P9;"M*"))*1)+(+(NB.SI($Q9;"M*"))*1)+(+(NB.SI($W9;"M*"))*1)+(+(NB.SI($AD9;"M*"))*1)+(+(NB.SI($AK9;"M*"))*1)+(+(NB.SI($AL9;"M*"))*1)+(+(NB.SI($X9;"M*"))*1)+(+(NB.SI($AE9;"M*"))*1)


et ensuite j'adapterai

merci qu'en même
a plus

 

Vote positif 0 Vote négatif

M

Monique

Nous a quitté

Repose en paix

• 9 Août 2006

• #6

Re : formule avec si

Re,

Tu peux la raccourcir :
=NB.SI($I6;"M*")+NB.SI($J6;"M*")+NB.SI($P6;"M*")+NB.SI($Q6;"M*")+NB.SI($W6;"M*")+NB.SI($AD6;"M*")+NB.SI($AK6;"M*")+NB.SI($AL6;"M*")+NB.SI($X6;"M*")+NB.SI($AE6;"M*")

Celle-ci a le même résultat :
=SOMME(SI(ESTNUM(TROUVE("m";$I6:$AL6));(MOD(COLONNE($I6:$AL6)-2;7)<2)*(SUBSTITUE($I6:$AL6;"m";0)*1>0)))
(prend aussi en compte les m50 ou les m0,5 que tu n'as peut-être pas, d'ailleurs)
à valider par ctrl, maj et entrée

 

Vote positif 0 Vote négatif

M

Monique

Nous a quitté

Repose en paix

• 9 Août 2006

• #7

Re : formule avec si

Re,

Tout simplement (à valider seulement par "Entrée") :
=SOMMEPROD((MOD(COLONNE($I6:$AL6)-2;7)<2)*(ESTNUM(CHERCHE("m";$I6:$AL6))))
si on compte tous les "m", quel que soit le nombre qui suit le "m"

 

Vote positif 0 Vote négatif

C

caline

XLDnaute Occasionnel

• 10 Août 2006

• #8

Re : formule avec si

MERCI Monique
=SOMMEPROD((MOD(COLONNE($I6:$AL6)-2;7)<2)*(ESTNUM(CHERCHE("m";$I6:$AL6))))


pour mon info -2;7 cela signifie qu'elle prend en compte les 2 cell(i et J) et puis la 7 après ?

mais a quoi correcpond le <2


bien à toi

 

Vote positif 0 Vote négatif

M

Monique

Nous a quitté

Repose en paix

• 10 Août 2006

• #9

Re : formule avec si

Bonjour,

=MOD(COLONNE();7)
renvoie le reste de la division par 7 du n° de colonne
Mod(7;7) renvoie 0 - Mod(8;7) renvoie 1 - Etc jusqu'à Mod(13;7) qui renvoie 6 puis on repart à zéro

Tapée en colonne I (colonne 9), la formule COLONNE() renvoie 9
Tapée en colonne I (colonne 10), elle renvoie 10

Tapée en colonne I (colonne 9), la formule MOD(COLONNE();7) renvoie 2
Tapée en colonne J (colonne 10), elle renvoie 3

Pour raccourcir la formule, Colonne()-2 renvoie 7 et 8 en I et J
Mod(Colonne()-2;7) renvoie 0 et 1 en I et J
donc <2

D'où le MOD(COLONNE($I6:$AL6)-2;7)<2)
qui ne prend en compte que 2 colonnes sur 7

 

Vote positif 0 Vote négatif

C

caline

XLDnaute Occasionnel

• 10 Août 2006

• #10

Re : formule avec si

SUPER EXPLICATION

j'espère le retenir pour une prochaine utilisation sinon un coup de forum auprès de toi

ps ou avez-vous appris toutes ces "choses"

Caline

 

Vote positif 0 Vote négatif