Microsoft 365 Dénombrer tous les couples selon 2 listes

[alexitt]

Bonjour,
J'ai 2 listes "code" et "opération".
Je souhaite trouver une formule excel permettant de lister tous les couples "code" & "opération" différents.

Puisque qu'un fichier est toujours plus parlant, vous trouverez ci-joint un exemple.

Merci d'avance pour votre aide.

 

[sylvanu]

Bonsoir Alexitt,
En PJ une méthode simplissime mais nécessite deux colonnes.

 

[Hecatonchire]

Bonjour,

en H2

=LET(code;A2:A11;ope;B2:B6;
nbOpe;NB(ope);
MAKEARRAY(NB(code)*nbOpe;2;LAMBDA(r;c;INDEX((code;ope);SI(c=1;ENT((r-1)/nbOpe)+1;MOD(r-1;nbOpe)+1);1;c))))

Mais je ne sais pas si tu disposes de ces fonctions

 

[Dranreb]

Bonjour.
En H2, à propager sur 50 lignes :

=INDEX($A$2:$A$11;QUOTIENT(LIGNE()-2;LIGNES($B$2:$B$6))+1)

En I2, à propager sur 50 lignes :

=INDEX($B$2:$B$6;MOD(LIGNE()-2;LIGNES($B$2:$B$6))+1)

 

[ALS35]

Bonjour à tous,
Pléthore de réponse !
Une autre possibilité pour M365, formule unique en H2 :

=--FRACTIONNER.TEXTE(CONCAT(A2:A11&"|"&TRANSPOSE(B2:B6)&"_");"|";"_";1)

Cordialement

 

[Hecatonchire]

Pour ancien Excel :

En H2 à recopier vers la gauche en I2 puis recopier H2:I2 vers le bas

=INDEX(($A$2:$A$11;$B$2:$B$6);SI(COLONNE()=8;ENT((LIGNE()-2)/NB($B$2:$B$6))+1;MOD(LIGNE()-2;NB($B$2:$B$6))+1);1;COLONNE()-7)

 

[mapomme]

Bonsoir à tous 😀,

Ma pomme veut participer aussi😒.

Deux formules à recopier suffisamment vers le bas jusqu'à obtenir des lignes vides (toutes versions) :
En E2 : =SI((LIGNE()-1)<=(NBVAL(A:A)-1)*(NBVAL(B:B)-1);INDEX(A:A;2+ENT((LIGNE()-2)/(NBVAL(B:B)-1)));"")
En D2 : =SI((LIGNE()-1)<=(NBVAL(A:A)-1)*(NBVAL(B:B)-1);INDEX(B:B;2+MOD(LIGNE()-2;NBVAL(B:B)-1));"")

Et une MFC pour alterner les couleurs des blocs.

nota : fonctionne même si les éléments sont du texte.

 

[alexitt]

Bonjour,
Merci à tous pour vos réponses, vous êtes au top.
Disposant de M365, j'ai choisi la méthode la plus simple et qui avec une plage dynamique peut s'adapter si le nombre de code ou opération évolue.