Est-il possible de raccourcir une formule comparative

[libellule85]

Bonsoir le forum,

Je viens vers vous pour savoir si il était possible de raccourcir une formule.
Je veux comparer les trimestres de deux années N et N-1 pour cela j'ai fait la formule suivante qui fonctionne :

=SI(NBVAL(E7:H7)=1;A7;SI(NBVAL(E7:H7)=2;SOMME(A7:B7);SI(NBVAL(E7:H7)=3;SOMME(A7:C7);SI(NBVAL(E7:H7)=4;SOMME(A7:D7);""))))

Si nbval(E7:H7)=1 mettre la A7
Si nbval(E7:H7)=2 mettre la somme de A7:B7
Si nbval(E7:H7)=3 mettre la somme de A7:C7
Si nbval(E7:H7)=4 mettre la somme de A7😀7

N'y a-t'il pas un moyen pour faire plus court
D'avance merci pour votre aide

 

[david84]

Re : Est-il possible de raccourcir une formule comparative

Bonsoir,
à tester :

=SI(NBVAL(E7:H7)>0;SOMME(DECALER(A7;;;;NBVAL(E7:H7)));"")

A+

 

[libellule85]

Re : Est-il possible de raccourcir une formule comparative

Bonsoir David84,

Merci beaucoup pour ta réponse, c'est sympa. J'ai testé ta formule, elle fonctionne impeccablement.
Encore merci et bonne soirée

 

[job75]

Re : Est-il possible de raccourcir une formule comparative

Bonjour libellule85, salut David,

=SOMMEPROD(A7:D7*SIGNE(E7:H7))

Mettre la cellule au format personnalisé 0;;

A+

 

[libellule85]

Re : Est-il possible de raccourcir une formule comparative

Bonsoir Job75,

Un grand merci pour ta réponse, je ne connaissais pas la fonction "signe".
Bonne soirée

 

[R@chid]

Re : Est-il possible de raccourcir une formule comparative

Bonjour @ tous,
Salut Libellule85, Salut David84, Salut Job75...
Attention à la fonction SIGNE(), il faut pas avoir des valeurs négatives dans la plage E7:H14, sinon remplacer SIGNE() par ESTNUM()...
Ou bien ,

=SOMME.SI(E7:H7;"<>"&"";A7:D7)

@ + +

 

[libellule85]

Re : Est-il possible de raccourcir une formule comparative

Bonsoir R@chid,

Merci pour ta réponse, décidément j'ai beaucoup de progrès à faire pour arriver à votre niveau !
Bonne soirée

 

[job75]

Re : Est-il possible de raccourcir une formule comparative

Bonjour libellule85, David, R@chid, le forum,

En fait tout dépend des valeurs du tableau et de ce que l'on veut en faire.

Si l'on veut tenir compte d'éventuelles valeurs textes utiliser :

=SOMMEPROD(A7:D7;1-ESTVIDE(E7:H7))

ou la formule donnée par R@chid :

=SOMME.SI(E7:H7;"<>"&"";A7:D7)

La première formule "pèse" 28 octets, la seconde 30 octets.

Fichier (2).

A+