Format HEURE

[Paladyn]

Bonjour à tous,
J'ai une application externe (business Object) qui génère un fichier Excel dans lequel des temps sont notés. Je ne peux pas intervenir sur BO, je me retrouve donc sur le problème ci dessous ;

Si un temps est < 1 heure il apparaitra comme cela MM:SS
St ce temps est > 1 heure cela se précente HH:MM:SS
Les cellules sont en format standard.

Mon problème est que si je souhaite additionner ces temps, les minutes du premier temps sont identifées en heure..😡
Si je souhaite changer de format, idem, MM:SS se retrouve MM:SS:00

Help !, connaissez vous la fonction, le format qui va bien ?
Fichier exemple joint.

Par avance, Merci
Paladyn

 

[jmd2]

Re : Format HEURE

hello

mets toutes tes cellules en format heure 00:00:00 (y compris les cellules contenant des sommes,
et veille à ce que les saisies se fassent en tapant bien 2chiffres2points2chiffres2points2chiffres

*****

 

[tototiti2008]

Re : Format HEURE

Bonjour Paladyn,

Formule à mettre en D2 et à recopier vers le bas :

=SI(C2="";"";SI(NBCAR(C2)<=5;GAUCHE(C2;CHERCHE(":";C2)-1)/1440+DROITE(C2;NBCAR(C2)-CHERCHE(":";C2))/86400;GAUCHE(C2;CHERCHE(":";C2)-1)/24+STXT(C2;CHERCHE(":";C2;1)+1;2)/1440+DROITE(C2;NBCAR(C2)-CHERCHE(":";C2;3))/86400))

 

[job75]

Re : Format HEURE

Bonjour Paladyn, salut jmd2 et tototiti,

Entrez en D2 la formule :

=SI(ESTNUM(1*("0:"&C2));1*("0:"&C2);1*C2)

à tirer vers le bas.

Puis mettez la colonne D au format heure hh:mm:ss

A+

 

[tototiti2008]

Re : Format HEURE

Bonjour à tous,

Bien vu Job75, beaucoup plus simple que la mienne... 🙂

 

[job75]

Re : Format HEURE

Re,

Pour le fun, un tout petit peu plus simple :

=1*SI(ESTNUM(1*("0:"&C2));"0:"&C2;C2)

ou

=1*(REPT("0:";ESTNUM(1*("0:"&C2)))&C2)

A+

 

[Paladyn]

Re : Format HEURE

Chapeau bas mes amis,
Respect🙂

Quand une feuille excel peut rendre fou, j'ai failli tester cet adage surtout avec 5000 lignes.

Excel est un excellent outil, mais dans vos mains, c'est une oeuvre d'art.

Bravo et merci !
A++
Paladyn

 

[GIBI]

Re : Format HEURE

Bonsoir,

Une autre solution plus horaire

=TEMPSVAL(SI(NBCAR(C2)<=5;"00:"& C2;C2))

GIBI