Fonction MOD

[Yvjo1025]

Bonjour à vous,
J'ai un problème (qui vous est peut-être connu) avec la fonction =MOD
J'ai vu sur le forum qu'il y a pas mal de choses sur le sujet mais je n'ai pas trouvé mon bonheur
Je désire additionner un nombre à 2 chiffres pour le réduire à un chiffre
18 devient 1+8 = 9
La fonction =MOD(18;9) joue pour tous les chiffres sauf pour ceux qui, comme mon exemple, devrait donner 9, il affiche 0 à la place.
Merci d'éclairer ma lanterne...

 

[R@chid]

Re : Fonction MOD

Bonjour @ tous,
Salut @ tous les amis que je voie qu'ils ont peut-être compris la demande... 🙂
Alors moi j'attends encore plus d'explications et si c'est possible les résultats souhaités 😕
@ + +

 

[Staple1600]

Re : Fonction MOD

Re

ROGER2327
J'ai bien compris cela.
mais je trouve étonnant que sur le site support de Microsoft, il ne propose pas une formule de ce type mais une formule matricielle. (voir lien ajouté dans l'édition de mon précédent message)

NB: Tu me diras qu'il est aussi étonnant que j'ai sorti l'artillerie lourde alors que c'est si simple avec MOD.

EDITION:Bonjour R@chid

 

[Staple1600]

Re : Fonction MOD

Re

Bonjour @ tous,
Salut @ tous les amis que je voie qu'ils ont peut-être compris la demande... 🙂
Alors moi j'attends encore plus d'explications et si c'est possible les résultats souhaités 😕
@ + +

Voici pour toi R@chid 😉

RACINE THÉOSOPHIQUE – Définition
La réduction théosophique ou racine essentielle est un nom complexe
pour une opération somme toute des plus simples.
Il s'agit de faire la somme des chiffres du nombre.
De recommencer, si nécessaire, avec le résultat.
Jusqu'à obtenir un seul chiffre.

123 => 1 + 2 + 3 = 6
La racine théosophique de 123 est 6.

456 => 4 + 5 + 6 = 15 => 1 + 5 = 6
La racine théosophique de 456 est 6.

'source: Gérard Villemin

 

[R@chid]

Re : Fonction MOD

Bonjour @ tous,
Avec,

=MOD(SOMMEPROD(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)*1);9)

@ + +

Edit : C'est une connerie ==> LaFormuleProposée=MOD(A2;9) 😉

 

[Staple1600]

Re : Fonction MOD

Re

Une petite récap (qui laisse apparaitre que j'avais mal lu ce que fait Microsoft 😉 )

(R@chid, après la plus courte, le nouveau jeu c'est de chercher la plus longue ? 😉 )



PS: si jamais des xldnautes sous Firefox passent dans ce fil, peuvent-ils me dirent comment ils font pour pour modifier la taille des images jointes dans les messages.
Je ne vois plus apparaitre le pinceau sur ce PC avec Firefox (version 22.O)

 

[JHA]

Re : Fonction MOD

Bonjour à tous,

Si j'ai bien compris la demande:
"Je désire additionner un nombre à 2 chiffres pour le réduire à un chiffre
18 devient 1+8 = 9
La fonction =MOD(18;9) joue pour tous les chiffres sauf pour ceux qui, comme mon exemple, devrait donner 9, il affiche 0 à la place."
si le nombre a toujours 2 chiffres et avec la solution de R@chid (que je salue🙂)

=SOMMEPROD(STXT(SOMMEPROD(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)*1);LIGNE(INDIRECT("1:"&NBCAR(SOMMEPROD(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)*1))));1)*1)

JHA

 

[chris]

Re : Fonction MOD

Bonjour

...

PS: si jamais des xldnautes sous Firefox passent dans ce fil, peuvent-ils me dirent comment ils font pour pour modifier la taille des images jointes dans les messages.
Je ne vois plus apparaitre le pinceau sur ce PC avec Firefox (version 22.O)

D'après une explication de Brigitte, j'édite le message posté, je double clique sur l'image et choisis la taille.

 

[JHA]

Re : Fonction MOD

Re,

A essayer

=ARRONDI.SUP(MOD(A2;9,001);0)

JHA

 

[Yvjo1025]

Re : Fonction MOD

Merci à vous tous pour la rapidité de vos réponses et les différentes solutions
Je vois que j'ai tout intérêt à repotasser un peu mes formules Excel...

@Eric
J'ai lu ton explication sur la fonction MOD et je n'ai pas remarqué ta solution qui fonctionne

@Roger2327
ça fonctionne aussi très bien

@staple1600
Merci pour la formule raccourcie en VBA...
Comme déjà dit, je n'y comprends rien, mais avec tes explications je vais tenter de l'appliquer

Merci

 

[R@chid]

Re : Fonction MOD

Bonjour @ tous,
Oui Staple,
je viens de faire attention à,

La fonction =MOD(18;9) joue pour tous les chiffres sauf pour ceux qui, comme mon exemple, devrait donner 9, il affiche 0 à la place.

