Microsoft 365 copier une cellule dans une autre feuille sous condition

M

mlleh22

XLDnaute Nouveau
Bonjour, je me permet de vous contacter pour vous demander de l'aide dans le cadre d'un projet.
Je suis à la recherche d'une macro pour copier le numéro de ticket(A3),(A12),(A21), ect, dans les autres onglets.

EXPLICATION:
Par exemple, je souhaiterais que lorsque que je rentre Matthieu dans la ligne "gestionnaire" le tableau 1 soit directement envoyé dans la page consacrée à Matthieu (feuille 2).
Capture 1.PNG

capture 2.PNG

Merci beaucoup pour votre aide, si vous avez besoin de plus de renseignements n'hésité pas.
En attente de votre retour

Cordialement
 
Trier par date Trier par votes
S

soan

XLDnaute Barbatruc
Inactif
Bonjour mlleh22,

Bienvenue sur le site XLD ! :)

je te propose le fichier Excel joint ci-dessous.

* en B11, saisis "NADEGE" ➯ feuille "2-Nadège", en A2 : 1

* en B20, saisis "MATTHIEU" ➯ feuille "1-Matthieu", en A2 : 2

remarque : il y a écrit : « INFO: nous souhaitons que le numéro du ticket apparaisse dans la colonne A. Le gestionnaire complétera manuellement l'état du ticket. » et « Par exemple le ticket numéro 2 est Matthieu alors copier le numéro du ticket A12 (feuille 1) dans A2 automatiquement. » ; ce que tu as mis pour "EXPLICATION:" ne concorde pas ! 😜

si besoin, tu peux demander une adaptation.
à te lire pour avoir ton avis. 😉​

soan
 

Pièces jointes

  • Exo mlleh22.xlsm
    24.1 KB · Affichages: 10
Dernière édition:
Vote positif 0 Vote négatif
M

mlleh22

XLDnaute Nouveau
soan à dit:
Bonjour mlleh22,

Bienvenue sur le site XLD ! :)

je te propose le fichier Excel joint ci-dessous.

* en B11, saisis "NADEGE" ➯ feuille "2-Nadège", en A2 : 1

* en B20, saisis "MATTHIEU" ➯ feuille "1-Matthieu", en A2 : 2

remarque : il y a écrit : « INFO: nous souhaitons que le numéro du ticket apparaisse dans la colonne A. Le gestionnaire complétera manuellement l'état du ticket. » et « Par exemple le ticket numéro 2 est Matthieu alors copier le numéro du ticket A12 (feuille 1) dans A2 automatiquement. » ; ce que tu as mis pour "EXPLICATION:" ne concorde pas ! 😜

si besoin, tu peux demander une adaptation.
à te lire pour avoir ton avis. 😉​

soan
Cliquez pour agrandir...
Bonjour, merci beaucoup pour votre aide, vous nous avez bien aidé!

Pour l'instant il n'y a que 3 tickets or par la suite, il n'y en aura beaucoup plus. Est-ce possible de ne pas écrasé le premier ticket?

Par exemple sur le fichier joint, nous avons attribué l'essemble des tickets à Matthieu, nous constatons que dans son onglet, seul le dernier ticket attribué est mentionné dans la cellule A2. Nous souhaitons qu'à chaque nouveau ticket, qu'il soit noté en dessous (par exemple A4,A5,A6...)

Et j'ai également relevé un autre problème, lorsque je note par exemple Lætitia, pour le ticket 3, or je voulait mettre Franck, le numéro du ticket reste dans la feuille de Lætitia, or il ne faudrait pas que cela y reste. Est-ce possible de faire quelque chose pour changer cela?

Encore merci
Cordialement
 

Pièces jointes

  • excel programmé.xlsm
    25.3 KB · Affichages: 4
Vote positif 0 Vote négatif
S

soan

XLDnaute Barbatruc
Inactif
@mlleh22

ton fichier en retour. :)

* en B20, saisis "MATTHIEU" ➯ feuille "1-Matthieu", en A2 : 2

* en B38, saisis "MATTHIEU" ➯ feuille "1-Matthieu", en A3 : 4

* en B47, saisis "MATTHIEU" ➯ feuille "1-Matthieu", en A4 : 5

ainsi, ça n'écrase plus le 1er ticket mais ça les met les en dessous ; code VBA :
​
VB: 
Option Explicit

