Filtre élaboré "contient" sur colonne nommée

sandra95 · 26 Février 2017

Bonjour,

J'ai besoin d'aide pour arranger mon filtre élaboré réalisé en VBA.
Je lance un userform forme.
Ma combobox1 me permet de choisir la colonne a filtrer (retranscrite en cellule G2):
Sheets("BASE CLIENTSV2").Range("G2").Value = ComboBox1
Mon textbox1 me permet de choisir ce que je cherche dans la colonne en question (retranscrit en cellule G3).
Sheets("BASE CLIENTSV2").Range("G3").Value = TextBox1

Le résultat de mon filtre fonctionne selon les critères choisis mais uniquement interprété en "est égal" ou "commence par".
Je cherche à lancer ce même filtre en "contient".
Pouvez-vous m'aider?
Je vous transmets le fichier pour comprendre.

Merci d'avance.

chris · 27 Février 2017

Bonjour

Utilise
Sheets("BASE CLIENTSV2").Range("G3").Value = "*" & TextBox1 & "*"

job75 · 27 Février 2017

Bonjour sandra95, chris, le forum,

Il n'y a vraiment pas besoin d'UserForm :

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [H1,J1]) Is Nothing Then Exit Sub
Application.ScreenUpdating = False
If Me.FilterMode Then Me.ShowAllData 'RAZ
If [H1] = "" Or [J1] = "" Then Exit Sub
With [A1].CurrentRegion 'à adapter éventuellement
  [K2] = "=SEARCH(J$1," & .Rows(1).Find([H1], , xlValues, xlWhole)(2).Address(0, 0) & ")"
  .AdvancedFilter xlFilterInPlace, [K1:K2]
End With
[K2] = ""
End Sub

Fichier joint.

Mais apparemment les réponses qu'on vous donne sur XLD ne vous intéressent guère :

https://www.excel-downloads.com/thr...une-cellule-contenant-deja-une-donnee.232575/

Bonne journée.

job75 · 27 Février 2017

Re,

On peut filtrer une colonne de dates en utilisant cette fonction personnalisée :

Code:

