fonction recherchev en partant du bas

[pascal21]

bonjour à tous
je recherche une alternative à la fonction recherchev
celle ci donne la 1ere valeur trouvée en partant du haut de la liste
je souhaiterais en fait la meme fonction mais que ça me donne la dernière valeur cherchée
ex
en colonne A
j'ai plusieurs noms qui reviennent
en colonne B des valeurs

je vous mets un exemple car je ne vais pas y arriver
merci

 

[hoerwind]

Re : fonction recherchev en partant du bas

Bonjour,

A essayer en E2 :

=DECALER(B1;MAX(SI(A1:A22=D2;LIGNE(1:22)-1));)

formule matricielle à valider par Ctrl+Maj+Entrée

 

[pascal21]

Re : fonction recherchev en partant du bas

bonjour hoerwind
merci pour ta réponse
en fouillant j'ai trouvé ça (dans mon pc)

=INDEX(B$1:B$30;RECHERCHE(9^9;EQUIV(2;1/(D2=A$1:A$30))))

en fait j'avais déja posé la question et je ne m'en souvenait plus
désolé!!!

 

[hoerwind]

Re : fonction recherchev en partant du bas

Re,

et je ne m'en souvenais plus
Eh oui, c'est ainsi que ça commence !

Il me semble quand même que la formule que je viens de te proposer est quelque peu plus simple que celle que tu avais.

 

[job75]

Re : fonction recherchev en partant du bas

Bonjour Pascal, hoerwind,

Il me semble quand même que la formule que je viens de te proposer est quelque peu plus simple que celle que tu avais.

Place occupée en mémoire :

- formule du post #2 => 62 octets

- formule du post #3 => 50 octets...

Edit : c'est dû essentiellement à la fonction SI, gourmande en octets.

Cette formule "pèse" 52 octets :

=DECALER(B1;MAX((A1:A22=D2)*(LIGNE(1:22)-1));)

A+

 

[hoerwind]

Re : fonction recherchev en partant du bas

Salut job75,

Merci pour ton commentaire, toujours heureux d'apprendre comment supprimer un SI !

Mais par "simple" je n'entendais pas son poids, bien "simple à comprendre"

 

[ericquad]

Bonjour
j'ai réussi à adapter votre fonction a mon tableau en modifiant les ref de cellules
ça marche trés bien un grand merci

mai je ne comprend pas à quoi sert "9^9" dans la formule
et de quelle façon vous obliger excel à faire la recherche en remontant et non en descendant
dans INDEX(B$1:B$30;RECHERCHE(9^9;EQUIV(2;1/(D2=A$1:A$30))))
merci
Eric

 

[job75]

Bonjour ericquad,

C'est un peu compliqué à expliquer.

On peut remplacer la formule de pascal21 par cette formule matricielle :

=INDEX(B$1:B$30;EQUIV(2;1/(D2=A$1:A$30)))

Dans EQUIV le 3ème argument est omis, EQUIV renvoie donc la position du dernier 1
de la matrice 1/(D2=A$1:A$30), soit 19.

La fonction RECHERCHE permet d'éviter la validation matricielle.

Son 1er argument doit être >= au numéro de ligne renvoyé par EQUIV.

Au lieu de 9^9 on pourrait mettre 1048576, nombre de lignes maximum d'une feuille Excel.

Mais 9^9 est plus simple et "pèse" 2 octets de moins.

A+

 

[job75]

Re,

En fait puisque le seul but de RECHERCHE est d'éviter la validation matricielle il y a plus simple :

=INDEX(B$1:B$30;SOMMEPROD(EQUIV(2;1/(D2=A$1:A$30))))

qui pèse 43 octets, soit 7 octets de moins que la formule de pascal21 au post #3.

A+

 

[ericquad]

Bonjour Job75
J'avais soupssoné une explication dans ce genre
mais ne serais pas capable de la mettre en oeuvre
grande invention que le "copier collé"
tes explication me permettent d'avancer un peut
je vais essayer de mettre en place la formule avec somme prod que je maitrise mieux
et que je trouve moins empirique
merci
Eric