Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

XL 2010 Fonction Find is nothing

I

Izbeul

XLDnaute Nouveau
Bonjour,

J'avoue ne pas comprendre. J'ai lu sur pleins de forums (dont celui-ci) mais en vain.
J'ai une fonction Find dans mon code qui me renvoie toujours "nothing" et du coup, plus rien ne va dans la suite.

Le fait est que je lui demande de trouver deux dates prises dans la feuille "Stabilité_Pilote", dans la feuille "Sauvegarde_DCS" colonne A. J'ai appliqué le même format date aux deux dates et à toute la colonne A. J'ai déclaré mes range avec des Set. Bref j'ai fait "la totale" à mon niveau. Mais toujours ce "nothing".

So, please! help me! SOS

VB: 
Sub Suivi_Tests()


Dim DateFinPer As Date
Dim DateDebutPer As Date
Dim rngDate1 As Range, rngDate2 As Range

Dim wf As WorksheetFunction
Set wf = Application.WorksheetFunction


Application.Worksheets("Stabilité_Pilote").Select
DateFinPer = Sheets("Stabilité_Pilote").Range("H5")
DateDebutPer = Sheets("Stabilité_Pilote").Range("H4")

    If DateDebutPer > DateFinPer Then
        MsgBox "La date de début de période doit être antérieure à celle de fin de période"
        GoTo derniereligne

    End If

Application.Worksheets("Sauvegarde_DCS").Select

    With Worksheets("Sauvegarde_DCS").Range("A3:A40000")

   Set rngDate1 = Sheets("Sauvegarde_DCS").Range("A3:A40000").Find(DateDebutPer)
   Set rngDate2 = Sheets("Sauvegarde_DCS").Range("A3:A40000").Find(DateFinPer)
  
   If rngDate1 Is Nothing And rngDate2 Is Nothing Then
        MsgBox "Aucune donnée correspondante aux dates spécifiées n'a été extraite"
   Exit Sub

   Else:
  
        If rngDate1 Is Nothing Then
            MsgBox "Les données correspondantes à la date de début spécifiée n'ont pas été extraites"
        Exit Sub
  
   Else:
        If rngDate2 Is Nothing Then
            MsgBox "Les données correspondantes à la date de fin spécifiée n'ont pas été extraites"
        Exit Sub
        
   Else:
        
        End If
    End If
End If

End With
 
Solution
Bonjour Izbeul, fanch55,

Utiliser la méthode Find ici ne va pas, il faut une autre méthode.

Par exemple le filtre automatique :
VB: 
Sub Rechercher()
Dim deb, fin
With Sheets("Stabilité_Pilote")
    deb = .[H4]
    fin = .[H5]
End With
If Not IsDate(deb) Or Not IsDate(fin) Or deb > fin Then MsgBox "Les dates en H4 et H5 sont à revoir !", 48: Exit Sub
With Sheets("Sauvegarde_DCS")
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
    .UsedRange.Columns(1).AutoFilter 1, Criteria1:=">=" & CLng(deb), Operator:=xlAnd, Criteria2:="<=" & CLng(fin)
    .Activate 'facultatif
End With
End Sub

Sub RAZ()
With ActiveSheet
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
End With
End Sub
Je joins un fichier...
Trier par date Trier par votes

fanch55

XLDnaute Barbatruc
Bonjour testez ce code :
VB: 
Sub Suivi_Tests()

Dim DateFinPer As Date
Dim DateDebutPer As Date
Dim rngDate1 As Range, rngDate2 As Range

    DateFinPer = CDate(Sheets("Stabilité_Pilote").[H5])
    DateDebutPer = CDate(Sheets("Stabilité_Pilote").[H4])

    If DateDebutPer > DateFinPer Then
        MsgBox "La date de début de période doit être antérieure à celle de fin de période"
    Else
        With Worksheets("Sauvegarde_DCS").Range("A3:A40000")
          .Parent.Activate
          
          Set rngDate1 = .Find(DateDebutPer, After:=.Cells(1), SearchOrder:=xlByRows)
          Set rngDate2 = .Find(DateFinPer, After:=.Cells(1), SearchOrder:=xlByRows)
          
          Select Case True
          Case rngDate1 Is Nothing And rngDate2 Is Nothing
              MsgBox "Aucune donnée correspondante aux dates spécifiées n'a été extraite"
          Case rngDate1 Is Nothing
              MsgBox "Les données correspondantes à la date de début spécifiée n'ont pas été extraites"
          Case rngDate2 Is Nothing
              MsgBox "Les données correspondantes à la date de fin spécifiée n'ont pas été extraites"
          Case Else
             MsgBox "Plage trouvée:" & Range(rngDate1, rngDate2).Address
          End Select
          
        End With
    End If
        
