XL pour MAC Entre le 3eme tiret et le dernier tiret

[cloum1]

Bonjour
J'imagine que la question a été abordé dans un cas similaire mais étant une bille avec les formule je n'arrive pas à extrapoler avec des solutions proches utilisant des fonctions imbriquées.
Pourriez vous m'aider pour une formule qui permettrait d'extraire tous les caractères présents dans une cellule entre le 3eme tiret et le dernier tiret ? la chaine est de longueur variable ainsi que le nombre de tirets

Merci !

 

[patricktoulon]

Bonjour
sujet similaire abordé tres récement

XL 2016 - Extraire des chiffres d'une chaine

Bonjour à tous, J'aimerais extraire les chiffres 55 et 1 de la chaine de caractère suivante : 1-21000_RZT_DWB100-55-CFG-1 et les chiffres 1et 20 de la chaine caractère suivante : G-34-7-TDP-2-1-DLS-20 Merci d'avance.

excel-downloads.com

 

[cloum1]

Bonjour
sujet similaire abordé tres récement

XL 2016 - Extraire des chiffres d'une chaine

Bonjour à tous, J'aimerais extraire les chiffres 55 et 1 de la chaine de caractère suivante : 1-21000_RZT_DWB100-55-CFG-1 et les chiffres 1et 20 de la chaine caractère suivante : G-34-7-TDP-2-1-DLS-20 Merci d'avance.

excel-downloads.com

J'ai essayé ca mais ca ne marche pas
=STXT(A1;SEARCH("-";A1;SEARCH("-";A1;SEARCH("-";A1)+1)+1)+1;SEARCH("$";SUBSTITUE(A1;"-";"$";NBCAR(A1)-NBCAR(SUBSTITUE(A1;"-";""))))-SEARCH("-";A1;SEARCH("-";A1;SEARCH("-";A1)+1)+1)-1)

 

[mapomme]

Bonsoir à tous 🙂,

Avec la formule matricielle suivante en B2 à copier vers le bas :
=STXT(A2;(PETITE.VALEUR(SI(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)="-";LIGNE(INDIRECT("1:"&NBCAR(A2)));"");3)+1);GRANDE.VALEUR(SI(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)="-";LIGNE(INDIRECT("1:"&NBCAR(A2)));"");1)-(PETITE.VALEUR(SI(STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)="-";LIGNE(INDIRECT("1:"&NBCAR(A2)));"");3)+1))

 

[Cousinhub]

Bonsoir,
Même si tu es sous MAC, il vaut peut-être mieux préciser ta version (365, 2021, .....)
Xl pour MAC, OK, mais quelle version?
Si tu as 365, Texte.Avant et Texte.Apres feront le boulot....
Bonne soirée

 

[mapomme]

Bonsoir à tous,

Si tu as 365, Texte.Avant et Texte.Apres feront le boulot....

D'après la suggestion de @Cousinhub que je salue 🙂, une formule en Excel 365 pourrait être :
=TEXTE.AVANT(TEXTE.APRES(A2;"-";3);"-";-1)

 

[job75]

Bonsoir à tous,

On peut aussi utiliser cette fonction VBA :

Function Tirets(x) As String
Dim s, a, i
s = Split(x, "-")
If UBound(s) < 4 Then Exit Function
ReDim a(UBound(s) - 4)
For i = 0 To UBound(a): a(i) = s(i + 3): Next
Tirets = Join(a, "-")
End Function

Bonne nuit.

 

[Jacky67]

Bonjour
J'imagine que la question a été abordé dans un cas similaire mais étant une bille avec les formule je n'arrive pas à extrapoler avec des solutions proches utilisant des fonctions imbriquées.
Pourriez vous m'aider pour une formule qui permettrait d'extraire tous les caractères présents dans une cellule entre le 3eme tiret et le dernier tiret ? la chaine est de longueur variable ainsi que le nombre de tirets

Merci !

Bonjour à tous
Ceci semble aussi fonctionner (Tester sur pc)

=STXT(A1;TROUVE("£";SUBSTITUE(A1;"-";"£";3))+1;TROUVE("¤";SUBSTITUE(A1;"-";"¤";NBCAR(A1)-NBCAR(SUBSTITUE(A1;"-";""))))-(TROUVE("£";SUBSTITUE(A1;"-";"£";3))+1))