Private Function SansAccents(chn$) As String
  Dim c01$, c02$, p%
  For p = 1 To Len(chn)
    c01 = Mid$(chn, p, 1): c02 = "@"
    Select Case c01
      Case "á", "à", "â", "ä", "ã", "å": c02 = "a"
      Case "é", "è", "ê", "ë": c02 = "e"
      Case "í", "ì", "î", "ï": c02 = "i"
      Case "ó", "ò", "ô", "ö", "õ", "ø": c02 = "o"
      Case "ú", "ù", "û", "ü": c02 = "u"
      Case "ñ": c02 = "n"
      Case "ç": c02 = "c"
      Case "š": c02 = "s"
      Case "ý", "ÿ": c02 = "y"
      Case "ž": c02 = "z"
    End Select
    If c02 <> "@" Then Mid$(chn, p, 1) = c02
  Next p
  SansAccents = chn
End Function

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim lig&, gst$, chn$, i%
  With Target
    If .CountLarge > 1 Then Exit Sub
    If .Column <> 2 Then Exit Sub
    lig = .Row: If lig < 11 Then Exit Sub
    If (lig - 3) Mod 9 <> 8 Then Exit Sub
    gst = .Value: If gst = "" Then Exit Sub
    For i = 2 To Worksheets.Count
      chn = Worksheets(i).Name
      chn = Right$(chn, Len(chn) - 2)
      If chn <> "" Then
        chn = SansAccents(LCase$(chn))
        If chn = LCase$(gst) Then
          With Worksheets(i)
            lig = .Cells(Rows.Count, 1).End(3).Row + 1
            .Cells(lig, 1) = Target.Offset(-8, -1)
          End With
        End If
      End If
    Next i
  End With
End Sub

je n'ai rien fait pour ta 2ème demande concernant une correction comme Franck au lieu de Lætitia car ça devient compliqué et je crois que « le jeu n'en vaut pas la chandelle » ; regarde les futures réponses, au cas où un autre intervenant veux essayer et peut te trouver une solution.​

soan
 

Pièces jointes

  • excel programmé.xlsm
    24.7 KB · Affichages: 3
Vote positif 0 Vote négatif
M

mlleh22

XLDnaute Nouveau
soan à dit:
@mlleh22

ton fichier en retour. :)

* en B20, saisis "MATTHIEU" ➯ feuille "1-Matthieu", en A2 : 2

* en B38, saisis "MATTHIEU" ➯ feuille "1-Matthieu", en A3 : 4

* en B47, saisis "MATTHIEU" ➯ feuille "1-Matthieu", en A4 : 5

ainsi, ça n'écrase plus le 1er ticket mais ça les met les en dessous ; code VBA :
​
VB: 
Option Explicit

Private Function SansAccents(chn$) As String
  Dim c01$, c02$, p%
  For p = 1 To Len(chn)
    c01 = Mid$(chn, p, 1): c02 = "@"
    Select Case c01
      Case "á", "à", "â", "ä", "ã", "å": c02 = "a"
      Case "é", "è", "ê", "ë": c02 = "e"
      Case "í", "ì", "î", "ï": c02 = "i"
      Case "ó", "ò", "ô", "ö", "õ", "ø": c02 = "o"
      Case "ú", "ù", "û", "ü": c02 = "u"
      Case "ñ": c02 = "n"
      Case "ç": c02 = "c"
      Case "š": c02 = "s"
      Case "ý", "ÿ": c02 = "y"
      Case "ž": c02 = "z"
    End Select
    If c02 <> "@" Then Mid$(chn, p, 1) = c02
  Next p
  SansAccents = chn
End Function

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim lig&, gst$, chn$, i%
  With Target
    If .CountLarge > 1 Then Exit Sub
    If .Column <> 2 Then Exit Sub
    lig = .Row: If lig < 11 Then Exit Sub
    If (lig - 3) Mod 9 <> 8 Then Exit Sub
    gst = .Value: If gst = "" Then Exit Sub
    For i = 2 To Worksheets.Count
      chn = Worksheets(i).Name
      chn = Right$(chn, Len(chn) - 2)
      If chn <> "" Then
        chn = SansAccents(LCase$(chn))
        If chn = LCase$(gst) Then
          With Worksheets(i)
            lig = .Cells(Rows.Count, 1).End(3).Row + 1
            .Cells(lig, 1) = Target.Offset(-8, -1)
          End With
        End If
      End If
    Next i
  End With
End Sub

