Donner un état avec conditions sur une colonne

[phendoc]

Bonjour à tous,

J'ai un tableau excel ci-joint pour lequel dans une feuille j'ai des termes composés de plusieurs mots, et dans une autre feuille des marques.
Si une marque listée dans la colonne unique de la feuille 2 est présente dans un terme de la feuille 1, alors un état "marque est indiqué dans la 2e colonne de la feuille 1.
Actuellement, j'utilise la formule suivante pour 6 marques listées :
=SI(OU(ESTNUM(CHERCHE(marques!$A$2;A2));ESTNUM(CHERCHE(marques!$A$3;A2));ESTNUM(CHERCHE(marques!$A$4;A2));ESTNUM(CHERCHE(marques!$A$5;A2));ESTNUM(CHERCHE(marques!$A$6;A2)));"marque";"pas de marque")

Le problème c'est que je peux avoir un nombre plus important de marques et que la formule risque d'être rapidement indigeste.
Y'a-t-il une méthode plus simple, si possible sans vba, pour prendre en compte les cellules de la feuille des marques (nommer un groupe de cellules, etc) ?

Merci par avance pour votre aide.
Michel

 

[job75]

Re : Donner un état avec conditions sur une colonne

Bonjour phendoc,

1) Définir (menu Insertion-Nom) le nom marques avec la formule :

=DECALER(marques!$A$2;;;NBVAL(marques!$A:$A)-1)

2) Entrer en B2 la formule :

=SI(SOMMEPROD(NB.SI(A2;"*"&marques&"*"));"";"pas de ")&"marque"

et tirer vers le bas.

On pourrait aussi utiliser les fonctions CHERCHE ou TROUVE.

A+

 

[job75]

Re : Donner un état avec conditions sur une colonne

Re,

Je donne quand même la formule en B2 avec CHERCHE :

=SI(SOMMEPROD(1*ESTNUM(CHERCHE(marques;A2)));"";"pas de ")&"marque"

A+

 

[phendoc]

Re : Donner un état avec conditions sur une colonne

Merci beaucoup job75, ça correspond tout-à-fait à ma problématique

 

[job75]

Re : Donner un état avec conditions sur une colonne

Re,

Pour clore ce fil correctement, les solutions les plus simples en terme de nombre d'octets utilisés :

=REPT("pas de ";NON(SOMMEPROD(1*ESTNUM(CHERCHE(marques;A2)))))&"marque"

et évidemment :

=SOMMEPROD(1*ESTNUM(CHERCHE(marques;A2)))&" marque(s)"

A+