Function TXT$(c As Range, form$)
TXT = Format(c, form)
End Function

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [I1,K1]) Is Nothing Then Exit Sub
Application.ScreenUpdating = False
If Me.FilterMode Then Me.ShowAllData 'RAZ
If [I1] = "" Or [K1] = "" Then Exit Sub
With [A1].CurrentRegion 'à adapter éventuellement
  With .Rows(1).Find([I1], , xlValues, xlWhole)(2)
    [L2] = "=SEARCH(K$1,TXT(" & .Address(0, 0) & ",""" & .NumberFormat & """))"
  End With
  .AdvancedFilter xlFilterInPlace, [L1:L2]
End With
[L2] = ""
End Sub

Les colonnes de nombres doivent être formatées : ID au format "0", CP au format "00000".

Fichier (2).

A+

sandra95 · 27 Février 2017

Bonjour Chris, Bonjour Job75,

Merci pour vos réponses (qui m'interessent énormément Job75!!)
Je tenterai les propositions ce soir, en rentrant du travail, et ne manquerai pas de vous dire si ça fonctionne.

Bonne journée à vous.

sandra95 · 27 Février 2017

j'ai craqué... j'ai regardé quand même vite fait...
Merci Chris, ça marche impec!!
Merci Job75 pour les formats, ça va m'aider pour continuer

job75 · 27 Février 2017

Re,

sandra95 à dit:
j'ai craqué... j'ai regardé quand même vite fait...
Merci Chris, ça marche impec!!

Oui vite fait... Vous n'avez pas testé les colonnes ID et CP...

A+

sandra95 · 27 Février 2017

job75 à dit:
Re,

Oui vite fait... Vous n'avez pas testé les colonnes ID et CP...

A+

si si... j'ai vu que ça n'allait pas... je vais m'aider de vos formats pour ces colonnes justement!

sandra95 · 27 Février 2017

Bonsoir,

J'ai un peu remanié mon fichier avec une sélection multicritères.
textbox1=*Nom*
textbox2=*rue*
textbox3=code postal
textbox4=*ville*

Job75, je n'arrive pas à comprendre et à réintégrer, dans mon Userform, tes conseils concernant le format (un userform m'est indispensable pour le projet final).
Dans mes critères actuels, il ne me reste plus qu'à pouvoir avoir , au niveau du code postal (texbox3), la possibilité d'indiquer soit le code postal entier, soit le département (donc les 2 premiers chiffres).

Merci de votre aide.

job75 · 28 Février 2017

Bonjour sandra95, le forum,

Mon code précédent utilise le critère "contient".

Si l'on veut utiliser le critère "commence par" faire suivre le texte en K1 d'un astérisque :

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [I1,K1]) Is Nothing Then Exit Sub
Application.ScreenUpdating = False
If Me.FilterMode Then Me.ShowAllData 'RAZ
If [I1] = "" Or [K1] = "" Then Exit Sub
With [A1].CurrentRegion 'à adapter éventuellement
  With .Rows(1).Find([I1], , xlValues, xlWhole)(2)
    If Right([K1], 1) = "*" Then
      [L2] = "=K$1=LEFT(TXT(" & .Address(0, 0) & ",""" & .NumberFormat & """),LEN(K$1)-1)&""*"""
    Else
      [L2] = "=SEARCH(K$1,TXT(" & .Address(0, 0) & ",""" & .NumberFormat & """))"
    End If
  End With
  .AdvancedFilter xlFilterInPlace, [L1:L2]
End With
[L2] = ""
End Sub

La cellule K1 est bien sûr au format Texte.

Fichier (3).

Bonne journée.

job75 · 28 Février 2017

Re,

Pendant qu'on y est introduisons le critère "égal à" :

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [I1,K1]) Is Nothing Then Exit Sub
Application.ScreenUpdating = False
If Me.FilterMode Then Me.ShowAllData 'RAZ
If [I1] = "" Or [K1] = "" Then Exit Sub
With [A1].CurrentRegion 'à adapter éventuellement
  With .Rows(1).Find([I1], , xlValues, xlWhole)(2)
    If Right([K1], 1) = "=" Then
      [L2] = "=K$1=TXT(" & .Address(0, 0) & ",""" & .NumberFormat & """)&""="""
    ElseIf Right([K1], 1) = "*" Then
      [L2] = "=K$1=LEFT(TXT(" & .Address(0, 0) & ",""" & .NumberFormat & """),LEN(K$1)-1)&""*"""
    Else
      [L2] = "=SEARCH(K$1,TXT(" & .Address(0, 0) & ",""" & .NumberFormat & """))"
    End If
  End With
  .AdvancedFilter xlFilterInPlace, [L1:L2]
End With
[L2] = ""
End Sub

Edit : j'ai modifié la fonction TXT, la colonne ID peut maintenant être au format "Standard" :

Code:

Function TXT$(c As Range, form$)
If form = "General" Then TXT = c Else TXT = Format(c, form)
End Function

Fichier (4).

A+

sandra95 · 28 Février 2017

Bonjour,

Je suis désolée job75, je ne comprends pas... 🙁
Je ne suis pas une super crack en langage macro...
Pouvez vous me traduire vos lignes pour que je puisse retranscrire dans mon fichier.
Le problème actuel, dans mon fichier est la recherche par département d'après la colonne code postal.
Merci d'avance

job75 · 28 Février 2017

Re,

J'ai pourtant été clair : pour faire une recherche par département entrer "CP" en I1 et en K1 entrer les 2 chiffres suivis d'un astérisque.

Relisez tous mes posts et les explications dans les fichiers, il faut que vous les compreniez tous.

A+

job75 · 28 Février 2017

Re,

Concernant votre UserForm je m'y intéresserai quand vous nous aurez montré ce qu'il peut faire d'utile.

Pour l'instant, sur vos exemples, il ne peut servir qu'à filtrer et comme je l'ai dit il n'a alors aucun intérêt.

Je crains que vous ne fassiez comme les toutous : quand ils ont un os à ronger, pas moyen de leur retirer.

Bonne fin de soirée.

sandra95 · 28 Février 2017

Ok bonne soirée également.
Bien cordialement.

Filtre élaboré "contient" sur colonne nommée

sandra95

XLDnaute Nouveau

Pièces jointes

chris

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

sandra95

XLDnaute Nouveau

sandra95

XLDnaute Nouveau

job75

XLDnaute Barbatruc

sandra95

XLDnaute Nouveau

sandra95

XLDnaute Nouveau

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

sandra95

XLDnaute Nouveau

job75

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

sandra95

XLDnaute Nouveau

Discussions similaires

Filtre élaboré "contient" sur colonne nommée

XLDnaute Nouveau

Pièces jointes

XLDnaute Barbatruc

XLDnaute Barbatruc

Pièces jointes

XLDnaute Barbatruc

Pièces jointes

XLDnaute Nouveau

XLDnaute Nouveau

XLDnaute Barbatruc

XLDnaute Nouveau

XLDnaute Nouveau

Pièces jointes

XLDnaute Barbatruc

Pièces jointes

XLDnaute Barbatruc

Pièces jointes

XLDnaute Nouveau

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Nouveau

Discussions similaires

Privacy & Transparency

Privacy & Transparency