Extraire extension d'un nom de fichier

D

david84

XLDnaute Barbatruc

• 29 Janvier 2010

• #2

Re : Extraire extension d'un nom de fichier

Bonjour,
en B1 =STXT(A1;TROUVE(".";A1)+1;99)
mais est-ce vraiment cela que tu veux ?

 

Vote positif 0 Vote négatif

Jocelyn

XLDnaute Barbatruc

• 29 Janvier 2010

• #3

Re : Extraire extension d'un nom de fichier

Bonjour le Forum,
Bonjour MJ13,

a tester en B1

Code:

=STXT(A1;CHERCHE(".";A1)+1;99)

Jocelyn

EDIT: Bonjour david 84 🙂, Tibo 🙂, quel ensemble tout le monde à la même heure

 

Dernière édition: 29 Janvier 2010

Vote positif 0 Vote négatif

Tibo

XLDnaute Barbatruc

• 29 Janvier 2010

• #4

Re : Extraire extension d'un nom de fichier

Bonjour Michel,

Avec STXT et CHERCHE :

Code:

=STXT(C1;CHERCHE(".";C1)+1;4)

Bonne journée

@+

Edit : Bing ! Salut Jocelyn et David 😉

@+

 

Dernière édition: 29 Janvier 2010

Vote positif 0 Vote négatif

CBernardT

XLDnaute Barbatruc

• 29 Janvier 2010

• #5

Re : Extraire extension d'un nom de fichier

bonjour à tous,

J'y vais de ma contribution, personne n'ayant encore utilisé la fonction droite ni NbCar 🙄

=DROITE(LC1;NBCAR(LC1)-TROUVE(".";LC1;1))

 

Vote positif 0 Vote négatif

MJ13

XLDnaute Barbatruc

• 29 Janvier 2010

• #6

Re : Extraire extension d'un nom de fichier

Bonjour David, Jocelyn, Tibo, Bernard.

Merci beaucoup à tous. C'est tout à fait cela. je l'aurai difficilement trouvé tout seul 🙄.

Pour extraire le nom du fichier, comme Tibo, il me semble m'avait aidé dans un autre post, j'ai fait cela avec Substitue.

Formule à mettre en C1 avec nom fichier en A1 et formule extension en B1:

Code:

=SUBSTITUE(A1;"."&B1;"")

J'ai encore un petit problème: si j'ai 2 points dans le nom, cela pose problème, car il me prend le premier point 😕.

Merci d'avance pour vos solutions 🙂.

 

Dernière édition: 29 Janvier 2010

Vote positif 0 Vote négatif

Tibo

XLDnaute Barbatruc

• 29 Janvier 2010

• #7

Re : Extraire extension d'un nom de fichier

re,

S'il peut y avoir plus d'un . dans le nom du fichier, une solution basée sur la recherche du dernier point :

Code:

=STXT(A1;TROUVE("µ";SUBSTITUE(A1;".";"µ";NBCAR(A1)-
NBCAR(SUBSTITUE(A1;".";""))))+1;99)

@+

 

Vote positif 0 Vote négatif

Hulk

XLDnaute Barbatruc

• 29 Janvier 2010

• #8

Re : Extraire extension d'un nom de fichier

Hello les amis,

Avec la formule à Bernard, tu n'auras pas ce problème, il va chercher le premier point de droite.

 

Vote positif 0 Vote négatif

MJ13

XLDnaute Barbatruc

• 29 Janvier 2010

• #9

Re : Extraire extension d'un nom de fichier

Re Bonjour Hulk

Tibo: Merci beaucoup. Encore moins (que j'aurai pu le trouver😱).

Hulk: Je m'y suis peut-être mal pris mais avec la formule de Bernard, il ne trouve pas l'extension.

ex: BIL.F1.XLS

Bonne Journée à tous 🙂.

 

Vote positif 0 Vote négatif

Tibo

XLDnaute Barbatruc

• 29 Janvier 2010

• #10

Re : Extraire extension d'un nom de fichier

Salut Hulk,

La formule de Bernard cherche le premier point, mais en partant de la gauche.

Ca ne fonctionnera pas.

Il est vrai que chercher le nième caractère d'une chaîne par le biais d'une formule demande une formule un peu complexe, mais j'ai pas trouvé mieux.

@+

 

Vote positif 0 Vote négatif

CBernardT

XLDnaute Barbatruc

• 29 Janvier 2010

• #11

Re : Extraire extension d'un nom de fichier

Re,

petite modification due au changement de données du problème :

=DROITE($A1;NBCAR($A1)-TROUVE(".";$A1;NBCAR($A1)-5))

 

Vote positif 0 Vote négatif

D

david84

XLDnaute Barbatruc

• 29 Janvier 2010

• #12

Re : Extraire extension d'un nom de fichier

Re;
tu as également cette solution
=(STXT(A1;TROUVE(".x";A1)+1;99))
A+

 

Vote positif 0 Vote négatif

MJ13

XLDnaute Barbatruc

• 29 Janvier 2010

• #13

Re : Extraire extension d'un nom de fichier

Re Bernard, David.

Ok pour vos formules, mais c'est comme à l'école, vous n'avez pas bien lu l'énoncé 😛.

Le but est de trouver l'extension d'un nom de fichier quelque soit le nombre de caractères après le dernier point. Hors sur quelques milliers de noms de fichiers XLS, XLSX, DOC etc... je peux avoir des doubles points dans le nom.

Et comme je veux faire des sauvegardes par année, il me faut absolument le nom et l'extension pour mes stats et pour pouvoir mettre mes gigas de données sur N DVD. Voila le pourquoi du comment 😉.

Hors d'après mes tests, la formule de Tibo de 10H01 (#7) semble aller parfaitement. En plus sur 12000 noms, c'est assez rapide comme formule.

Encore merci à tous 🙂.

 

Vote positif 0 Vote négatif

Jocelyn

XLDnaute Barbatruc

• 3 Février 2010

• #14

Re : Extraire extension d'un nom de fichier

re,
Bonjour a ceux que je n'ais pas encore salué,

bon je viens juste de voir ton dernier message MJ13 et je ne sais pas si tu a résolu le soucis alors je poste une formule corrigée qui tient compte de ta remarque.🙂

Code:

=STXT(SUBSTITUE(A1;".";"µ";SOMMEPROD((STXT(A1;LIGNE($1:$50);1)=".")*1));CHERCHE("µ";SUBSTITUE(A1;".";"µ";SOMMEPROD((STXT(A1;LIGNE($1:$50);1)=".")*1)))+1;99)

voir le fichier

Jocelyn

EDIT : Arf en plus j'ai lu ton message en diagonale alors mes excuses a tibo qui a deja donné la réponse

 

Pièces jointes

• mj13.xls

  18 KB · Affichages: 100

Dernière édition: 3 Février 2010

Vote positif 0 Vote négatif

Staple1600

XLDnaute Barbatruc

• 3 Février 2010

• #15

Re : Extraire extension d'un nom de fichier

Bonsoir à tous



en VBA

Code:

Function extension(r As Range, element As Long)
extension = Split(r.Text, ".")(element)
End Function

pour le nom du fichier : =extension(A1;0)
pour son extension : =extension(A1;1)

par formules

Code:

=STXT(A1;CHERCHE(".xl*";A1)+1;4)

ou

Code:

=SUBSTITUE(DROITE(A1;4);".";"")

 

Vote positif 0 Vote négatif