Extraire date en fonction du mois

[pad01]

Bonsoir le Forum,
J'avais déjà fait une demande ultérieure sur ce sujet mais sans succès. Depuis, mon fichier est un peu plus étoffé puisque mes extractions de dates se font suivant les numéros de poste.
Le problème, que je n'arrive pas à résoudre, est que je voudrai faire les mêmes extractions mais suivant un mois demandé.
Merci de votre aide
Cordialement

 

[Tibo]

Re : Extraire date en fonction du mois

Bonsoir,

Sous réserve d'avoir compris, je te propose cette formule matricielle en B4 :

=SI(LIGNES($1:1)>SOMME((MOIS(Bd!$A$2:$A$9)=MOIS($B$1))*(Bd!$B$2:$B$9=B$3));"";INDEX(Bd!$A$1:$A$9;PETITE.VALEUR(SI((MOIS(Bd!$A$2:$A$9)=MOIS($B$1))*(Bd!$B$2:$B$9=B$3);(MOIS(Bd!$A$2:$A$9)=MOIS($B$1))*(Bd!$B$2:$B$9=B$3)*LIGNE(Bd!$A$2:$A$9));LIGNES($1:1))))

Formule matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers le bas et vers la droite.

@+

 

[pad01]

Re : Extraire date en fonction du mois

Bonsoir Tibo,
Merci pour la réponse et l'aide.
La formule proposée répond bien au changement de mois mais est parfois en erreur sur le choix de postes. Pour mars, elle me met les trois dates en poste 1.
Cdt

 

[pad01]

Re : Extraire date en fonction du mois

Rebonsoir Tibo,
Après avoir regardé de plus prés la formule, l'erreur vient de la présentation de ma pièce jointe. Je m'explique, les postes ne se trouve pas sur la ligne 4 mais dans la colonne A:A. La formule est donc opérationnelle mais il faut le retourner... Je suis preneur si tu as encore du temps à me consacrer sinon je me débrouillerai.
Encore un gros merci pour ta solution.
Cdt

 

[Tibo]

Re : Extraire date en fonction du mois

re,

Une adaptation de la formule :

=SI(COLONNES($A:A)>SOMME((MOIS(Bd!$A$2:$A$9)=MOIS($B$1))*(Bd!$B$2:$B$9=$A4));"";INDEX(Bd!$A$1:$A$9;PETITE.VALEUR(SI((MOIS(Bd!$A$2:$A$9)=MOIS($B$1))*(Bd!$B$2:$B$9=$A4);(MOIS(Bd!$A$2:$A$9)=MOIS($B$1))*(Bd!$B$2:$B$9=$A4)*LIGNE(Bd!$A$2:$A$9));COLONNES($A:A))))

toujours matricielle,

à recopier vers le bas et vers la droite

@+

 

[pad01]

Re : Extraire date en fonction du mois

Bonsoir Tibo,
Cela fait plaisir de te relire car j'avoue que je ramais un peu mais cela fait partie de l'apprentissage.
Cela fonctionne à merveille et répond à ma demande
Merci à toi