Microsoft 365 correspondance date comprise entre deux dates

[moostick]

Bonjour,

Je cherche à faire une formule qui me permets de mettre une correspondance en face d'une date si celle-ci est comprise en deux dates.
J'ai essayé via une recherchev mais ca ne fonctionne pas car il faut pouvoir parcourir l'ensemble de mon tableau source pour afficher la correspondance dans mon tableau de destination.

Pourriez-vous m'apporter votre aide car je sèche ?

Je vous remercie par avance de l'attention que vous accorderez à ma demande et de l'aide que vous pourrez m'apporter.

Je vous joins une simulation simplifiée de ce que je souhaite réaliser, un exemple parlera surement mieux que mon explication.

 

[chris]

Bonjour

=SIERREUR(INDEX($D$2:$D$12;MAX(SI(($B$2:$B$12<=G2)*(G2<=$C$2:$C$12);LIGNE($D$2:$D$12)-1;-1)));"")

 

[job75]

Bonjour moostick, chris,

Ou aussi :

=SIERREUR(INDEX(D$2:D$12;EQUIV(1;(B$2:B$12<=G2)*(G2<=C$2:C$12);0));"")

Comme celle de chris elle nécessite la validation matricielle par Ctrl+Maj+Entrée.

A+

 

[chris]

Bonjour

Plus efficace !

Comme celle de chris elle nécessite la validation matricielle par Ctrl+Maj+Entrée.

Plus sur 365

 

[Hasco]

Bonjour,

Encore une autre en H2 à tirer vers le bas pour 365 et 2021 :

=FILTRE($D$2:$D$12;($G2>=$B$2:$B$12)*($G2<=$C$2:$C$12);"-")

Cordialement

 

[moostick]

Bonjour à tous,

Merci beaucoup pour vos réponses . Ca fonctionne très bien dans l'exemple, je vous en remercie.

Néanmoins, j'ai oublié du préciser une chose essentielle, dans mon cas réel, mes tableaux sont beaucoup plus grands et les ID diffèrent. Ici ca fonctionne très bien car l'ID unique 17 est renseigné.

Sauriez-vous me l'adapter pour que ça fonctionne avec l'ensemble des ID renseignés dans un même tableau ? Je vous remets un exemple simplifié.

Je suis vraiment désolé de le préciser après coup.

 

[job75]

Il suffit de rajouter un critère :

=SIERREUR(INDEX(D$2:D$14;EQUIV(1;(A$2:A$14=F2)*(B$2:B$14<=G2)*(G2<=C$2:C$14);0));"")

 

[Hasco]

Bonjour,

Je l'attendais celle-là 🙂

Voici pour la fonction filtre dans laquelle il est facile de modifier les critères

=FILTRE($D$2:$D$14;($G2>=$B$2:$B$14)*($G2<=$C$2:$C$14)*($F2=$A$2:$A$14);"-")

 

[chris]

RE à tous

Et en mettant la base en tableau structuré nommé Absences

=FILTRE(Absences[motif];($G2>=Absences[début abs])*($G2<=Absences[fin abs])*(Absences[ID]=F2);"-")

 

[moostick]

Ca à l'air de fonctionner ! merci beaucoup