Autres Date automatique en fonction du mois et de l'année sans dimanche

Fitgy

XLDnaute Junior
Bonjour à tous!

J'apprends tout doucement à utiliser Excel sans Macro mais qu’avec des formules! Ma société passe par un sharepoint pour avoir excel et nombreuses macros ne fonctionnent pas ou plante avec j'essaye donc d'éviter au maximum de les utiliser...
C'est là que j'ai besoin d'aide je me retrouve bloqué face à une choses toutes bête mais je n'y arrive vraiment pas.

J'ai mon mois en en B4 et mon année en E4. J'ai besoin qu'à partir de A10 mes dates ce mettent automatiquement en fonction de mon année et de mon mois. J'ai utilisé la fonction : =DATE(ANNEE(E4);MOIS(B4);1) mais à priori il y a quelque chose que je fais mal pourrais-je avoir une explication s'il vous plaît? Ou Alors ce n'est juste pas la bonne formule.

Si éventuellement on pouvait faire en sorte que les dimanche ne soit pas pris en compte ce serait le top du top !!

Merci d'avance,
 

Pièces jointes

  • Suivi densité tanks P6 en cours.xlsx
    11 KB · Affichages: 9
Solution
Bonjour à tous
En une seule formule en A10 à tirer vers le bas
VB:
=SERIE.JOUR.OUVRE.INTL(SOMME("1/"&$B$4&"/"&$E$4)-1;LIGNES($1:1);"0000001")
Pour éviter d'empiéter sur le mois suivant:
Code:
=SI(MOIS(SERIE.JOUR.OUVRE.INTL(SOMME("1/"&$B$4&"/"&$E$4)-1;LIGNES($1:1);"0000001"))=MOIS(SOMME("1/"&$B$4&"/"&$E$4));SERIE.JOUR.OUVRE.INTL(SOMME("1/"&$B$4&"/"&$E$4)-1;LIGNES($1:1);"0000001");"")

Cordialement

vgendron

XLDnaute Barbatruc
Hello
je te propose la solution suivante:
1) créer une liste "ListeMois" pour alimenter une liste de validation de ta cellule B4 formatée pour afficher le mois en toutes lettres
2) formule pour donner le premier jour du mois de l'année (en E4
3) formule en A10 pour donner le premier jour HORS dimanche
4) formule en A11 et jusqu'en bas pour le reste
 

Pièces jointes

  • Suivi densité tanks P6 en cours.xlsx
    12.9 KB · Affichages: 13

Efgé

XLDnaute Barbatruc
Bonjour à tous
En une seule formule en A10 à tirer vers le bas
VB:
=SERIE.JOUR.OUVRE.INTL(SOMME("1/"&$B$4&"/"&$E$4)-1;LIGNES($1:1);"0000001")
Pour éviter d'empiéter sur le mois suivant:
Code:
=SI(MOIS(SERIE.JOUR.OUVRE.INTL(SOMME("1/"&$B$4&"/"&$E$4)-1;LIGNES($1:1);"0000001"))=MOIS(SOMME("1/"&$B$4&"/"&$E$4));SERIE.JOUR.OUVRE.INTL(SOMME("1/"&$B$4&"/"&$E$4)-1;LIGNES($1:1);"0000001");"")

Cordialement
 
Dernière édition:

Efgé

XLDnaute Barbatruc
Re
Et une spéciale 365 à tirer vers le bas
VB:
=LET(DateDeb;SOMME("1/"&$B$4&"/"&$E$4)-1;Ladate;SERIE.JOUR.OUVRE.INTL(DateDeb;LIGNES($1:1);"0000001");SI(MOIS(Ladate)=MOIS(DateDeb)+1;Ladate;""))
ou en matricielle dynamique :
VB:
=LET(DateDeb;SOMME("1/"&$B$4&"/"&$E$4)-1;Ladate;SERIE.JOUR.OUVRE.INTL(DateDeb;LIGNE($1:31);"0000001");SI(MOIS(Ladate)=MOIS(DateDeb)+1;Ladate;""))
Cordialement
 
Dernière édition:

Discussions similaires

Statistiques des forums

Discussions
311 711
Messages
2 081 799
Membres
101 818
dernier inscrit
tiftouf5757