je n'ai rien fait pour ta 2ème demande concernant une correction comme Franck au lieu de Lætitia car ça devient compliqué et je crois que « le jeu n'en vaut pas la chandelle » ; regarde les futures réponses, au cas où un autre intervenant veux essayer et peut te trouver une solution.​

soan
Cliquez pour agrandir...
Je vous remercie énormément, merci merci beaucoup
Tout fonctionne :))
 
Vote positif 0 Vote négatif
S

soan

XLDnaute Barbatruc
Inactif
Bonjour mlleh22,

J'ai trouvé une solution pour la suppression et le changement d'un gestionnaire. 😊

* sur la feuille "1-Matthieu", tu peux voir que A2 est vide.
* va sur la feuille "2-Nadège" ; A2 est vide aussi.
* va sur la feuille "Générale" ; en B11, saisis "NADEGE" et valide.
* vérifie que sur "2-Nadège", il y a 1 en A2.

* va sur "Générale" ; tu es en B11 ; appuie sur la touche Suppression.
* va sur "2-Nadège" ; tu peux voir que le 1 de A2 a été supprimé.

* va sur "Générale" ; en B11, saisis "MATTHIEU" et valide.
* va sur "1-Matthieu" ; il y a 1 en A2 ; normal ... sauf que t'as fait une erreur de saisie : tu aurais dû mettre "NADEGE" et pas "MATTHIEU" ! ne change rien, et retourne sur la 1ère feuille.
* sur "Générale", en B11, sans avoir besoin de supprimer "MATTHIEU", saisis à la place "NADEGE" et valide.
* va sur "1-Matthieu" ; tu peux voir que le 1 de A2 a été supprimé ; va sur "2-Nadège" ; tu peux voir qu'il y a 1 en A2 ➯ la correction a bien été effectuée. :)

ce que j'écris maintenant est par rapport au dernier paragraphe de ton post #3 : tu pourras faire de même pour ton ticket 3, si tu as saisi Lætitia alors que tu aurais voulu saisir Franck : il suffit donc de saisir "Franck" à la place de "Lætitia", sans devoir supprimer d'abord "Lætitia".​

je te laisse faire d'autres tests.

si besoin, tu peux demander une adaptation.
à te lire pour avoir ton avis. 😉

VB: 
Option Explicit

Private Function SansAccents(chn$) As String
  Dim c01$, c02$, p%
  For p = 1 To Len(chn)
    c01 = Mid$(chn, p, 1): c02 = "@"
    Select Case c01
      Case "á", "à", "â", "ä", "ã", "å": c02 = "a"
      Case "é", "è", "ê", "ë": c02 = "e"
      Case "í", "ì", "î", "ï": c02 = "i"
      Case "ó", "ò", "ô", "ö", "õ", "ø": c02 = "o"
      Case "ú", "ù", "û", "ü": c02 = "u"
      Case "ñ": c02 = "n"
      Case "ç": c02 = "c"
      Case "š": c02 = "s"
      Case "ý", "ÿ": c02 = "y"
      Case "ž": c02 = "z"
    End Select
    If c02 <> "@" Then Mid$(chn, p, 1) = c02
  Next p
  SansAccents = chn
End Function

Private Sub IndexFX(gst$, idx%)
  Dim chn$, i%: idx = 0
  For i = 2 To Worksheets.Count
    chn = Worksheets(i).Name
    chn = Right$(chn, Len(chn) - 2)
    If chn <> "" Then
      chn = SansAccents(LCase$(chn))
      If chn = LCase$(gst) Then idx = i: Exit For
    End If
  Next i
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim tck As Range, cel As Range, gst1$, gst2$, idx%, lig&
  With Target
    If .CountLarge > 1 Then Exit Sub
    If .Column <> 2 Then Exit Sub
    lig = .Row: If lig < 11 Then Exit Sub
    If (lig - 3) Mod 9 <> 8 Then Exit Sub
    Set tck = .Offset(-8, -1): gst2 = .Value
  End With
  With Application
    .ScreenUpdating = 0: .EnableEvents = 0: .Undo
    gst1 = Target: Target = gst2: .EnableEvents = -1
  End With
  If gst1 <> "" And (gst2 = "" Or gst2 <> gst1) Then
    IndexFX gst1, idx
    If idx > 0 Then
      With Worksheets(idx)
        Set cel = .Columns(1).Find(tck, , -4163, 1, 1)
        If Not cel Is Nothing Then .Rows(cel.Row).Delete
      End With
    End If
  End If
  If gst2 = "" Then Exit Sub
  IndexFX gst2, idx: If idx = 0 Then Exit Sub
  With Worksheets(idx)
    lig = .Cells(Rows.Count, 1).End(3).Row + 1
    .Cells(lig, 1) = tck
  End With
