Déduire des jours dans une période donnée

[cimbombom]

Bonjour,

Pour mon travail (et pour jeudi surtout), je dois créer une feuille de calcul excel. Je m’explique.

Je dois créer un tableau qui décompte, dans une période donnée :

-le nombre de jours total dans l'année (ça c'est facile j'y suis arrivé)
-le nombre de jours non décomptés (jours de fermeture de l’établissement)

... ce qui me donnera, par une soustraction, le nombre de jours réellement décomptés.

Par exemple, j’inscris automatiquement les dates voulues, par exemple du 01.04.2011 au 15.08.2011 et mes formules me calculent automatiquement le nombre de jours total et le nombre de jours non-décomptés (par rapport à une colonne qui contient les jours de fermeture que j’aurai inscrit manuellement).

Est-ce clair ? Quelqu’un peut-il m’aider ?

Je vous joins ce que j’ai fait jusqu’à présent.

C’est très urgent, mon boss va me taper sur les doigts si je présente rien jeudi.

Merci d’avance !

 

[Everlast03]

Re : Déduire des jours dans une période donnée

Est-ce clair ? Quelqu’un peut-il m’aider ?

Je vous joins ce que j’ai fait jusqu’à présent.

Non pas vraiment, explique toi mieux si tu le veux bien ;-).

 

[cimbombom]

Re : Déduire des jours dans une période donnée

Sur ma colonne de droite sous "fermeture établissement", il y a une série de date inscrite manuellement.

J'aimerais qu'une formule me calcule le nombre de jours qui apparaissent dans cette colonne durant la période inscrite en haut de la feuille.

C'est plus clair ?

Merci

 

[mromain]

Re : Déduire des jours dans une période donnée

Bonjour cimbombom, Everlast03,

Essaye avec cette formule en D13 :

=SOMMEPROD((G12:G32>=B13)*(G12:G32<=C13))

a+

 

[cimbombom]

Re : Déduire des jours dans une période donnée

MILLE MERCI !

Quelle rapidité ! Merci encore ça fonctionne nickel !

 

[Everlast03]

Re : Déduire des jours dans une période donnée

Pour ta formule :

Si tu la places en B30 par exemple :

"B30" =(F8-D8)-(NBVAL(G:G)-1)

• (F8-D8) Correspond à ton nombre de jour total
• (NBVAL(G:G)-1) Correspond au nombre de valeurs rentrées dans ta colonne G moins une qui correspond à ton entête "Fermeture établissement"

PS : J'ai pas compris ton "F8-D8+1"

 

[cimbombom]

Re : Déduire des jours dans une période donnée

Merci encore à tout le monde pour votre aide.

@ Everlast03 : Ben si par exemple je mets pas le "+1" dans la formule, il me décompte un seul jours si je mets du 01.01 au 02.01.

Ose-je encore abuser de vos bons conseils ?

J'ai remis en pièce jointe le fichier, serait-ce possible que ces fameuses dates de fermeture apparaissent sous une phrase : "Les dates de fermeture sont :" ? En l'occurence dans l'exemple qui se trouve dans mon fichier, les 6 dates de fermeture apparaitraient à la fin de cette phrase.

Merci messieurs (et mesdames je sais pas) pour vos conseils très avisés.

 

[mromain]

Re : Déduire des jours dans une période donnée

Bonjour cimbombom,

Voici un essai avec cette formule matricielle (à valider par <Ctrl> + <Maj> + <Entrée>) à saisir en A17 et à tirer vers le bas :

=SI(LIGNES($A$17:$A17)>$B$13;"";INDEX('Fermeture établissement'!$A$2:$A$22;GRANDE.VALEUR(('Fermeture établissement'!$A$2:$A$22>=$B$8)*('Fermeture établissement'!$A$2:$A$22<=$D$8)*LIGNE('Fermeture établissement'!$A$2:$A$22);$B$13-LIGNES($A$17:$A17)+1)-LIGNE('Fermeture établissement'!$A$2:$A$22)+1))

a+

Edit:

Une autre solution avec une formule plus courte et pas matricielle (toujours à saisir en A17 et à tirer vers le bas) :

=SI(LIGNES($A$17:$A17)>$B$13;"";INDEX('Fermeture établissement'!$A$2:$A$22;EQUIV($B$8;'Fermeture établissement'!$A$2:$A$22;1)+LIGNES($A$17:$A17)))

Par contre, les jours fermés (feuille Fermeture établissement) doivent impérativement être triés (comme c'est le cas ici).

a+

 

[cimbombom]

Re : Déduire des jours dans une période donnée

Mrromain : merci merci et encore merci ça fonctionne. Tu es le Usain Bolt de la formule excel

 

[cimbombom]

Re : Déduire des jours dans une période donnée

mromain (ou d'autres),

Tout petit bug, sais-tu me dire pourquoi dans l'exemple de mon fichier en pièce jointe, le 04.07.2011 apparait ? Ce jour n'est pas compris dans la période donnée pourtant.

merci encore

 

[mromain]

Re : Déduire des jours dans une période donnée

Re bonjour,

Voici la formule modifiée (en C17, à tirer vers le bas) :

=SI(LIGNES($A$17:$A17)>$B$13;"";INDEX(Vacances;SI(ESTNA(EQUIV($B$8;Vacances;0));EQUIV($B$8;Vacances;1);EQUIV($B$8;Vacances;1)-1)+LIGNES($A$17:$A17)))

a+

 

[cimbombom]

Re : Déduire des jours dans une période donnée

mromain

Merci pour ton aide.

Je n'y arrive malheureusement pas. J'ai tenté également en modifiant le nom de la feuille (vacances scolaires et pas vacances) mais ca ne fonctionne quand même pas.

Je remarque également que le 3 janvier n'est pas inscrit (alors qu'il devrait y être)

 

[mromain]

Re : Déduire des jours dans une période donnée

Re,

Voici la bonne formule. Désolé :

=SI(LIGNES($A$17:$A17)>$B$13;"";INDEX('Vacances scolaires'!$A$2:$A$505;SI(ESTNA(EQUIV($B$8;'Vacances scolaires'!$A$2:$A$505;0));EQUIV($B$8;'Vacances scolaires'!$A$2:$A$505;1);EQUIV($B$8;'Vacances scolaires'!$A$2:$A$505;1)-1)+LIGNES($A$17:$A17)))

a+

 

[cimbombom]

Re : Déduire des jours dans une période donnée

Génial ! Merci encore une fois. La confédération suisse te doit beaucoup

 

[mromain]

Re : Déduire des jours dans une période donnée

Génial ! Merci encore une fois. La confédération suisse te doit beaucoup

J'accepte volontiers d'être rémunéré en boites de chocolat...

a+