XL 2019 copier des données à partir d'un autre fichier excel VBA

Guillaumeg3

XLDnaute Junior
Bonjour à tous,

J'essai de créer une macro pour que depuis mon fichier ouvert, je pouisse importer des données d'un autre fichier excel situé dans le même dossier quelque soit son nom où seul une feuille est rempli (Dans ce dossier il n'y aura que le fichier source et le fichier cible)
J'ai essayé le code suivant mais pas de chance
VB:
Sub Importerdonnées()

    Dim filePath As String
    Dim fileName As String
    Dim sourceSheet As Worksheet
    Dim targetSheet As Worksheet
    
 
    filePath = ActiveWorkbook.Path & "\"
    
    fileName = Dir(filePath & "*.xlsx")
    
    If fileName = "" Then
        MsgBox "Aucun fichier Excel n'a été trouvé dans ce dossier.", vbExclamation, "Erreur"
        Exit Sub
    End If
    
  
    Set sourceSheet = Workbooks.Open(filePath & fileName).Worksheets("Feuil1")
    
    
    Set targetSheet = ActiveWorkbook.Worksheets("Feuil1")
    
  
    sourceSheet.Range("A1:BF2").Copy targetSheet.Range("A1")
    
    
    sourceSheet.Parent.Close False
    
 
    MsgBox "Les données ont été importées avec succès.", vbInformation, "Importation terminée"
    
End Sub

En appuyant sur le bouton cela indique le message que cela a été un succès mais aucune données s'affichent...

Merci de votre aide
 

xUpsilon

XLDnaute Accro
Bonjour,

Remplacez
VB:
Set targetSheet = ActiveWorkbook.Worksheets("Feuil1")
par
Code:
Set targetSheet = ThisWorkbook.Worksheets("Feuil1")

Le souci est que l'instruction Workbooks.Open donne le focus au classeur qui vient d'être ouvert. Ainsi, le targetSheet qui appelle le ActiveWorkbook appelle en fait la même feuille que la sourceSheet.

Bonne journée,
 

Discussions similaires

Statistiques des forums

Discussions
313 197
Messages
2 096 115
Membres
106 501
dernier inscrit
axtion