Fonction Joursem dans une Fonction SommeProd

[mp45]

Bonjour,

J'ai actuellement un petit problème. Je cherche à savoir combien un personne a fait d'analyse pour chaque jour de la semaine. J'utilise donc une formule qui a cet aspect là

=SOMMEPROD((($A$1:$A$153)="TEAM A")*(($B$1:$B$153)=G$2)*(JOURSEM($C$1:$C$153)=$F3))

Or, étant donné que j'ai dans la BDD la date sous forme de date (comme son nom l'indique^^) je suis obligé d'utiliser la fonction Joursem pour récuperer le jour de la semaine. Le problème est que dans la plage C$1:$C$153, je n'ai pas que des dates, et donc lorsque Excel tente d'évaluer Joursem(C3) (par exemple), il me revoie #VALEUR!, et le résultat final est donc aussi #VALEUR!

J'ai donc modifié ma formule en

=SOMMEPROD((($A$1:$A$153)="TEAM A")*(($B$1:$B$153)=H$2)*(SI(ESTERR(JOURSEM($C$1:$C$153)=$G3);10;SI(JOURSEM($C$1:$C$153)=$G3;1;0))))

Pour essayer de gerer l'erreur, mais comme vous pouvez le voir dans le fichier excel, ça ne donne pas totalement le résultat excompté...

Merci d'avance, tout aide sera la bienvenue.

Bonne journée.

Mp45

 

[R@chid]

Re : Fonction Joursem dans une Fonction SommeProd

Bonjour,
Si j'ai bien compris, en H3,

=SOMME(SI(ESTNUM($C$1:$C$153);($A$1:$A$153="TEAM A")*($B$1:$B$153=H$2)*(JOURSEM($C$1:$C$153;2)=LIGNES($3:3))))

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas et vers la droite

@ + +

 

[job75]

Re : Fonction Joursem dans une Fonction SommeProd

Bonjour mp45,

Votre fichier en retour avec cette formule en H3 :

=SOMMEPROD((($A$1:$A$153)="TEAM A")*(($B$1:$B$153)=H$2)*ESTNUM(LN((JOURSEM($C$1:$C$153)=$G3))))

Rappel :

LN(VRAI) = LN(1) = 0

LN(FAUX) = LN(0) = #NOMBRE!

A+

 

[R@chid]

Re : Fonction Joursem dans une Fonction SommeProd

Re,
Salut Job75, ça fait longtemps que l'on ne s'est pas croisé au détour d'un fil.
Tu m'as eu avec LN() 🙂


@ + +

 

[job75]

Re : Fonction Joursem dans une Fonction SommeProd

Re,

Edit : je corrige avec JOURSEM(xxx;2).

Les cellules vides en colonne C rendaient faux les résultats du samedi car JOURSEM(0;2) = 6.

Il suffit d'ajouter ""& devant $C$1:$C$153 :

=SOMMEPROD((($A$1:$A$153)="TEAM A")*(($B$1:$B$153)=H$2)*ESTNUM(LN((JOURSEM(""&$C$1:$C$153;2)=$G3))))

Fichier (2).

Edit : hello R@chid, heureux de te croiser 🙂

A+

 

[job75]

Re : Fonction Joursem dans une Fonction SommeProd

Re,

Ah mp45 vous m'avez induit en erreur avec votre formule !!

Bien sûr c'est JOURSEM(""&$C$1:$C$153;2) qu'il faut utiliser.

Je corrige mon post #5.

A+

 

[JCGL]

Re : Fonction Joursem dans une Fonction SommeProd

Bonjour à tous,
Salut Rachid,
Salut Gérard,

Avec un TCD qui donne le mêmes résultats que la formule de l'ami Job.

A+ à tous

 

[job75]

Re : Fonction Joursem dans une Fonction SommeProd

Bonsoir Jean-Claude,

Ok pour le TCD sauf que tes jours sont décalés...

Tu t'es planté, la formule en D2 doit être =SI(C2="";"";TEXTE(C2;"jjjj"))

Bonne fin de soirée et A+