Fonction SOMME.SI

[karsud]

Bonjour,

Voilà, j'aimerai savoir si on peut mettre plusieurs critères different dans la fonction SOMME.SI car visiblement on ne peut mettre qu'un critère.

Ma deuxième question est la suivante.

Lorsque que je mets, toujours dans la fonction SOMME.SI, une reference tel que 04-002 (une reference de stage)dans le critère ,excel me fait une addition automatiquement et donc me met 2 (il soustrait 4-2) alors que j'aimerai qu'il prenne en compte ma reference pour pouvoir additionner toutes les sommes liées à cette référence.

Je ne sais pas si j'ai été très clair mais je tiens à vous remercier d'avance pour toute l'aide que vous pourrez m'apporter.

 

[Monique]

Bonjour,

Du SommeProd
Somme.Si() (1 seul critère) transformé en SommeProd :
=SOMME.SI(A1:A20;E1;C1:C20)
=SOMMEPROD((A1:A20=E1)*C1:C20)

SommeProd avec 2 critères (tu peux aller jusqu'à 30) :
=SOMMEPROD((A1:A20=E1)*(B1:B20="A")*C1:C20)

Pour que Excel prenne ton 04-002, tu le fais précéder d'une apostrophe.
ou bien tu mets ta cellule au format texte.

 

[nicolas]

bonjour, j ai un probleme aussi avec une somme si a plusieurs critere:
j ai un tableau a 2 colone:

la colonne B (correspondant au types d entree ou de sortie d argent ds la caisse), sous forme d une liste de choix impose
" Homme","Femme","Vente","prelevement d espece","achat","depot"

la colonne C ( correspondant au montant des ces entrees ou sortie)

j aimerais a la fin du tableau, faire le calcul des entrees d argent sans prendre en compte les sorties
j ai essaye la formule suivante, mais le solde reste a 0

=SOMMEPROD((B7:B34="Homme")*(B7:B34="Femme")*(B7:B34="Vente")*C7:C34)

en traduisant ds mon language ,je voudrais:
faire la somme des cellule de la colonne C, seulement si les cellules correspondante de la collone B contiennent les entrees "Hommes, Femme ou Ventes"
merci pour votre aide

 

[Monique]

Bonjour,

Ecris ta formule comme ça :
=SOMMEPROD(((B7:B34="Homme")+(B7:B34="Femme")+(B7:B34="Vente"))*C7:C34)
(attention aux parenthèses qui entourent tes 3 conditions)

Le * équivaut à ET, le + équivaut à OU, le - à "Sauf"
Ta formule demandait à faire la somme de la colonne C si la colonne B contenait à la fois et "Homme" et "Femme" et "Vente".

 

[Monique]

Re,

Tu peux aussi l'écrire comme ça :
=SOMMEPROD((B7:B34={"Homme"."Femme"."Vente"})*C7:C34)

Ou bien tu mets tes 3 critères en D1, E1, F1 (ou ailleurs) :
=SOMMEPROD(((B7:B34=D1)+(B7:B34=E1)+(B7:B34=F1))*C7:C34)