Microsoft 365 convertir un fichier excel en csv

P

patrice3450

XLDnaute Nouveau
Bonjour,
je voudrais automatiser la création de plusieurs fichiers csv à partir de fichiers excel
un fichier excel aura plusieurs classeurs et donc créer un fichier csv de chacun des classeurs pour chaque fichier excel présent dans mon répertoire
merci pour votre aide
 
Trier par date Trier par votes
xUpsilon

xUpsilon

XLDnaute Accro
Bonjour,

Voir le code suivant à adapter à votre besoin, trouvé sur stackoverflow en deux clics.
Code: 
Sub SaveWorksheetsAsCsv()

Dim WS As Excel.Worksheet
Dim SaveToDirectory As String

Dim CurrentWorkbook As String
Dim CurrentFormat As Long

CurrentWorkbook = ThisWorkbook.FullName
CurrentFormat = ThisWorkbook.FileFormat
' Store current details for the workbook
SaveToDirectory = "H:\test\"

For Each WS In Application.ActiveWorkbook.Worksheets
    WS.SaveAs SaveToDirectory & WS.Name, xlCSV
Next

Application.DisplayAlerts = False
ThisWorkbook.SaveAs Filename:=CurrentWorkbook, FileFormat:=CurrentFormat
Application.DisplayAlerts = True
' Temporarily turn alerts off to prevent the user being prompted
'  about overwriting the original file.

End Sub

Bonne journée,
 
Vote positif 0 Vote négatif
job75

job75

XLDnaute Barbatruc
Téléchargez les fichiers joints dans le même dossier (le bureau), ouvrez le fichier Pilote.xlsm et exécutez la macro du bouton :
VB: 
Sub Creer_CSV()
Dim chemin$, fichier$, n&, w As Worksheet, nf&
chemin = ThisWorkbook.Path & "\"
fichier = Dir(chemin) '1er fichier du dossier
Application.ScreenUpdating = False
Application.DisplayAlerts = False 'si un fichier est déjà créé
On Error Resume Next
While fichier <> ""
    If fichier <> ThisWorkbook.Name And (Right(fichier, 5) = ".xlsx" Or Right(fichier, 5) = ".xlsm") Then
        Workbooks(fichier).Close False 'si le fichier est ouvert on le ferme
        With Workbooks.Open(chemin & fichier) 'ouverture du fichier
            n = n + 1
            For Each w In .Worksheets
                nf = nf + 1
                w.Select
                .SaveAs chemin & fichier & "-" & w.Name & ".csv", xlCSV
            Next
            .Close False 'fermeture
        End With
    End If
    fichier = Dir 'fichier suivant
Wend
MsgBox n & " fichier(s) Excel traité(s), " & nf & " fichier(s) CSV créé(s)"
End Sub
 

Pièces jointes

  • Pilote.xlsm
    17.7 KB · Affichages: 5
  • Classeur1.xlsx
    9.2 KB · Affichages: 3
  • Classeur2.xlsx
    9.2 KB · Affichages: 3
Dernière édition:
Vote positif 0 Vote négatif
P

patrice3450

XLDnaute Nouveau
xUpsilon à dit:
Bonjour,

Voir le code suivant à adapter à votre besoin, trouvé sur stackoverflow en deux clics.
Code: 
Sub SaveWorksheetsAsCsv()

Dim WS As Excel.Worksheet
Dim SaveToDirectory As String

Dim CurrentWorkbook As String
Dim CurrentFormat As Long

CurrentWorkbook = ThisWorkbook.FullName
CurrentFormat = ThisWorkbook.FileFormat
' Store current details for the workbook
SaveToDirectory = "H:\test\"

For Each WS In Application.ActiveWorkbook.Worksheets
    WS.SaveAs SaveToDirectory & WS.Name, xlCSV
Next

Application.DisplayAlerts = False
ThisWorkbook.SaveAs Filename:=CurrentWorkbook, FileFormat:=CurrentFormat
Application.DisplayAlerts = True
' Temporarily turn alerts off to prevent the user being prompted
'  about overwriting the original file.

End Sub

Bonne journée,
Cliquez pour agrandir...
merci pour la réponse, je teste et adapte si besoin et si j't arrive à mon environnement et besoin
 
Vote positif 0 Vote négatif
P

patrice3450

XLDnaute Nouveau
job75 à dit:
Téléchargez les fichiers joints dans le même dossier (le bureau), ouvrez le fichier Pilote.xlsm et exécutez la macro du bouton :
VB: 
Sub Creer_CSV()
Dim chemin$, fichier$, n&, w As Worksheet, nf&
chemin = ThisWorkbook.Path & "\"
fichier = Dir(chemin) '1er fichier du dossier
Application.ScreenUpdating = False
Application.DisplayAlerts = False 'si un fichier est déjà créé
On Error Resume Next
While fichier <> ""
    If fichier <> ThisWorkbook.Name And (Right(fichier, 5) = ".xlsx" Or Right(fichier, 5) = ".xlsm") Then
        Workbooks(fichier).Close False 'si le fichier est ouvert on le ferme
        With Workbooks.Open(chemin & fichier) 'ouverture du fichier
            n = n + 1
            For Each w In .Worksheets
                nf = nf + 1
                w.Select
                .SaveAs chemin & fichier & "-" & w.Name & ".csv", xlCSV
            Next
            .Close False 'fermeture
        End With
    End If
    fichier = Dir 'fichier suivant
