Copier le contenu

[edi]

Bonjour à tous,
J'ai une problématique à traiter sur excel, je ne sais pas si une formule excel permet de le faire ou une macro....
Je vous la soumets.
Merci d'avance de l'intérêt que vous accorderez à cette requête.

Si dans la colonne E de la "feuil1", nous retrouvons le nom "jaune" alors copier
vers la cellule "A1" de la "feuil3" le contenu de la cellule de la colonne A
correspondant à la ligne où le nom jaune a été retrouvé.
Dans l'exemple ci-joint si la fonction ou la macro fonctionne bien, nous devons copier les noms "Awa" et "Sibiri" respectivement dans les cellules A1 et A2 dans la feuil3. et ainsi de suite, on copie au fur et mesure les noms retrouvés dans la colonne A....

PS: Le fichier de l'exemple est joint.

 

[CISCO]

Re : Copier le contenu

Bonjour

Une possibilité parmi d'autres en pièce jointe, avec une formule matricielle, donc à valider en appuyant sur Ctrl+shift tempo+entrer.

@ plus

 

[st007]

Re : Copier le contenu

Bonsoir,
En feuil3 A1 et en matriciel avec un vrai tableau en feuil1

=SIERREUR(INDEX(Tableau1[Colonne1];PETITE.VALEUR(SI(Tableau1[Colonne5]="jaune";LIGNE(Tableau1[Colonne5]));LIGNE(1:1))-LIGNE(Tableau1[#En-têtes]));"")

Bonsoir cisco, je vai voir si tu as la même ..
et cours de rattrapage
Ce lien n'existe plus

PS: avec pièce jointe puisque fournie, j'ai sélectionné tes données en feuil1 puis onglet insertion-tableau

 

[DoubleZero]

Re : Copier le contenu

Bonjour à toutes et à tous,

Une autre suggestion avec ce code, logé dans un module standard.

Sub Contenu_copier()
Dim i As Long
Application.ScreenUpdating = False
Sheets("Feuil3").Columns(1).Clear
For i = Cells(Rows.Count, "e").End(xlUp).Row To 2 Step -1
If Range("e" & i) = "jaune" Then Range("a" & i).Copy Destination:=Sheets("Feuil3").Range("a" & Rows.Count).End(xlUp)(2)
Next i
Application.ScreenUpdating = True
End Sub

A bientôt

 

[Staple1600]

Re : Copier le contenu

Bonsoir à tous


Une autre, autre suggestion (qui évite la boucle)

Sub CopieParFiltreElab()
Dim fd As Worksheet: Set fd = Sheets("Feuil3")
With Sheets("Feuil1").Range("A1")
    .Value = "ITEM1"
    .AutoFill Destination:=.Resize(, 5), Type:=xlFillDefault
fd.Range("G1:G2") = Application.Transpose(Array("ITEM5", "jaune"))
    .Range("A1:E6").AdvancedFilter Action:=2, CriteriaRange:=fd.Range("G1:G2"), CopyToRange:=fd.Range("A1"), Unique:=False
    .Resize(, 5) = Empty
End With
fd.Rows(1) = Empty
fd.Range("G1:G2") = Empty
End Sub

NB: Cette solution fonctionne aussi très bien en appliquant le filtre élaboré manuellement donc sans macros.

 

[Si...]

Re : Copier le contenu

Dans la page de code de la feuille de départ


pour Double0 : doubleclic sur E1 pour avoir en Feuil3 tous les noms en jaune

Private Sub Worksheet_BeforeDoubleClick(ByVal R As Range, Cancel As Boolean)
  Dim C As Range
  With Sheets("Feuil3")
    .Rows("2:65000").Clear
    For Each C In [E:E].SpecialCells(2)
      If C = "jaune" Then .[A65000].End(xlUp)(2) = C(1, -3)
    Next
  End With
End Sub

pour Staple : clic sur [A1] pour avoir en Feuil2 tous les noms en jaune

Private Sub Worksheet_SelectionChange(ByVal R As Range)
  If R(1, 1).Address <> "$A$1" Then Exit Sub
  Sheets("Feuil2").Rows("2:65000").Clear
  [E1].AutoFilter 5, "jaune"
  [A2:A6].SpecialCells(12).Copy Sheets("Feuil2").[A2]
  [E1].AutoFilter
  R(1, 2).Select
End Sub

Et surtout pour le plaisir de saluer mes cher(e)s collègues

 

[edi]

Re : Copier le contenu

Bonjour Double Zéro,
Merci pour la macro, elle fonctionne à merveille, par contre, le souci est la mise à jour.
En effet, l'idée est que lorsqu'on ajoute une nouvelle ligne dans la feuil1 qui répond au même critère (couleur jaune), la macro puisse automatiquement mettre à jour la feuil3.
Merci encore une fois de ton aide.

Bien Cordialement
Edi

 

[DoubleZero]

Re : Copier le contenu

Bonjour à toutes et à tous,

Bonjour Double Zéro,
Merci pour la macro, elle fonctionne à merveille... Merci encore une fois de ton aide...

@ edi,

Merci pour ce retour mais... il ne faut pas oublier que CISCO , st007 , Staple1600 et Si ont également offert de leur temps pour répondre à :

Merci d'avance de l'intérêt que vous accorderez à cette requête.

Quant à :

... la macro, elle fonctionne à merveille, par contre, le souci est la mise à jour.
En effet, l'idée est que lorsqu'on ajoute une nouvelle ligne dans la feuil1 qui répond au même critère (couleur jaune), la macro puisse automatiquement mettre à jour la feuil3...

J'avoue ne pas comprendre ledit souci.

A bientôt

 

[edi]

Re : Copier le contenu

Merci Double Zéro,
Je tiens à m'excuser pour le retard de ma réponse et je tiens remercier CISCO , st007 , Staple1600, SI et tout ceux qui ont pris de leur temps pour réfléchir sur ce sujet. Merci à vous.

Pour le souci que j'ai, c'est erreur de ma part, j'ai un peu modifié la maro, du coup j'avais pas le résultat escompté.
Merci encore et désolé pour le désagrément.

Bien Cordialement
Edi

 

[st007]

Re : Copier le contenu

Bonjour,
Merci aussi du retour ..., pour la mise à jour, aucun soucis par formule tant qu'elle est suffisamment étirée...
par macro, tu peux utiliser l’événementielle private sub worksheet_activate() logé dans la feuille de destination .