Effacer une plage de cellule avec Macro

[Defter]

Bonjour à tous,

J'ai actuellement un problème lié à une Macro destinée à effacer des cellules situées entre une plage de colonne précise.
Ma macro actuelle est la suivante :

Private Sub CommandButton2_Click()
    If ActiveSheet.[B1048576].End(xlUp).Row > 31 Then
        ActiveSheet.Range(Cells([B1048576].End(xlUp).Row, 2), Cells([B1048576].End(xlUp).Row, 36)).ClearContents
    End If
End Sub

Le Commandbutton2 est situé sur la même feuille que la plage de cellule à effacer il n'y a donc aucun problème, cette macro fonctionne.

Ça ce complique :
Pour un autre cas, ma plage de cellule à effacer ce situe sur une autre feuille nommée "Tableau Resultat", Mon Commandbutton2 est sur une feuille nommée "Interface". J'ai donc adapté la macro précédente :

Private Sub CommandButton2_Click()
    If Sheets("Tableau Resultat").[B1048576].End(xlUp).Row > 3 Then
        Sheets("Tableau Resultat").Range(Cells([B1048576].End(xlUp).Row, 1), Cells([B1048576].End(xlUp).Row, 20)).ClearContents
    End If
End Sub

Mais la il me met une erreur '1004 à la ligne

Sheets("Tableau Resultat").Range(Cells([B1048576].End(xlUp).Row, 1), Cells([B1048576].End(xlUp).Row, 20)).ClearContents

J'ai essayé diverses solutions mais rien ne marche.
Auriez vous une solution ?

Par avance, Merci,
Defter

 

[Cousinhub]

Re : Effacer une plage de cellule avec Macro

Bonjour,

Effectivement, tu fais référence à des cellules de la feuille active....

Pour y remédier, essaie ainsi :

Private Sub CommandButton2_Click()
With Sheets("Tableau Resultat")
    If .[B1048576].End(xlUp).Row > 3 Then
        .Range(.Cells(.[B1048576].End(xlUp).Row, 1), .Cells(.[B1048576].End(xlUp).Row, 20)).ClearContents
    End If
End With
End Sub

Bonne journée

 

[tbft]

Re : Effacer une plage de cellule avec Macro

Bonjour

Un fichier (avec données bidons) serait fortement utile!!!

 

[Defter]

Re : Effacer une plage de cellule avec Macro

Bonjour Bhbh et Tbft,

Merci d'avoir porter attention à mon sujet !

Bhbh, merci beaucoup ça marche parfaitement.
Effectivement je ne savais pas qu'il fallait rappeler le faite d'être sur une autre feuille à chaque fonction (Avec le point).

Merci à tout les deux,

Cordialement,
Defter