Fonction Recherchev sur 2 cellules

[toune21]

Bonjour le forum,

Vous allez me dire "il y a déjà des posts sur ce sujet", j'ai recherché toute la matinée, j'ai trouvé des SI, ET, OU, IMBRIQUE.

Je souhaiterais faire RECHERCHEV sur 2 cellules.

A7 fait référence à « NOM »
A12 fait référence à « Absences »
résultat dans la Colonne H
=SI(ESTVIDE($A$7);" ";RECHERCHEV($A$7;Absences;3)), jusque là ça marche,
Il faut aussi faire référence à la cellule A12, pour rechercher le bon montant.

Pour faire coucou à JOB75, je joints la boule de cristal.🙂

Si quelqu'un peut m'aider merci d'avance.
Toune

 

[JNP]

Re : Fonction Recherchev sur 2 cellules

Bonjour Toune21 🙂,
En H12

=SI(ESTVIDE($A$7);"";SOMMEPROD((données!$D$26:$J$26=fichevierge!$A12)*(données!$B$28:$B$32=fichevierge!$A$7)*(données!$D$28:$J$32)))

à glisser vers le bas 😛...
Bon dimanche 😎

 

[poulie]

Re : Fonction Recherchev sur 2 cellules

Bonjour toune21, JNP, bonjour à tous,

Pas certain d'avoir tout compris.

En H12 : =SI(ESTVIDE($A$7);"";INDEX(données!$D$28:$J$37;EQUIV(fichevierge!$A$7;données!$B$28:$B$37;0);EQUIV(fichevierge!A12;données!$D$26:$J$26;0)))

En B12: =INDEX(données!$D$27:$J$27;EQUIV(fichevierge!A12;données!$D$26:$J$26;0))

Boonne réception

 

[toune21]

Re : Fonction Recherchev sur 2 cellules

Bonjour JNP et Poulie,
Merci à tous les deux.

JNP ta formule fonctionne parfaitement. 🙂

Poulie merci pour ta formule en B12 impec !!!
et la formule H12 fonctionne aussi.
Vous êtes des chefs. 🙂 🙂
Bon dimanche à vous aussi 😎 et 10 000 merci même plus encore
Toune

 

[toune21]

Re : Fonction Recherchev sur 2 cellules

Re bonsoir JNP et Poulie, et le forum
Le dessert est mangé, le café bu, un petit tour sur mon fichier.
Comme je l'ai dit plus haut les formules fonctionnent,

mais si la cellule A12 est vide j'ai une erreur #N/A, pour vos exemples à tous les deux
Une petite idée
Merci encore

JNP 🙂 il n'y a pas erreur #N/A, c'est SOMMEPROD
=SI(ESTVIDE($A$7);"";SOMMEPROD((données!$D$26:$J$26=fichevierge!$A12)*(données!$B$28:$B$32=fichevierge!$A$7)*(données!$D$28:$J$32)))
fichier joint
A++

 

[JNP]

Re : Fonction Recherchev sur 2 cellules

Re 🙂,

mais si la cellule A12 est vide j'ai une erreur #N/A, pour vos exemples à tous les deux
Une petite idée

Tu t'es pas trop créusé la tête non plus 😡...

=SI(OU(ESTVIDE($A$7);A12="");"";SOMMEPROD((données!$D$26:$J$26=fichevierge!$A12)*(données!$B$28:$B$32=fichevierge!$A$7)*(données!$D$28:$J$32)))

Bonne soirée 😎

 

[toune21]

Re : Fonction Recherchev sur 2 cellules

Re JNP,
J'ai pas pensé au OU
c'est le café et le pousse😛
Merci beaucoup
Toune