Format personnalisée pour deux données

[Ilino]

Bonjour Forum

Je souhaite tapé dans la cellule des données suivantes CHIFFRE et DATE après validation il s’affiche dans la cellule CHIFFRE /ILINO/2014 DU DATE (format personnalisée)
EXEMPLE :
Si je saisie dans la cellule L5 le CHIFFRE 12 et la date 1/7/2014 j’aurai dans la cellule 12/ILINO/2014 DU 1/7/2014
GRAZIE

 

[job75]

Re : Format personnalisée pour deux données

Bonjour Ilino,

Ce n'est pas un format personnalisé mais cette macro :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim r As Range, s
Set r = Intersect(Target, [L5:L26]) 'plage à adapter
If Not r Is Nothing Then
  For Each r In r 'si plusieurs cellules (copier-coller)
    s = Split(Application.Trim(r.Text))
    If UBound(s) = 1 Then _
      If IsNumeric(s(0)) And IsDate(s(1)) Then _
        r = s(0) & "/ILINO/" & Year(s(1))
  Next
End If
End Sub

A+

 

[Misange]

Re : Format personnalisée pour deux données

Bonjour

Tu peux mettre un format personnalisé sur UNE donnée entrée dans une cellule
ou tu peux taper ton chiffre dans une cellule, ta date dans l'autre et concaténer les deux dans un troisième en ajoutant le texte que tu veux
mais un format perso ne peut pas faire ce que tu souhaites. La seule solution est par macro comme proposé par Job

 

[Ilino]

Re : Format personnalisée pour deux données

Bonjour Ilino,

Ce n'est pas un format personnalisé mais cette macro :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim r As Range, s
Set r = Intersect(Target, [L5:L26]) 'plage à adapter
If Not r Is Nothing Then
  For Each r In r 'si plusieurs cellules (copier-coller)
    s = Split(Application.Trim(r.Text))
    If UBound(s) = 1 Then _
      If IsNumeric(s(0)) And IsDate(s(1)) Then _
        r = s(0) & "/ILINO/" & Year(s(1))
  Next
End If
End Sub

A+

Bonjour JOB MISANGE
MERCI POUR LES REPONSES MAIS CA N'A PAS FONCTIONNE
QUAND JE SAISIE 12 ET 1/7/2014 J'AI 12/ILINO/2014 ???!!!

 

[job75]

Re : Format personnalisée pour deux données

Re,

Une variante qui affiche toujours 12 en tête, si l'on entre 012 12,6 12.6 ou 12a :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim r As Range, s, i%
Set r = Intersect(Target, [L5:L26]) 'plage à adapter
If Not r Is Nothing Then
  For Each r In r 'si plusieurs cellules (copier-coller)
    s = Split(Application.Trim(r.Text))
    If UBound(s) = 1 Then
      For i = 1 To Len(s(0))
        If Not IsNumeric(Mid(s(0), i, 1)) Then Exit For
      Next
      If i > 1 And IsDate(s(1)) Then _
        r = Val(Mid(s(0), 1, i - 1)) & "/ILINO/" & Year(s(1))
    End If
  Next
End If
End Sub

A+

 

[job75]

Re : Format personnalisée pour deux données

CA N'A PAS FONCTIONNE
QUAND JE SAISIE 12 ET 1/7/2014 J'AI 12/ILINO/2014 ???!!!

😕 tu bois trop de café Ilino 🙁

A+

 

[Ilino]

Re : Format personnalisée pour deux données

Re
Grazie job , mais le souci persiste encore
c a d si je saisie 10 et 5/07/2014 je souhaite dans la même cellule avoir
10/ilino/2014 du 5/07/2014
A+

 

[job75]

Re : Format personnalisée pour deux données

Re,

Ah oui j'ai relu le post #1, tu veux qu'on rajoute "DU 1/7/2014".

Pour la formule de r à la fin, ajoute & Format(s(1), " \DU d/m/yyyy")

A+

 

[job75]

Re : Format personnalisée pour deux données

Re,

Plus simplement tu remplaces Year(s(1)) par Format(s(1), "yyyy \DU d/m/yyyy")

A+

 

[Ilino]

Re : Format personnalisée pour deux données

Bonjour JOB
SUPER ..... PBLM RESOLU
GRAZIE