Copier & Coller une sélection sur une autre feuille en VBA

[fironman]

Bonjour à tous,
après de nombreuses recherches et de tests durant deux jours, je ne trouve pas le code qui me convient.
Je voudrais sélectionner une plage de A à I si les dates de la colonne A sont antérieures ou égales à la date du jour. Pour les colorier, par exemple, je fais ce code et pas de problème :
Sub test()
Dim ws As Worksheet
Dim i As Long

Set ws = Worksheets("Frais fixes")
With ws
i = 2
While .Range("A" & i).Value <> ""
If .Range("A" & i).Value <= Date Then
Range("A" & i, "I" & i).Interior.ColorIndex = 7
End If
i = i + 1
Wend
End With

End Sub

Par contre , pour copier cette sélection en entier sur une autre feuille, je n'y arrive pas, mais pas du tout ! Au mieux , je copie la dernière ligne de la sélection mais rien de mieux.
Merci d'aider un débutant.😀

 

[kjin]

Re : Copier & Coller une sélection sur une autre feuille en VBA

Bonjour et bienvenu,
Un petit détour par la charte du forum est fortement conseillé [thread=32841]ICI[/thread]
Tu y apprendras notamment que sans fichier exemple, ce genre de demande à peu de chance d'aboutir
Néanmois, je te suggère de consulter les fils relatifs aux filtres sous excel
A+
kjin

 

[fironman]

Re : Copier & Coller une sélection sur une autre feuille en VBA

Bonjour et bienvenu,
Un petit détour par la charte du forum est fortement conseillé [thread=32841]ICI[/thread]
Tu y apprendras notamment que sans fichier exemple, ce genre de demande à peu de chance d'aboutir
Néanmois, je te suggère de consulter les fils relatifs aux filtres sous excel
A+
kjin

Oui, je sais mais le fichier est volumineux, je continue à chercher ma solution et on verra bien si j'ai des réponses ...ou pas ! 😉

 

[Robert]

Re : Copier & Coller une sélection sur une autre feuille en VBA

Bonjour Fironman, Kjin, bonjour le forum,

T'es pas en vacances Kjin ? Ça baille à Montpeul ?...

Pourquoi ne pas partir d'un fichier vierge respectant la structure de ton original (même nom des plages nommées, des onglets etc..) avec une poignée de données, juste pour l'exemple ?

 

[fironman]

Re : Copier & Coller une sélection sur une autre feuille en VBA

Bonjour Fironman, Kjin, bonjour le forum,

T'es pas en vacances Kjin ? Ça baille à Montpeul ?...

Pourquoi ne pas partir d'un fichier vierge respectant la structure de ton original (même nom des plages nommées, des onglets etc..) avec une poignée de données, juste pour l'exemple ?

Voilà, un mini fichier ci-joint, je voudrais en fait, transférer ou copier les lignes (A:I) <= à la date d'aujourd'hui de "frais fixes" à la 1ère cellule vide de colonne A dans "Dexia" avec effacement de ces plages dans "frais fixes" après la copie.🙄
Genre :
Sub test()
Dim ws As Worksheet
Dim i As Long

Set ws = Worksheets("Frais fixes")
With ws
i = 2
While .Range("A" & i).Value <> ""
If .Range("A" & i).Value <= Date Then
Range("A" & i, "I" & i).copy
sheets("dexia").select
Range("A65536").End(xlUp).Offset(1, 0).Select
selection.copy
End If
i = i + 1
Wend
End With
sheets("frais fixes").select
Selection.Delete Shift:=xlUp
sheets("dexia").select
range("A1").select

End Sub

Qui ne fonctionne pas, évidemment...😕

 

[kjin]

Re : Copier & Coller une sélection sur une autre feuille en VBA

re, salut mon voisin,

T'es pas en vacances Kjin

Bah en fait j'en sais rien...c'est quoi ?!
fironman, mon histoire de filtre ça tiens toujours mais là je vais au boulot
A+
kjin

 

[Guest]

Re : Copier & Coller une sélection sur une autre feuille en VBA

Bonjour le fil,
Hello amis du sud🙂🙂

Proposition:

Sub test()
    Dim Plage As Range, c As Range
    With Worksheets("Frais fixes")
        Set Plage = .Range("A2:A" & .Cells(.Rows.Count, 1).End(xlUp).Row)
    End With
    For Each c In Plage
        If IsDate(c) Then
            If c < Date Then
                With c.Resize(1, 9)
                    .Copy Destination:=Sheets("Dexia").Cells(Rows.Count, 1).End(xlUp).Offset(1)
                    .ClearContents    ' ou .delete xlshiftup pour supprimer
                End With
            End If
        End If
    Next
End Sub

Pas compris la nécéssité de Interior.ColorIndex ni s'il fallait vider les cellules d'origine ou les supprimer. Ci-dessus ça les vide.

A+

 

[fironman]

Re : Copier & Coller une sélection sur une autre feuille en VBA

Merci, je vais tester. la méthode avecInterior.colorindex fonctionnait et pas la même méthode en copier/coller, c'était juste pour montrer mon cheminement, aucun intérêt sinon.

 

[fironman]

Re : Copier & Coller une sélection sur une autre feuille en VBA

Bonjour le fil,
Hello amis du sud🙂🙂

Proposition:

Sub test()
    Dim Plage As Range, c As Range
    With Worksheets("Frais fixes")
        Set Plage = .Range("A2:A" & .Cells(.Rows.Count, 1).End(xlUp).Row)
    End With
    For Each c In Plage
        If IsDate(c) Then
            If c < Date Then
                With c.Resize(1, 9)
                    .Copy Destination:=Sheets("Dexia").Cells(Rows.Count, 1).End(xlUp).Offset(1)
                    .ClearContents    ' ou .delete xlshiftup pour supprimer
                End With
            End If
        End If
    Next
End Sub

Pas compris la nécéssité de Interior.ColorIndex ni s'il fallait vider les cellules d'origine ou les supprimer. Ci-dessus ça les vide.

A+

Ca fonctionne impeccablement bien et je comprends bien tout le cheminement, je suis ravi, merci d'avoir consacré un peu de temps pour m'aider.🙂 A+