Autres Feuille avec Date comme nom

[DragonBallZ1981]

Bonjour à tous,

Je rencontre un problème avec les dates et leur format
J'utilise Excel 2007

Ne pouvant pas mettre de / dans le nom des feuilles j'ai donc mis des -
exemple avec la date d'aujourd'hui 27-10-2022

Dans une cellule je récupère donc le nom de ma feuille avec la formule suivante en cellule A1

=STXT(CELLULE("nomfichier";A1);TROUVE("]";CELLULE("nomfichier";A1);1)+1;30)

J'utilise ensuite la formule suivant pour retrouver la date avec les slash 27/10/2022 en cellule B1

=CONCATENER(GAUCHE(A1;2);"/";GAUCHE(DROITE(A1;7);2);"/";DROITE(A1;4))

Le problème est quand je veux utilisé une formule du type Si date supérieur à date le résultat qu'il me donne est pas forcément juste
Exemple en C1 20/09/2022
Et la formule en D1

=SI(B1>C1;"Vrai";"Faux")

J'obtiens Vrai ce qui est bon
Mais si en C1 je met 20/09/2024
J'obtiens également un Vrai mais qui cette fois est faux

J'ai beau mettre les cellule au format date mais ca ne fonctionne pas.

Est-ce qu'il existe un moyen de transformer la date du nom de la feuille au format "DATE" afin de comparer la date de la feuille avec une autre date ??

Merci de votre aide

 

[Hasco]

Bonjour

Dans le fichier plusieurs manières de faire. Vos dates sont des textes pas des dates.

=DATEVAL(CONCATENER(GAUCHE(A1;2);"/";GAUCHE(DROITE(A1;7);2);"/";DROITE(A1;4)))

=CNUM(CONCATENER(GAUCHE(A2;2);"/";GAUCHE(DROITE(A2;7);2);"/";DROITE(A2;4)))

=CONCATENER(GAUCHE(A3;2);"/";GAUCHE(DROITE(A3;7);2);"/";DROITE(A3;4))*1

=--CONCATENER(GAUCHE(A4;2);"/";GAUCHE(DROITE(A4;7);2);"/";DROITE(A4;4))

et mes préférées

=DATE(DROITE(A5;2);STXT(A5;4;2);GAUCHE(A5;2))

dont la plus courte

=SUBSTITUE(A6;"-";"/")*1

Concatener concatène du texte et renvoie du texte pas une date

Cordialement

 

[TooFatBoy]

Bonjour,

Dans une cellule je récupère donc le nom de ma feuille avec la formule suivante en cellule A1

=STXT(CELLULE("nomfichier";A1);TROUVE("]";CELLULE("nomfichier";A1);1)+1;30)

J'utilise ensuite la formule suivant pour retrouver la date avec les slash 27/10/2022 en cellule B1

=CONCATENER(GAUCHE(A1;2);"/";GAUCHE(DROITE(A1;7);2);"/";DROITE(A1;4))

Le problème est quand je veux utilisé une formule du type Si date supérieur à date le résultat qu'il me donne est pas forcément juste

La deuxième partie est inutile : il suffit de mettre -- devant STXT de ta formule récupérant le nom de l'onglet pour récupérer une vraie date. 😉

 

[DragonBallZ1981]

Bonjour Hasco,

Merci beaucoup ca fonctionne parfaitement

Mais pour comprendre un peu a quoi sert le *1 ??
Car la formule que tu as mis en ligne 3 reste la même que moi juste avec *1 a la fin

 

[DragonBallZ1981]

La deuxième partie est inutile : il suffit de mettre -- devant STXT de ta formule récupérant le nom de l'onglet pour récupérer une vraie date. 😉

Bonjour TooFatBoy,

Ca revient un peu a une des proposition de Hasco mais en plus rapide effectivement
les -- transforme en date mais comment on fait pour le deviner, j'ai pourtant chercher des heure sur internet sans jamais rien trouver😭

 

[TooFatBoy]

Mais pour comprendre un peu a quoi sert le *1 ??

Je me permets de répondre à la question qui ne m'est pas adressée puisqu'il n'y a pas moyen de savoir si Hasco est là ou pas : -- ou *1 font la même chose : ça transforme le texte en valeur numérique. 😉

 

[Hasco]

Re,

Vous avez vu celle que j'ai rajoutée ?

=SUBSTITUE(A6;"-";"/")*1

-- (dans la quatrième proposée post#2) comme *1 force la conversion de texte en numérique.

Cordialement

 

[DragonBallZ1981]

Merci a vous deux,

Oui Hasco j'ai vu toute les formules, la substitution d'un caractère par un autre est très simple, je ne connaissais pas non plus, et ensuite le *1 pour la convertir en date
Merci beaucoup pour votre aide (très rapide en plus) dire que j'ai passé 2 jours a chercher
Je ferme le sujet

EDIT:
Je n'ai pas trouver ou clôturer le sujet, désolé, si quelqu'un peu le faire a ma place
Merci