Dernière cellule, ligne colonne

[zazou5908]

Bonjour le Forum,

Je cherche à récupérer dans une sheet1 "Paramètres", dans différentes cellules les informations suivantes:

Numéro de la dernière ligne utilisée dans la sheet2
Numéro de la dernière colonne utilisée dans la sheet2
Références ligne/colonne de la dernière cellule utilisée dans la sheet2.

Avec la formule du style

Sheets(1).Range("b2").Value = Sheets(2).Range("a65536").End(xlUp).Row

j'obtiens la dernière ligne utilisée de la colonne A.
Mais j'ai peut être plus de ligne dans la colonne B !!!

Même problème pour déterminer la dernière colonne.

Quant à ma 3èm demande, c'est pour voir si je sais récupérer les 2 informations (ligne et colonne) en une seule fois pour traitement ultérieur (copier une cellule de référence dans une sheet3 jusqu'à la dernière ligne utilisée ou dernière colonne utilisée ou jusqu'à la dernière cellule utilisée

Bien à vous et merci pour l'aide que vous accorder bénévollement à toutes les personnes comme moi !

 

[SergiO]

Re : Dernière cellule, ligne colonne

Bonjour Zazou

Ci-joint un petit exemple à adapter:

Option Explicit
Sub test1()
Dim c As Range
Set c = ActiveSheet.UsedRange
MsgBox c.Rows.Count
MsgBox c.Columns.Count
Set c = c(c.Rows.Count, c.Columns.Count)
Range(Cells(1, 1), c).Select

End Sub

@+

 

[zazou5908]

Re : Dernière cellule, ligne colonne

Bonjour SergiO

Merci pour la réponse. Je vais essayer de comprendre ce que tu fais.
Si je comprends bien le début, je dois me trouver dans la sheet qui comprend toutes les données ?

Merci

 

[Pierrot93]

Re : Dernière cellule, ligne colonne

Bonjour Zazou, Sergio

une autre solution :

Sub test()
With Worksheets(2).Cells
    Set c = .Find("*", LookIn:=xlValues)
    If Not c Is Nothing Then Sheets(1).Range("B2").Value = c.Address(0, 0)
End With
End Sub

bonne fin d'après midi
@+

 

[Bebere]

Re : Dernière cellule, ligne colonne

bonsoir Pierrot,Zazou,Sergio

Sub test()
MsgBox DerCell.Address
' MsgBox DERCELLCURRENT(ActiveCell).Address
End Sub

Sub GetRealLastCell()
'mpfe (doc J@C)
Dim RealLastRow As Long
Dim RealLastColumn As Long
Range("A1").Select
On Error Resume Next
RealLastRow = _
Cells.Find("*", [A1], , , xlByRows, xlPrevious).Row
RealLastColumn = _
Cells.Find("*", [A1], , , xlByColumns, xlPrevious).Column
Cells(RealLastRow, RealLastColumn).Select
End Sub

Function DerCell() As Range
Dim derLi, derCol
On Error GoTo fin
derLi = Cells.Find("*", [A1], , , 1, 2).Row
derCol = Cells.Find("*", [A1], , , 2, 2).Column
Set DerCell = Cells(derLi, derCol)
Exit Function
fin:
Set DerCell = Cells(1, 1)
End Function

à bientôt

 

[zazou5908]

Re : Dernière cellule, ligne colonne

Bonjour à tous le monde et merci à Sergio, Pierrot et Bebere.

Je vais essayer les différentes solutions proposées pour voir ce qui me convient le mieux.

Désolé pour la réaction tardive mais hier je travaillais de chez moi et Internet c'est mis HS !

Le temps d'attendre les vrais techniciens de VOO (Bebere comprendra).... Mais cela valait la peine d'attendre !!! Ils n'ont pas trouvé un problème mais 3 problèmes dans le réseau alimentant ma rue !!!

A plus et merci pour vos solutions.