Microsoft 365 Extraire une partie d'une chaine de caractères

[iliess]

Bonjour
Comment extraire tout ce qui se trouve après le dernier trait de soulignement "_" dans une chaine de caractères ?
exemple:

12547-Achat climatiseur 23 avr. 2024_25/2024 =======> résultat : 25/2024
00025-Réparation moteur pour iliess_104G/2024======> résultat : 104G/2024
Rempl_renfors_deplace.transfor ht_mp du 04 fev 2023_BC854/2023=======> résultat : BC854/2023

cordialement

 

[mapomme]

Bonsoir @iliess 🙂,

Avec O365 : = =TEXTE.APRES(A1;"_";-1)

 

[mapomme]

Re,
Pour toutes les versions d'Excel :
=SUPPRESPACE(DROITE(SUBSTITUE(SUPPRESPACE(A1);"_";REPT(" ";250));250))

 

[Staple1600]

Bonsoir

Puisque Office 365
En B1
=TEXTE.APRES(A1;"_";SOMME(NBCAR(A1)-NBCAR(SUBSTITUE(A1;"_";""))))
puis recopie vers le bas

 

[iliess]

Mille merci. M @mapomme et M @Staple1600

 

[Staple1600]

Bonsoir @mapomme

Bizarrement mon navigateur affichait 0 réponses quand j'ai posté

Pour la peine, voici deux autres formules
(pour 365)
=DROITE(A1;EQUIV("_";STXT(A1;SEQUENCE(NBCAR(A1);;NBCAR(A1);-1);1);0)-1)

(pour 365 et inférieur)
=FILTRE.XML("<t><s>"&SUBSTITUE(A1;"_";"</s><s>")&"</s></t>";"//s[last()]")

 

[mapomme]

Bonjour @Staple1600 🙂,

Bizarrement mon navigateur affichait 0 réponses quand j'ai posté

Pas de souci, pléthore de solutions ne nuit pas 😉.