Microsoft 365 Extraire une chaine de caractère numérique d'une cellule

[Menjye]

Bonjour,

Je travaille dans un fichier Excel et je dois extraire un numéro de facture au sein d'une cellule, qui n'a pas toujours la même position au sein de cette cellule et qui répond aux critères suivants :
- 9 caractères
- composée de chiffres uniquement (pas d'espace, de lettres ou de caractères spéciaux)
- qui suit toujours le motif YYMMXXXXX où YY est l'année et MM est le mois de la facture.

Voici un exemple de libellé de cellule dans lequel je dois extraire ce numéro :
"Virement de Vincialis 24-01-08 240111987 test"
Je n'arrive pas à définir la formule qui retournerait le résultat "240111987". J'obtiens le résultat "24-01-08 " 🙁

Avez-vous des idées car je suis dessus depuis plusieurs jours et je n'y parviens pas...

Merci à vous !

 

[djidji59430]

Bonjour à tous,

=STXT(I4;CHERCHE("-";I4)+7;9)

Crdlmt

 

[Efgé]

Bonjour
Une proposition dans le vide pour cause de fichier test absent, avec le nom en A1

=LET(
MonTab;FRACTIONNER.TEXTE(A1;" ");
MesChiffres;SI(ESTERREUR(MonTab*1);"";MonTab);
MonExtrac;SI(ESTERREUR(DATEVAL(MesChiffres));MesChiffres;"");
JOINDRE.TEXTE("";1;MonExtrac)
)

Cordialement

EDIT : Bonjour @djidji59430 , désolé, pas rafraîchi

 

[djidji59430]

Je l'ai refait avec let

=
=LET(

frac

;STXT($I$4;SEQUENCE(NBCAR($I$4));1)

;chiffre;(CODE(frac)>=CODE(0))*(CODE(frac)<=CODE(9))

;plage;TROUVE(REPT(1;9);CONCAT(chiffre))-1+LIGNE(1:9)

;JOINDRE.TEXTE("";;INDEX(frac;plage)))

 

[ALS35]

Bonjour à tous,

=TEXTE.AVANT(TEXTE.APRES(TEXTE.APRES(A1;"-";2);" ");" ")

Cordialement

 

[job75]

Bonsoir à tous,

Petite fonction VBA, très simple :

Function Numero$(x$, n)
Dim i%
For i = 1 To Len(x) - n + 1
    If Mid(x, i, n) Like String(n, "#") Then Numero = Mid(x, i, n)
Next
End Function

A+

 

[ALS35]

Bonjour à tous,
Une autre :

=LET(f;FRACTIONNER.TEXTE(A1;" ");PRENDRE(FILTRE(f;ESTNUM(--f));;-1))

Cordialement

 

[patricktoulon]

re
bonjour
visiblement ta chaine numérique est entourée d'espaces
ben cherche les espaces et sert toi de mid (STXT en formule)
à l'ancienne

=STXT(A1;CHERCHE(" ";A1;1)+1;CHERCHE(" ";A1;CHERCHE(" ";A1;1)+1)-CHERCHE(" ";A1;1)-1)

= STXT(ton texte ; index du premier espace+1 ; index du 2d espace moins l'index du premier moins 1)

 

[job75]

Bonjour,

@patricktoulon teste ta formule sur le fichier du post #6...

A+

 

[djidji59430]

Visiblement, on lui a fait peur, à Menjye !

 

[patricktoulon]

re Bonjour à tous
ok @job75 bonnet blanc blanc bonnet on garde le même principe
sauf que le premier cherche c'est le format "??-??-??"

=STXT(A1;CHERCHE("??-??-??";A1;1)+9;CHERCHE(" ";A1;CHERCHE("??-??-??";A1;1)+9+1)-(CHERCHE("??-??-??";A1;1)+9))

testé sur le post #6
sur 2021 avec LET ca devient du pipi de chat la formule 😉