fonctions si, et, ou imbriquées

[Baj]

bonjour,
Pourriez vous m'aider?
j'ai une colonne avec type de sol ( colonne BO): si il y a "bitumé", "stabilisé" ou "meuble" je veux qu'il me dise vrai ( mais dans le cas où il y a meuble, il faut que dans la colonne suivante (BP), il y ait écrit oui)pour qu'il me dise vrai

j'ai essayé ça mais ça ne marche pas : =SI(OU(BO2="Bitumé";BO2="Stabilisé";Vrai);si(ET(BO2="Meuble"; BP2=oui));VRAI)
qu'est ce qui est faux ?
ma colonne BP contient plein de cases vides , mais ça vient pas de ça ?
merci

 

[bolem]

Re : fonctions si, et, ou imbriquées

avec ca ca devrait marché si ce n'est pas trop tard
=SI(OU(BO2="Bitumé";BO2="Stabilisé");"vrai";SI(ET(BO2="Meuble";BP2="oui");"VRAI"))

 

[Dranreb]

Re : fonctions si, et, ou imbriquées

Pas besoin de si pour des combinaisons de conditions: elles vallent d'elles mêmes VRAI ou FAUX

=OU(BO2="Bitumé";BO2="Stabilisé";ET(BO2="Meuble";BP2="oui"))

À+

 

[hoerwind]

Re : fonctions si, et, ou imbriquées

Bonjour, salut bolem et Dranreb,

Pas besoin de répéter la référence de la cellule sous un OU
=OU(BO2="Bitumé";BO2="Stabilisé")
peut être remplacé par :
=OU(BO2={"Bitumé";"Stabilisé"})
les {} doivent être saisies au clavier (ce n'est pas une matricielle)

 

[Dranreb]

Re : fonctions si, et, ou imbriquées

Bonjour.
Savais pas...
...jamais découvert ça...
...m'en veux...
MERCI HOERWIND !
Mais où peut on trouver ça dans l'aide ?
La fonction inverse marche aussi: =ET(J39<>{"A";"B";"C"})
Cordialement.

 

[hoerwind]

Re : fonctions si, et, ou imbriquées

Re,

Heureux de t'avoir appris quelque chose !

Quant à savoir où on pourrait trouver cela dans l'aide, aucune idée (je n'ai pas cherché non plus !)
Je l'ai découvert par hasard, en testant, car j'employais déjà ces {} :

Sous la fonction CHOISIR()
A titre d'exemples :
=CHOISIR(EQUIV(A1;{"lundi";"mardi";"mercredi";"jeudi";"vendredi";"samedi";"dimanche"};0);1;2;3;4;5;6;7)
=CHOISIR(EQUIV(A1;{0;5;10;15});"très mauvais";"mauvais";"bon";"très bon")

Aussi sous le fonction RECHERCHEV :
A titre d'exemple :
=RECHERCHEV(A1;{0\"très mauvais";5\"mauvais";10\"bon";15\"très bon"};2)
dans laquelle chez moi le \ est le séparateur de colonnes et le ; le séparateur de lignes (dépend des options régionales)

 

[Baj]

Re : fonctions si, et, ou imbriquées

merci beaucoup à tous ! ça marche ! c'est un plaisir !
En revanche, j'ai une autre question:
Pourquoi cette formule ne fonctionne t elle pas ?

=ET(BT2="VRAI";CI2="Vrai";BR2>=15;BQ2="VRAI")

même quand les quatre conditions sont remplies, cela s'affiche faux quand même.

 

[hoerwind]

Re : fonctions si, et, ou imbriquées

Bonjour,

Essaie : =ET(BT2*1=1;CI2*1=1;BR2>=15;BQ2*1=1)

ou plus court :
=ET((BT2*1+CI2*1+BD2*1)=3;BR2>=15)

 

[Dranreb]

Re : fonctions si, et, ou imbriquées

baj,
"VRAI" est une constante texte qui est toujours différente d'une valeur booléenne. Voila pourquoi ça ne marche pas. Elle marcherait si vous tapiez une apostrophe dans les cellules devant VRAI ou FAUX ou après avoir mis un format Texte sur les cellules (si toutefois vous méprisiez à ce point les valeurs booléennes)
ET(BT2=VRAI;CI2=VRAI;BR2>=15;BQ2=VRAI) marcherait aussi mais, sauf pour la 3ème expression, ce seraient des pléonasmes booleens.
ET(BT2;CI2;BR2>=15;BQ2) serait correct.


À+

 

[hoerwind]

Re : fonctions si, et, ou imbriquées

Salut Dranreb,

Je me permets de ne pas partager ton avis.
Si BT2, CI2 et/ou BQ2 ne contiennent rien ou contiennent autre chose que FAUX, la formule renverra VRAI

Par contre si ces cellules ne peuvent contenir que VRAI ou FAUX, et ne jamais être vides, alors tu as raison.