End Sub

soan
 

Pièces jointes

  • excel programmé v2.xlsm
    26.9 KB · Affichages: 1
Dernière édition:
Vote positif 0 Vote négatif

Discussions similaires

M
  • Question
Autres Copier la ligne complète d’un tableau dans un autre tableau sous condition
Réponses
1
Affichages
296
djidji59430
djidji59430
jeanmi
  • Question
XL 2010 Copier cellule avec mise en forme d’une feuille sur l’autre
Réponses
12
Affichages
517
jeanmi
jeanmi
S
  • Résolu(e)
XL 2016 Copier/Coller des cellules en multipliant par des cellules sur une autre page
Réponses
3
Affichages
557
migau
migau
P
  • Question
XL 2021 Code VBA pour copier coller des données de cellules d'une feuille a une autre
Réponses
4
Affichages
602
phoceenjo
P
R
  • Question
XL 2010 Copier des lignes de données de plusieurs feuilles dans une seule
Réponses
5
Affichages
503
sylvanu
sylvanu
P
  • Question
XL 2019 Copier des cellules d'une feuille sur une autre
Réponses
2
Affichages
593
phoceenjo
P
Nadou69
  • Résolu(e)
XL 2019 Erreur dans ma macro
Réponses
9
Affichages
358
Nadou69
Nadou69
Droopyougo
  • Résolu(e)
Microsoft 365 Remplir une cellule avec la valeur d'une autre sous condition
Réponses
2
Affichages
291
Droopyougo
Droopyougo
S
  • Résolu(e)
Microsoft 365 Copier automatiquement sur une ligne sur une autre feuille si la date est supérieur à une date définie
2
Réponses
17
Affichages
1 K
S.J
S
M
  • Question
XL 2016 Remplacer nombres et symboles depuis une liste dans une autre feuille
Réponses
2
Affichages
255
Marjorie73
M
A
  • Question
XL 2021 Macro copier dans un fichier Excel sur Sharepoint
Réponses
1
Affichages
232
vgendron
vgendron
M
  • Question
XL 2019 Transposer des données d'une feuille vers une autre sous forme de synthèse
Réponses
8
Affichages
267
mromain
mromain
S
  • Résolu(e)
XL 2016 copier des données d'une feuille à une autre selon critères et protection de la feuille 1
Réponses
6
Affichages
451
steph_29120
S
M
  • Question
XL 2019 Copier des lignes les unes a la suite des autres dans une autre feuille sous conditions et seulement certaines colonnes
Réponses
7
Affichages
649
MGH
M
chris6999
  • Question
Microsoft 365 Copier une plage vers une autre feuille depuis un USF
Réponses
4
Affichages
199
chris6999
chris6999
H
  • Résolu(e)
XL 2016 Copier cellule dans un autre onglets
2
Réponses
16
Affichages
356
Phil69970
Phil69970
D
  • Question
XL 2016 Plusieurs conditions dans une cellule
2
Réponses
16
Affichages
593
TooFatBoy
TooFatBoy
Sellig
  • Résolu(e)
XL 2019 Créer un lien Hypertexte ancré à un mot sur une autre feuille
Réponses
8
Affichages
358
sylvanu
sylvanu
N
  • Question
Microsoft 365 afficher/masquer des lignes en fonction de la valeur d'une cellule qui aura été renseignée par une autre feuille (via un copier/collé automatique)
Réponses
5
Affichages
459
Nel'
N
T
  • Question
XL 2021 Reporter sous forme de liste dans une cellule les donnés contenues dans plusieurs cellules et cela sous condition
Réponses
2
Affichages
160
thioff
T

Membres actuellement en ligne

22 membres et 399 invités.

Partager cette page

Tutos vidéos

Power Query : Ajouter des requêtes (Excel et Power BI)
Créez votre première fonction LAMBDA dans Excel en 3 étapes!
LAMBDA, l’arme secrète de Microsoft pour Excel !
Office Insider - Découvrez les nouveautés Excel avant tout le monde

Statistiques des forums

Discussions
315 242
Messages
2 117 693
Membres
113 270
dernier inscrit
Maximax