Date entre 2 périodes

[vandewinkel]

Salut ts le monde

Dans ma feuille qui resemble à ceci
Col A début de période ; Col B fin de période nbr de Lig: 272

Dans une autre Col E des dates "résultat d'autre feuilles" nbr de ligne indéterminée

Dans la Col F la réponse à la question:

SI la date de E1 se trouve dans la plage entre A1 et B1, ou A2,B2 ... A272 B272?
et la meme chose pour E2 E3 E...

je vois vraiment pas comment faire.
Merci du coup de votre coup de main.

 

[job75]

Re : Date entre 2 périodes

Bonjour vandewinkel,

C'est calme ce matin sur ce forum.

Formule en F1 :

=NON(SOMMEPROD((E1>=A$1:A$272)*(E1<=B$1:B$272)+(E1<=A$1:A$272)*(E1>=B$1:B$272)))+1

J'ai ajouté une autre formule en H1 (recherche de la 1ère ligne) :

=MIN(SI((E1>=A$1:A$272)*(E1<=B$1:B$272)+(E1<=A$1:A$272)*(E1>=B$1:B$272);LIGNE(A$1:A$272)))

C'est une formule matricielle à valider par Ctrl+Maj+Entrée.

Edit : Ah oui, on peut avoir A1 postérieure à B1... J'ai corrigé.

A+

 

[job75]

Re : Date entre 2 périodes

Re,

Formules plus simples en F1 et H1 :

=NON(SOMMEPROD(((E1-A$1:A$272)*(E1-B$1:B$272)<=0)*1))+1

=MIN(SI((E1-A$1:A$272)*(E1-B$1:B$272)<=0;LIGNE(A$1:A$272)))

A+

 

[vandewinkel]

Re : Date entre 2 périodes

Re,

Formules plus simples en F1 et H1 :

=NON(SOMMEPROD(((E1-A$1:A$272)*(E1-B$1:B$272)<=0)*1))+1

=MIN(SI((E1-A$1:A$272)*(E1-B$1:B$272)<=0;LIGNE(A$1:A$272)))

A+

Salut Job75,

Un grand merci pour ta réonse qui me retire une epine du pied. Moi je cherchais une solution avec RecherchV mais j'étais à coté de la plaque.
Je peux encore te demander un complément? car le fichier envoyé est une partie de mon classeur.
J'ai les 2 "col A" et "col B" avec les périodes
dans la "col E" la date à controler et dans la "col F" le resultat 1ou2

mais dans "col C" et "col D" j'ai une reponse qui vient d'une autre feuille avec vrais ou faux => pour dire valable le Mat. Aprem.
avec ta formule je vois encore moins comment la faire pour les 2 col.
avec recherchV j'y arrive mis c'est pas ca.
Tu veux bien jeter un oeil svp.
Un grnad merci

 

[job75]

Re : Date entre 2 périodes

Bonjour,

avec ta formule je vois encore moins comment la faire pour les 2 col.

Donc vous n'avez pas compris comment fonctionne SOMMEPROD...

Une seule formule en F1 à tirer à droite et vers le bas.

1) Fichier (3), la formule n'ayant pas été tirée en ligne 4 :

=NON(SOMMEPROD((($E1-$A$1:$A$272)*($E1-$B$1:$B$272)<=0)[COLOR="Red"]*C1[/COLOR]))+1

2) Fichier (4), j'ai ajouté le test en rouge, si l'on veut 2 quand la cellule colonne E est vide :

=NON(SOMMEPROD([COLOR="Red"]($E1<>"")*[/COLOR](($E1-$A$1:$A$272)*($E1-$B$1:$B$272)<=0)*C1))+1

On met tous les tests que l'on veut dans SOMMEPROD, ET se traduit par *.

Edit : zut j'avais oublié des $...

A+

 

[job75]

Re : Date entre 2 périodes

Re,

Attention, j'avais oublié quelques signes $ dans mes formules, j'ai édité le post précédent.

A+

 

[vandewinkel]

Re : Date entre 2 périodes

Bonjour,


Donc vous n'avez pas compris comment fonctionne SOMMEPROD...

Une seule formule en F1 à tirer à droite et vers le bas.

1) Fichier (3), la formule n'ayant pas été tirée en ligne 4 :

=NON(SOMMEPROD((($E1-$A$1:$A$272)*($E1-$B$1:$B$272)<=0)[COLOR="Red"]*C1[/COLOR]))+1

2) Fichier (4), j'ai ajouté le test en rouge, si l'on veut 2 quand la cellule colonne E est vide :

=NON(SOMMEPROD([COLOR="Red"]($E1<>"")*[/COLOR](($E1-$A$1:$A$272)*($E1-$B$1:$B$272)<=0)*C1))+1

On met tous les tests que l'on veut dans SOMMEPROD, ET se traduit par *.

Edit : zut j'avais oublié des $...

A+

Un super GRAND merci c'est tip-top ce dont j'ai besoin.
Encore merci Job75