XL 2021 copier des donnees en dessous un mot

[cg1980]

Bonjour
dans le fichier ci joint, via une maco j'aimerais copier les données de sheet 1 vers sheets 3

La difficulté est que je dois prendre les données qui sont en dessous du mot specifiques "NRegister", celui n'est pas toujours au meme endroit c'est pourquoi je dois le prendre comme critere

Donc en resume je prends les données en dessous de NRegister en sheet1 et les copie en Sheet2

merci de votre aide

 

[sylvanu]

Bonjour CG,
Un essai en PJ avec :

Sub Copie()
    Dim DL%, PL%, T
    On Error GoTo Fin                                                   ' Si NRegister n'est pas trouvé
    DL = [B610000].End(xlUp).Row                                        ' DL dernière ligne à copier
    PL = 1 + Application.Match("NRegister", [B:B], 0)                   ' PL première ligne à copier
    T = Range(Cells(PL, "B"), Cells(DL, "P"))                           ' Copie de la plage dans un array
    With Sheets("Sheet3")
        DLsheet3 = .[A10000].End(xlUp).Row + 1                          ' Première ligne dispo en Sheet3
        .Cells(DLsheet3, "A").Resize(UBound(T, 1), UBound(T, 2)) = T    ' Copie des données
    End With
Exit Sub
Fin:
MsgBox "NRegister n'est pas trouvé en colonne B."                       ' Message d'erreur si non trouvé
End Sub

A noter que je cherche NRegister seulement en colonne B.

 

[job75]

Bonsoir cg1980, sylvanu,

Comme rien n'est précisé on peut essayer cette macro :

Private Sub Worksheet_Activate()
Dim c As Range
Application.ScreenUpdating = False
Cells.Delete 'RAZ
Set c = Sheets("Sheet1").Cells.Find("NRegister", , xlValues, xlWhole)
If c Is Nothing Then Exit Sub
c.Resize(c.End(xlDown).Row - c.Row + 1, 15).Copy [A1]
Columns.AutoFit 'ajustement largeurs
End Sub

Elle est placée dans le code de Sheet3 et se déclenche automatiquement quand on active la feuille.

A+

 

[cg1980]

impressionant d'efficacité, merci à vous deux. Nregister sera bien toujours en colonne B, c'est correct