demande un vide au lieu de "0"

[Lipadec]

Bonjour le Forum

Comme d'habitude, je viens tjs vers vous pour me donner de vos conseils et vos connaissances.
J'ai une formule que j'utilise beaucoup dans un travail, mais au d'un vide que je veux, j'ai un "0", car dans l'application que je vais utiliser, je ne dois pas avoir de "0", tout en gardant le NBCAR de la chaîne à 255
Je pense que je me suis bien exprimé.
Je vous envois en pièce jointe, un apperçu de ce travail
Merci pour votre aide

Lipadec

 

[Victor21]

Re : demande un vide au lieu de "0"

Bonjour, Lipadec.

Un vide ou 17 caractères nuls ?
Si c'est rien :

SI(IMP2!G4=0;"";SI(NBCAR(IMP2!G4)<G$2;IMP2!G4&REPT(" ";G$2-NBCAR(IMP2!G4));GAUCHE(IMP2!G4;G$2)))

Si c'est 17 caractères nuls:

=SI(IMP2!G4=0;REPT(" ";G$2);SI(NBCAR(IMP2!G4)<G$2;IMP2!G4&REPT(" ";G$2-NBCAR(IMP2!G4));GAUCHE(IMP2!G4;G$2)))

 

[Dugenou]

Re : demande un vide au lieu de "0"

Bonjour,

bonjour Victor

je ne sais pas pourquoi tu gères les espaces après tes comptes tiers mais avec
=SI(NBCAR(IMP2!G4)<G$2;CNUM(IMP2!G4&REPT(" ";G$2-NBCAR(IMP2!G4)));CNUM(GAUCHE(IMP2!G4;G$2)))
on supprime les 0
Cordialement

 

[Gorfael]

Re : demande un vide au lieu de "0"

Salut Lipadec et le forum
Comme toujours sur excel, une multitude de possibilités.
Memu outils>>option>>onglet Affichage>>Valeur 0
Mais ça, c'est pour tout

L'éternel =si(formule=0;"";formule)

Format de cellule personnalisé de type : standard;standard;
J'ai mis standard, mais tu petx mettre ce que tu veux, l'important c'est que la troisième partie reste vide.
A+

 

[tototiti2008]

Re : demande un vide au lieu de "0"

Bonjour Lipadec,

un essai en G4

=SI(NBCAR(T(IMP2!G4))<G$2;T(IMP2!G4)&REPT(" ";G$2-NBCAR(T(IMP2!G4)));GAUCHE(IMP2!G4;G$2))

Edit : Oups, pas rafraichi, moi
Bonjour Victor, Bonjour Dugenou, Bonjour Gorfael

 

[Lipadec]

Re : demande un vide au lieu de "0"

Re

Merci beaucoup les experts d'excel, en appliquant la solution de Victor21, elle m'a donné de ce que je veux, et en appliquant celle de Dugenou, et fait la même chose mais elle ne conserve pas le NBCAR de 255
Dans tous les cas merci à vous deux pour votre réponse si vite, vous êtes vraiment des experts et je vous en félicite

Lipadec

 

[Lipadec]

Re : demande un vide au lieu de "0"

Re
Merci à toi aussi Tototiti2000, sa réponse marche aussi
Vive les experts
Merci à tout le monde du Forum

Lipadec