End Sub
 
Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc
Bonjour Izbeul, fanch55,

Utiliser la méthode Find ici ne va pas, il faut une autre méthode.

Par exemple le filtre automatique :
VB: 
Sub Rechercher()
Dim deb, fin
With Sheets("Stabilité_Pilote")
    deb = .[H4]
    fin = .[H5]
End With
If Not IsDate(deb) Or Not IsDate(fin) Or deb > fin Then MsgBox "Les dates en H4 et H5 sont à revoir !", 48: Exit Sub
With Sheets("Sauvegarde_DCS")
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
    .UsedRange.Columns(1).AutoFilter 1, Criteria1:=">=" & CLng(deb), Operator:=xlAnd, Criteria2:="<=" & CLng(fin)
    .Activate 'facultatif
End With
End Sub

Sub RAZ()
With ActiveSheet
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
End With
End Sub
Je joins un fichier exemple, ce qui aurait dû être fait dès le post #1.

A+
 

Pièces jointes

  • Rechercher dates(1).xlsm
    20.9 KB · Affichages: 7
Vote positif 0 Vote négatif
Solution

fanch55

XLDnaute Barbatruc
Re,
Bonjour Job75,
Ne sachant pas la configuration de la feuille Sauvegarde_DCS ( nombre de tables, colonnes utilisées ) ni la finalité de l'Extraction probable , je n'ai pas voulu utiliser de filtres.
J'ai été dans la démarche demandée : résoudre les finds .
Mais effectivement, ta proposition est la meilleure dans l'hypothèse d'une feuille=une table
Le fichier joint illustre cela :
 

Pièces jointes

  • Izbeul.xlsm
    21.6 KB · Affichages: 3
Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc
Il ne sert à rien de rechercher la date de début et la date de fin.

Ce qu'il faut rechercher ce sont les dates situées entre ces 2 dates.

Il existe plusieurs méthodes, la plus simple est d'utiliser une MFC, sans VBA, fichier joint.
 

Pièces jointes

  • MFC dates(1).xlsx
    11.6 KB · Affichages: 2
Vote positif 0 Vote négatif
I

Izbeul

XLDnaute Nouveau
Bonjour,

je tiens à vous remercier infiniment pour vos retours. J'ai pu tester chacune de vos réponses, elles marchent à la perfections!

En effet, Job75, c'est juste la position des dates que je cherche. J'ai même découvert la fonction range.row qui permet de savoir le numéro de ligne concernée par une variable dans un range. Cette méthode marche aussi.

Vraiment un grand merci. Je rentre ce soir soulagée



Izbeul
 
Vote positif 0 Vote négatif
Identifiez-vous ou inscrivez-vous pour participer.

Discussions similaires

F
  • Question
Microsoft 365 aide VBA excel
Réponses
4
Affichages
302
Oneida
E
  • Résolu(e)
XL 2019 chercher une date dans une colonne vba
Réponses
12
Affichages
474
sylvanu
N
  • Résolu(e)
XL 2021 comment faire recherche dans une colonne et ligne
Réponses
5
Affichages
376
job75
E
  • Résolu(e)
Microsoft 365 Copier Coller selon condition
Réponses
5
Affichages
223
TooFatBoy
  • Résolu(e)
XL 2016 If Not xRgSel Is Nothing Then --> Ne marche pas
Réponses
10
Affichages
421
R3n0W
J
  • Question
Microsoft 365 Probléme VBA
Réponses
5
Affichages
100
jalaba
J
A
  • Question
insertion d'une ligne automatique dans un tableau excel.
Réponses
1
Affichages
280
sylvanu
  • Question
Microsoft 365 Trouver et attribuer une plage de cellule en fonction de la cellule active
Réponses
6
Affichages
401
Jojo973
  • Résolu(e)
XL 2019 Sélection zone avec la souris et copier puis Sélection zone avec la souris et coller
Réponses
9
Affichages
518
Sellig
G
  • Question
XL 2016 Extraire des données d'un pdf et les copier dans excel
2
Réponses
17
Affichages
821
gali2
G
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…