Wend
MsgBox n & " fichier(s) Excel traité(s), " & nf & " fichier(s) CSV créé(s)"
End Sub
Cliquez pour agrandir...
merci cela fonctionne, j'ai adapté le résultat sans le nom du fichier devant mais il me reste à tester l'imput du fichier csv dans une base de donnée
 
Vote positif 0 Vote négatif
P

patrice3450

XLDnaute Nouveau
job75 à dit:
Bonjour patrice3450, le forum,

Alors comment faites-vous si les noms des feuilles sont les mêmes ???

A+
Cliquez pour agrandir...
j'ai conçu mes différents classeurs excel avec des noms de feuilles différents car se sont des virus ou bactéries différentes
en fait j'ai plusieurs choses à faire :
je récupère des fichiers excel dans lesquels il y a plusieurs feuilles (pas le même nombre)
chaque feuille de chaque fichier est un tableau dont je dois retirer la première ligne et chaque feuille de chaque fichier doit être enregistré en csv
j'arrive a peu prêt à faire chaque étape manuellement, ou avec des macros, le fichier csv le plus satisfaisant que je fais est avec kutools+ (diviser le classeur)
je voudrais faire tout cela avec le moins de manipulation possible en lançant un bouton ou plusieurs si pas possible avec un sur un répertoire ou je mettrais tous mes fichiers excel à traiter
 

Pièces jointes

  • tableaux_virus_28.09.22.xlsx
    28.4 KB · Affichages: 1
Vote positif 0 Vote négatif
job75

job75

XLDnaute Barbatruc
Si l'extension de tous les fichiers sources est ".xlsx" :
VB: 
Sub Creer_CSV()
Dim chemin$, fichier$, n&, w As Worksheet, nf&
chemin = ThisWorkbook.Path & "\"
fichier = Dir(chemin & "*.xlsx") '1er fichier du dossier
Application.ScreenUpdating = False
Application.DisplayAlerts = False 'si un fichier est déjà créé
While fichier <> ""
    On Error Resume Next
    Workbooks(fichier).Close False 'si le fichier est ouvert on le ferme
    On Error GoTo 0
    With Workbooks.Open(chemin & fichier) 'ouverture du fichier
        n = n + 1
        For Each w In .Worksheets
            nf = nf + 1
            w.Select
            w.UsedRange.Rows(1).Delete 'supprime la 1ère ligne
            .SaveAs chemin & w.Name & ".csv", xlCSV
        Next
        .Close False 'fermeture
    End With
    fichier = Dir 'fichier suivant
Wend
MsgBox n & " fichier(s) Excel traité(s), " & nf & " fichier(s) CSV créé(s)"
End Sub
 

Pièces jointes

  • Pilote(1).xlsm
    17.4 KB · Affichages: 4
  • tableaux_virus_28.09.22.xlsx
    28.4 KB · Affichages: 2
Vote positif 0 Vote négatif

Discussions similaires

A
  • Question
Autres Protégé un fichier csv par mot de passe
2
Réponses
16
Affichages
492
job75
job75
G
  • Question
Microsoft 365 Convertir CSV en tableau de nombres
Réponses
7
Affichages
123
sylvanu
sylvanu
J
  • Question
XL 2021 excel - vbs - csv
2
Réponses
28
Affichages
1 K
jerome1980
J
A
  • Question
Microsoft 365 Convertir un fichier csv sans séparateur en xls
Réponses
1
Affichages
425
sylvanu
sylvanu
N
  • Question
XL 2021 sauvegarde en csv format ";"
Réponses
4
Affichages
581
patricktoulon
patricktoulon
cathodique
  • Résolu(e)
XL 2010 Problème màj feuilles depuis fichiers CSV
2
Réponses
23
Affichages
2 K
cathodique
cathodique
F
  • Résolu(e)
Microsoft 365 Comment enregistrer chaque ligne en tant que fichier texte dans Excel?
2
Réponses
24
Affichages
708
TooFatBoy
TooFatBoy
jeanmi
  • Résolu(e)
XL 2013 recherche de données sur plusieurs fichiers
Réponses
13
Affichages
416
dysorthographie
dysorthographie
L
  • Question
Autres Macro pour conevrtir des lignes excel en CSV
Réponses
3
Affichages
422
sylvanu
sylvanu
B
  • Question
XL 2016 Export Tableau en un fichier CSV
Réponses
5
Affichages
338
job75
job75

Membres actuellement en ligne

14 membres et 129 invités.

Partager cette page

Tutos vidéos

Power Query : Ajouter des requêtes (Excel et Power BI)
Créez votre première fonction LAMBDA dans Excel en 3 étapes!
LAMBDA, l’arme secrète de Microsoft pour Excel !
Office Insider - Découvrez les nouveautés Excel avant tout le monde

Statistiques des forums

Discussions
315 096
Messages
2 116 175
Membres
112 677
dernier inscrit
Justine11