faire une somme sans prendre les valeurs négatives

[gnimitz]

Bonjour à tous

Je suis confronté au problème suivant :

j'ai dans 3 colonnes des valeurs, je désire faire la somme des ces dernière sauf si une des valeurs est de type négative, actuellement je crée 3 colonnes et je fait le test suivant ex: =SI(H2>=0;H2;"")

puis je fait cette formule dans 3 colonnes et termine par une somme !

comment le faire en 1 formule ??????

Merci d'avance de vos idées !
cjoint fichier essai.xls

 

[Dranreb]

Re : faire une somme sans prendre les valeurs négatives

Bonjour,

=SOMME(H2:J500*(H2:J500>0))

validé matriciellement par Ctrl+Maj+Entrée
Ou

=SOMMEPROD(H2:J500;(H2:J500>0)+0)

validé normalement par Entrée

Bon. Rien compris au problème moi.
Solution donnéee ci après par Victor21 que je salue.

 

[Victor21]

Re : faire une somme sans prendre les valeurs négatives

Bonjour, gnimitz

Essaie :

=H2*(H2>0)+K2*(K2>0)+N2*(N2>0)

Si H2 est >0 , il renvoie Vrai, donc 1 et H2*1=H2.
Sinon, il renvoie Faux, donc 0 et H2*0=0

 

[ROGER2327]

Re : faire une somme sans prendre les valeurs négatives

Bonsoir à tous

Une autre :

=SOMME((H2:N2+ABS(H2:N2))*(MOD(COLONNE(C:I);3)=0))/2

(Formule matricielle à valider par Ctrl Maj Entrée.)​

ROGER2327
#5034

Mardi 10 Pédale 138 (Nativité de Saint Tancrède, jeune homme, SQ)
14 Ventôse An CCXIX
2011-W09-5T16:37:40Z

 

[Victor21]

Re : faire une somme sans prendre les valeurs négatives

Bonsoir, ROGER2327.

Mais où vas-tu chercher tout ça !!!
Serait-ce un effet de ta bonté d'expliquer la première partie de ta formule ?

=SOMME((H2:N2+ABS(H2:N2))...)

 

[tototiti2008]

Re : faire une somme sans prendre les valeurs négatives

Bonjour à tous,

expliquer la première partie de ta formule

si on additionne des valeurs négatives à leur valeur absolue, on obtient 0
si on additionne des valeurs positives à leur valeur absolue, on obtient la valeur X 2

Les valeurs négatives sont donc exclues du calcul, et on redivise par 2 en fin de formule pour récupérer les positives 😉

 

[Victor21]

Re : faire une somme sans prendre les valeurs négatives

Bonsoir, tototiti2008.

Merci pour cette explication.

 

[ROGER2327]

Re : faire une somme sans prendre les valeurs négatives

Re…

Bonsoir, ROGER2327.

Mais où vas-tu chercher tout ça !!!
Serait-ce un effet de ta bonté d'expliquer la première partie de ta formule ?

=SOMME((H2:N2+ABS(H2:N2))...)

Absolument ! Ma bonté est infinie (surtout le vendredi soir).
Souvenir de collège (vieux souvenir d'un temps apparemment révolu où on apprenait ces choses en classe de cinquième...) :
Un nombre positif est égal à sa valeur absolue.
Un nombre négatif est égal à l'opposé de sa valeur absolue.

Autrement dit : Si x >=0 alors x = Abs(x) ; Si x <=0 alors x = -Abs(x).
Donc : Si x >=0 alors x + Abs(x) = 2x ; si x <=0 alors x + Abs(x) =0.
D'où : Si x >=0 alors x = [x + Abs(x)] / 2 ; si x <=0 alors 0 = [x + Abs(x)] / 2.
Par conséquent, [x + Abs(x)] / 2 = Max(x ; 0).
Ça remplace agréablement un "Si x est positif alors x sinon 0".

Formule dérivée : [x - Abs(x)] / 2 = Min(x ; 0).

Pour en revenir à notre formule Excel, on pourrait être tenté d'écrire :

=SOMME(MAX(H2:N2;0)*(MOD(COLONNE(C:I);3)=0))

mais ça ne fonctionne pas (et c'est normal).
Une solution alternative est

=SOMME(H2:N2*(SIGNE(H2:N2)>0)*(MOD(COLONNE(C:I);3)=0))

Voilà…​

ROGER2327
#5035

Mardi 10 Pédale 138 (Nativité de Saint Tancrède, jeune homme, SQ)
14 Ventôse An CCXIX
2011-W09-5T17:48:59Z

 

[Victor21]

Re : faire une somme sans prendre les valeurs négatives

Re, ROGER2327

Merci pour ces explications.
Merci également de m'avoir fait découvrir signe() que je n'avais pas eu encore l'occasion de découvrir.