Option Explicit
Private WithEvents CL As ComboBoxLiées
Private LCou As Long, VLgn()
'
Private Sub UserForm_Initialize()
Set CL = New ComboBoxLiées
CL.Plage FeuiCompét.Rows(2)
CL.Add Me.ComboUNITE, "B"
CL.Add Me.ComboMETIER, "C"
CL.CouleurSympa
CL.Actualiser
End Sub
'
Private Sub CL_Change(ByVal Complet As Boolean, ByVal NbrLgn As Long)
If NbrLgn = 1 Then Exit Sub
LCou = 0
ReDim VLgn(1 To 1, 1 To 13)
GarnirTBx
BtnValider.Enabled = Complet
BtnValider.Caption = "Ajouter (Entrée)"
BtnSupprimer.Enabled = False
BtnQuitter.Caption = IIf(Complet, "Annuler", "Effacer") & " (Echap)"
End Sub
'
Private Sub CL_BingoUn(ByVal Ligne As Long)
LCou = Ligne
VLgn = CL.PlgTablo.Rows(LCou).Resize(, 13).Value
GarnirTBx
BtnValider.Enabled = True
BtnValider.Caption = "Modifier (Entrée)"
BtnSupprimer.Enabled = True
BtnQuitter.Caption = "Annuler (Echap)"
End Sub
'
Private Sub GarnirTBx()
Dim C As Long
For C = 1 To 5
Me("Text" & C & "KTECH").Text = VLgn(1, 3 + C)
Me("Text" & C & "KPRO").Text = VLgn(1, 8 + C)
Next C
End Sub
'
Private Sub BtnQuitter_Click()
If CL.ChangéÀLEchap Then Exit Sub
Select Case Left$(BtnQuitter.Caption, 1)
Case "A": GarnirTBx: BtnQuitter.Caption = "Effacer (Echap)"
Case "E": CL.Nettoyer: BtnQuitter.Caption = "Quitter (Echap)"
Case "Q": Unload Me: End Select
End Sub
'
Private Sub BtnValider_Click()
Dim C As Long
If LCou = 0 Then
CL.ValeursVers VLgn
LCou = CL.PlgTablo.Rows.Count
CL.PlgTablo.Rows(LCou).Copy
CL.PlgTablo.Rows(LCou).Insert
Application.CutCopyMode = False
LCou = LCou + 1: End If
For C = 1 To 5
VLgn(1, 3 + C) = Me("Text" & C & "KTECH").Text
VLgn(1, 8 + C) = Me("Text" & C & "KPRO").Text
Next C
CL.PlgTablo.Rows(LCou).Resize(, 13).Value = VLgn
CL.Actualiser
End Sub
'
Private Sub BtnSupprimer_Click()
CL.PlgTablo.Rows(LCou).Delete
CL.Actualiser
End Sub