Copie d'une cellule par double clic

[ipod]

Bonjour à tous (tes)

Je penche depuis une semaine sur ce problème et n'arrive à aucun résultat.

Je voudrais en étant sur la feuille "Minute devis" pouvoir en double cliquant sur une des cellules (par exemple A 15)
de la ouvrir la feuille " REG " pour ensuite en double cliquant sur une des cellules de
la colonne A " copier le contenu - revenir sur la feuille minute devis pour coller le texte dans la cellule A15.

J’espère que je suis assez clair dans mon explication

Par avance Merci de votre aide.

Phil

 

[job75]

Re : Copie d'une cellule par double clic

Bonjour ipod,

Mettez dans ThisWorkbook le code suivant :

Dim cible As Range 'mémorise la variable

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, _
  ByVal Target As Range, Cancel As Boolean)
If Sh.Name = "Minute devis" Then
  Cancel = True
  Set cible = Target
  Sheets("REG").Visible = True 'au cas où...
  Application.Goto Sheets("REG").[A1], True
ElseIf Sh.Name = "REG" And Target.Column = 1 And Not cible Is Nothing Then
  Cancel = True
  Target.Copy cible 'copier-coller
  Sheets("Minute devis").Visible = True 'au cas où...
  Application.Goto cible
  Set cible = Nothing 'RAZ
End If
End Sub

Important : ne pas oublier la ligne qui mémorise, en haut de la feuille.

A+

 

[job75]

Re : Copie d'une cellule par double clic

Re,

Si le CodeName de la feuille Minute devis est Feuil1,

si le CodeName de la feuille REG est Feuil2,

il est bien mieux d'écrire :

Dim cible As Range 'mémorise la variable

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, _
  ByVal Target As Range, Cancel As Boolean)
If Sh.CodeName = "Feuil1" Then
  Cancel = True
  Set cible = Target
  Feuil2.Visible = True 'au cas où...
  Application.Goto Feuil2.[A1], True
ElseIf Sh.CodeName = "Feuil2" And Target.Column = 1 And Not cible Is Nothing Then
  Cancel = True
  Target.Copy cible
  Feuil1.Visible = True 'au cas où...
  Application.Goto cible
  Set cible = Nothing
End If
End Sub

Ainsi le changement des noms des onglets ne posera pas de problème.

A+

 

[job75]

Re : Copie d'une cellule par double clic

Re, pour terminer,

Bien entendu si l'on s'amuse à supprimer cible la macro beugue...

Alors :

Dim cible As Range 'mémorise la variable

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, _
  ByVal Target As Range, Cancel As Boolean)
If Sh.CodeName = "Feuil1" Then
  Cancel = True
  Set cible = Target
  Feuil2.Visible = True 'au cas où...
  Application.Goto Feuil2.[A1], True
ElseIf Sh.CodeName = "Feuil2" And Target.Column = 1 And Not cible Is Nothing Then
  Cancel = True
  On Error Resume Next 'au cas où cible serait supprimée...
  Target.Copy cible
  Feuil1.Visible = True 'au cas où...
  Application.Goto cible
  Set cible = Nothing
End If
End Sub

A+

 

[ipod]

Re : Copie d'une cellule par double clic

Merci beaucoup Job75,

c'est exactement ce que je voulais.

Merci encore.

Phil