@ + +

 

[ROGER2327]

Re : Fonction MOD

Bonjour à tous.

Allons enfants de la Patrie, pourquoi faire simple si on peut faire compliqué ?​

=SOMME(--STXT(SOMME(--STXT(SOMME(--STXT(SOMME(--STXT(A2;COLONNE(DECALER($A:$A;;;1;NBCAR(A2)));1));COLONNE(DECALER($A:$A;;;1;NBCAR(SOMME(--STXT(A2;COLONNE(DECALER($A:$A;;;1;NBCAR(A2)));1)))));1));COLONNE(DECALER($A:$A;;;1;NBCAR(SOMME(--STXT(SOMME(--STXT(A2;COLONNE(DECALER($A:$A;;;1;NBCAR(A2)));1));COLONNE(DECALER($A:$A;;;1;NBCAR(SOMME(--STXT(A2;COLONNE(DECALER($A:$A;;;1;NBCAR(A2)));1)))));1)))));1));COLONNE(DECALER($A:$A;;;1;NBCAR(SOMME(--STXT(SOMME(--STXT(SOMME(--STXT(A2;COLONNE(DECALER($A:$A;;;1;NBCAR(A2)));1));COLONNE(DECALER($A:$A;;;1;NBCAR(SOMME(--STXT(A2;COLONNE(DECALER($A:$A;;;1;NBCAR(A2)));1)))));1));COLONNE(DECALER($A:$A;;;1;NBCAR(SOMME(--STXT(SOMME(--STXT(A2;COLONNE(DECALER($A:$A;;;1;NBCAR(A2)));1));COLONNE(DECALER($A:$A;;;1;NBCAR(SOMME(--STXT(A2;COLONNE(DECALER($A:$A;;;1;NBCAR(A2)));1)))));1)))));1)))));1))

Cette formule, matricielle, bien sûr, renvoie 9 pour ce nombre à mille cinquante chiffres :

166380259611756018835830326357901277412647138747288119815142706378373468134945258648723862371279195827930196137210359048978005660199801901659268750058594450996345342984687456919631398211680279130418522099684910255436467618395497016120736651568601291313818212371536754656922633560283964945592588279395933449335320262548792552176537431443567823964060878536371829591765911485119654315099621055123386740638152711038364927678982696031542242946587658034419606138425346045910838138776054879879737013920241553961992094807093103977955633562232884329679125954313016654642279036484645352499949859154919665358396349726690364239757128904116248675999412716010541474449509869763035916022375495695373016863322562738981871602475434944651191971293572378268013272785277304639377744547559149594063969592234546851269436792437175868409930557699843518873696159088949295177489271129082907238991743374384673838428735297198142292569904194288194092190713827769970756256489617478040752610890004964073550892106516106434247295272323587055029244329102607901790611376787523428805019
en A2.

À vérifier...​

ROGER2327
#6687

Dimanche 1[SUP]er[/SUP] Tatane 140 (Fête du Père Ubu (Ubu d’été) - fête Suprême Première seconde)
26 Messidor An CCXXI, 0,8094h - sauge
2013-W28-7T01:56:33Z

 

[exene]

Re : Fonction MOD

Bonjour,

A essayer une formule de Phibou

=MOD(A2;9)+9*(MOD(A2;9)=0)

Mais ne fonctionne que sur un nombre jusqu'à 9 chiffres

@+

 

[eriiic]

Re : Fonction MOD

Bonjour à tous,

@Roger2327

À vérifier...

Tu pourrais la faire compatible excel 2003 stp ? ;-)

eric

 

[R@chid]

Re : Fonction MOD

Bonjour @ tous,

=MOD(SOMMEPROD(CNUM(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)))-1;9)+1

@ + +

 

[ROGER2327]

Re : Fonction MOD

Re...

Bonjour à tous,

@Roger2327

Tu pourrais la faire compatible excel 2003 stp ? ;-)

eric

Non, (trop de parenthèses emboîtées), mais VBA est notre ami.​

Fonction récursive :​

Function RTH_1(x)
    If Left$(x, 1) = "-" Then x = Right$(x, Len(x) - 1)
    t = ""
    For i = 1 To Len(x): t = Val(t) + CLng(Mid$(x, i, 1)): Next
    If Len(t) > 1 Then t = RTH_1(t)
    RTH_1 = t
End Function

Plus classiquement :​

Function RTH_2(x)
    If Left$(x, 1) = "-" Then x = Right$(x, Len(x) - 1)
    t = ""
    For i = 1 To Len(x)
        t = Val(t) + CLng(Mid$(x, i, 1))
        t = t + 9 * (t > 9)
    Next
    RTH_2 = t
End Function

On remarquera que ces fonctions n'utilisent fondamentalement que l'addition.​

Bonne journée.


ROGER2327
#6688

Dimanche 1[SUP]er[/SUP] Tatane 140 (Fête du Père Ubu (Ubu d’été) - fête Suprême Première seconde)
26 Messidor An CCXXI, 4,1732h - sauge
2013-W28-7T10:00:56Z