Extraire des personnes d'un tableau vers un autre tableau

[RobertT]

Bonjour,
En premier, merci pour votre site.
Voici la situation.
J'ai 2 tableaux. Un sur la feuille 1 et l'autre sur la feuille 2.

Nom du tableau 1 ; tblPays
Nom du tableau 2 : tblPersonne

Je voudrais extraire les noms des personnes (tableau 1) dont le pays répond au critère "France" vers un le tableau 2.
Voici la formule avec index equiv:
=INDEX((tblPays[Personne]);EQUIV("France";tblPays[Pays];0))
La validation a été fait par ctrl shift enter

Données sources
tblPays:

Tableau 1
Personne Pays
André Benoit France
Marc Laberge France
Joe Frazier Bretagne
Rodrigo Marques France
Walter Peper Bretagne
Walter Peper Bretagne

Données attendues
Tableau 2
Personne
André Benoit
Marc Laberge
Rodrigo Marques

Malheureusement la formule me retourne toujours "André Benoit".


Merci pour vos suggestions,

 

[job75]

Re : Extraire des personnes d'un tableau vers un autre tableau

Bonjour RobertT,

Très très classique... Formule matricielle en A2 :

=SIERREUR(INDEX(tblPays[Personne];PETITE.VALEUR(SI(tblPays[Pays]="France";LIGNE(tblPays[Pays]));LIGNES($2:2)));"")

A valider par Ctrl+Maj+Entrée et tirer vers le bas.

Fichier joint.

A+

 

[job75]

Re : Extraire des personnes d'un tableau vers un autre tableau

Bonjour RobertT le forum,

Pas fait attention, il manquait un -1 :

=SIERREUR(INDEX(tblPays[Personne];PETITE.VALEUR(SI(tblPays[Pays]="France";LIGNE(tblPays[Pays])-1);LIGNES($2:2)));"")

Les tableaux commencent en effet à la ligne 2...

Fichier (2).

A+

 

[JCGL]

Re : Extraire des personnes d'un tableau vers un autre tableau

Bonjour à tous,
Salut Gérard,

Avec un TCD et un Segment (je ne me souviens plus si cela est disponible sur XL 2010...)

A++ l'ami
A+ à tous

 

[Victor21]

Re : Extraire des personnes d'un tableau vers un autre tableau

Bonjour, lézamis.

Fâché avec les matricielles, et essayant de comprendre et d'adapter la formule proposée par job75 :

=SIERREUR(INDEX(tblPays[Personne];PETITE.VALEUR(SI(tblPays[Pays]="France";LIGNE(tblPays[Pays])-1);LIGNES($2:2)));"")

il me vient une question :
Si tblPays est déplacé, la formule ne se met pas à jour automatiquement. Comment faire ?

Comment remplacer LIGNE(tblPays[Pays])-1 par "Ligne des titres de tblPays" ???

PS : JC les segments sont disponibles sous XL10 😉

 

[Guest]

Re : Extraire des personnes d'un tableau vers un autre tableau

Bonsoir tous,

Hello JC🙂
salut Victor🙂

tblPays[#En-têtes] (Dans la simplicité Microsoftienne...arf)

Sur la base du tableau du fichier de JC🙂🙂

=INDEX(tblPays[Personne];PETITE.VALEUR(SI(tblPays[Pays]="Bretagne";LIGNE(tblPays)-LIGNE(tblPays[#En-têtes]));LIGNES($1:1)))

A+

 

[Victor21]

Re : Extraire des personnes d'un tableau vers un autre tableau

Bonjour, Hasco 🙂

Merci pour ta réponse, que je vais tester illico presto.

J'ai pour ma part trouvé :

=SIERREUR(INDEX(tblPays[Personne];PETITE.VALEUR(SI(tblPays[Pays]="France";LIGNE(tblPays[Pays])-CELLULE("ligne";tblPays)+1);LIGNES($1:1)));"")

Edit : Les deux fonctionnent 🙂

 

[job75]

Re : Extraire des personnes d'un tableau vers un autre tableau

Bonsoir à tous,

Ou aussi :

=SIERREUR(INDEX(tblPays[Personne];PETITE.VALEUR(SI(tblPays[Pays]="France";LIGNE(tblPays[Pays])-LIGNE(INDEX(tblPays;1;))+1);LIGNES($1:1)));"")

Fichier (3).

A+