XL 2021 Extraire valeurs après caractère spécial ou numérique

[sum01]

Bonsoir le forum,

Dans ce petite problème dont je ne parviens pas à trouver la formule/solution. Je cherche à extraire la première valeur qui vient juste après une valeur numérique ou un caractère spécial ("%"). Et si la cellule ne contient aucun des deux alors je prends la première valeur.
Les valeurs en A ne sont pas toujours structurée proprement et je n'ai pas la main sur ces données. Parfois, les valeurs peuvent être séparées par un espace et parfois non.

Je joins le fichier qui, je l'espère, illustre mieux le sujet.

Un grand merci pour votre aide

Belle soirée

 

[sum01]

Bonsoir @ tous,
en B2:

=LET(Fnc;SUPPRESPACE(SI(ESTNUM(CHERCHE("%";A2));STXT(A2;EQUIV("%";STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1);0)+1;99);SIERREUR(STXT(A2;EQUIV(9^9;--STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1))+1;99);GAUCHE(A2;TROUVE(" ";A2)-1))));SIERREUR(GAUCHE(Fnc;TROUVE(" ";Fnc)-1);Fnc))

@ tirer vers le bas

Cordialement

Bonjour,

Merci pour votre aide. Rien à redire la formule correspond parfaitement à mes besoins et permet de gérer un manque de cohérence dans les libellés c’est génial
Belle journée à vous

Bonsoir à @sum01🙂, R@chid 😉,

Une autre pour le fun et pour toutes les versions de Excel. Formule à valider matriciellement (avec la combinaison des 3 touches Ctrl+Maj+Entrée) pour les anciennes version d'Excel :
=SUPPRESPACE(GAUCHE(SUBSTITUE(STXT(A2;EQUIV(FAUX;EXACT(MINUSCULE(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2);1));1));MAJUSCULE(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2);1));1)));0);255);" ";REPT(" ";255));255))

nota : en fait, on extrait à partir de la première lettre quels que soient les caractères avant cette première

 

[sum01]

Bonsoir
Merci à vous tous c'est magnifique, une vrai mine d'informations concernant ce topic à travers toutes les solutions proposées. J'ai appliqué la formule proposée par MaPomme qui fonctionne parfaitement.
A moi de jouer maintenant pour trouver l'inverse cette fois. La bonne formule qui devra extraire cette fois-ci les premiers caractères (les taux donc) avec les fractions mais sans les %.
Encore mille fois merci et bonne soirée à vous.

 

[patricktoulon]

en ce qui concerne les donées maths
a peu près la même technique
recherche equiv dans la matrice stx de la chaine mais cette fois ci de du premier caratères non numérique
touce qui sera à gauche c'est la données maths
😉

 

[mapomme]

Re,

Voir formules au choix dans le classeur joint colonne C ou D.

 

[sum01]

Re,

Voir formules au choix dans le classeur joint colonne C ou D.

Bonsoir Mapomme Bonsoir à tous,

Merci encore et encore et encore. C'est exactement et exactement le résultat qui s'est matérialisé lorsque j'ai appliqué votre solution. C'est parfait !
Merci mille fois pour votre aide
Belle soirée à vous

 

[R@chid]

Bonsoir @ tous,
pour la deuxième question :

=LET(Fnx;MAJUSCULE(STXT(A2;SEQUENCE(NBCAR(A2));1));SUPPRESPACE(SUBSTITUE(CONCAT(FILTRE(Fnx;(CODE(Fnx)<65)+(CODE(Fnx)>91)));"%";)))

@ tirer vers le bas

Cordialement,