Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

XL 2010 Consolider plusieurs feuilles (classeurs) identiques par VBA

Créer une discussion
  • Initiateur de la discussion Initiateur de la discussion fattah_5791
  • Date de début Date de début

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

S'inscrire
F

fattah_5791

XLDnaute Occasionnel
Bonsoir tout le monde,

merci de m'aider à surmonter mon petit probleme.

j'ai une dizaine de classeurs (chq classeur contient une seule feuille) identiques que je veux consolider par VBA. les cellules de la plage A1:H250 de toutes les feuilles à consolider contiennent des valeurs numeriques. je veux faire la somme des cellules A1 de ttes les feuilles et la mettre ds la cellule A1 d'une feuille RECAP et de meme pour B1, C1,...., H250.

Merci de votre aide
 
Trier par date Trier par votes
Bonjour le fil,

fattah_5791
Poser des questions c'est bien
Se souvenir qu'on a déjà posé la question, c'est mieux 😉

ouvrir plusieurs fichiers par boucle et y prendre des données

salut j'ai realisé une petite Macro vba me permettant d'ouvrir un fichier nommé (TCS-1.xlsx) et d'y copier des données puis les coller ds un autre classeur. Code VBA: ce code permet de copier des données du fichier source TCS-1.xlsx et de les coller ds la feuille TC.Sc1 du classeur...
www.excel-downloads.com
Suivre la question qu'on a jadis posée et réagir aux réponses, c'est encore mieux 😉
(Mais ne pas attendre trois ans pour le faire 😉)
 
Vote positif 0 Vote négatif
Bonjour le forum,

Voici, en tenant compte de tes remarques, à savoir structure identique sur tous les classeurs.

Il faut renseigner les noms des classeurs à partir de "A2", en mettant le chemin complet.
Puis appuyer sur le bouton Consolidation.

Testé sur 3 et 4 classeurs.

Les sommes seront affichées dans la feuille Résultat.

VB: 
Option Explicit

Sub Consolidation()
Dim i As Long, j As Integer, n As Long, k As Integer, m As Integer, total As Integer
Application.ScreenUpdating = False
Sheets("Calculs").[A1].CurrentRegion.ClearContents
Call Ouverture_Classeur
Sheets("Calculs").Activate
Application.Calculation = xlCalculationManual
m = 0
For j = 1 To 8
    For i = 1 To 250
        n = 251
        n = n + m
        total = Cells(i, j) + Cells(n, j)
            For k = 1 To Application.CountA(Sheets("Matrice").Range("A:A")) - 1
                n = n + 250
                total = total + Cells(n, j)
            Next k
        Sheets("Résultat").Cells(i, j) = total
        m = m + 1
    Next i
    m = 0
Next j
'Application.FileDialog(msoFileDialogFolderPicker).Show ' Ouverture boite de dialogue
Application.Calculation = xlCalculationAutomatic

Sheets("Résultat").Activate

Application.ScreenUpdating = True
End Sub

Sub Ouverture_Classeur()
Dim fichier As String, i As Byte, Flag As Boolean


For i = 2 To Cells(Rows.Count, 1).End(xlUp).Row
fichier = Cells(i, 1)
On Error Resume Next
    Workbooks(fichier).Activate
    If Err.Number <> 0 Then
        Workbooks.Open fichier
    End If

If Flag = False Then
    [A1].CurrentRegion.Copy Destination:=ThisWorkbook.Sheets("Calculs").Range("A" & Rows.Count).End(xlUp)
Else
    [A1].CurrentRegion.Copy Destination:=ThisWorkbook.Sheets("Calculs").Range("A" & Rows.Count).End(xlUp).Offset(1, 0)
End If

Flag = True
ActiveWorkbook.Close
Next i
End Sub

A+
 

Pièces jointes

Vote positif 0 Vote négatif
Bonjour Calvus

Non, je trouve toujours dommage quand un demandeur ne fait pas un retour quand il a une réponse à une question posée...

Et tes PJ pourront servir à d'autres lecteurs du fil.

PS: D'ou sors-tu le nom des feuilles des classeurs?
Vu que le demandeur n'a pas joint de fichier exemple...
 
Vote positif 0 Vote négatif
Bonjour fattah_5791, JM, Calvus,

10 classeurs à consolider ce n'est pas la mer à boire, pas besoin de VBA, il suffit d'utiliser des formules de liaison.

Ouvrez tous les fichiers à consolider et le fichier Consolidation.xlsx.

En A1 de ce dernier fichier entrez la formule comme ici avec 4 fichiers :
Code: 
=[tatata.xlsx]Feuil1!A1+[tututu.xlsx]Feuil1!A1+[tototo.xlsx]Feuil1!A1+[tititi.xlsx]Feuil1!A1
Vous pouvez maintenant fermer les fichiers sources et tirer la formule à droite et vers le bas pour remplir A1:H250.

Fichiers joints, téléchargez-les dans le même répertoire (le bureau).

A+
 

Pièces jointes

Vote positif 0 Vote négatif
Bonjour le forum,

Les manipulations indiquées au post précédent peuvent bien sûr se faire par VBA :
VB: 
Sub Consolider()
Dim t#, chemin$, fichier$, nfich%, f$, wb As Workbook
t = Timer
chemin = ThisWorkbook.Path & "\" 'dossier à adapter
fichier = Dir(chemin & "*.xls*") '1er fichier du dossier
Application.ScreenUpdating = False
'---ouverture des fichiers---
While fichier <> ""
    If fichier <> ThisWorkbook.Name Then
        nfich = nfich + 1
        f = f & IIf(f = "", "=", "+") & "'[" & fichier & "]" & Workbooks.Open(chemin & fichier).Sheets(1).Name & "'!A1"
    End If
    fichier = Dir 'fichier suivant
Wend
'--remplissage du tableau---
With ThisWorkbook.Sheets(1).[A2:H251] 'plage à adapter
    .Formula = f
    .Value = .Value 'supprime les formules
End With
'---fermeture des fichiers---
For Each wb In Workbooks
    If wb.Name <> ThisWorkbook.Name Then wb.Close False
Next
Application.ScreenUpdating = True
MsgBox nfich & " fichiers consolidés en " & Format(Timer - t, "0.00 \s")
End Sub
Fichiers joints, chez moi sur Win 10 - Excel 2013 la consolidation des 4 fichiers se fait en 2,4 secondes.

A+
 

Pièces jointes

Vote positif 0 Vote négatif
Bonjour le forum,

Si le nom de la feuille est toujours le même, il n'est pas nécessaire d'ouvrir les fichiers :
VB: 
Sub Consolider()
Dim t#, chemin$, fichier$, nomfeuil$, nfich%, f$, wb As Workbook
t = Timer
chemin = ThisWorkbook.Path & "\" 'dossier à adapter
fichier = Dir(chemin & "*.xls*") '1er fichier du dossier
nomfeuil = "Feuil1" 'nom à adapter
'---formule concaténée---
While fichier <> ""
    If fichier <> ThisWorkbook.Name Then
        nfich = nfich + 1
        f = f & IIf(f = "", "='", "+'") & chemin & "[" & fichier & "]" & nomfeuil & "'!A1"
    End If
    fichier = Dir 'fichier suivant
Wend
'--remplissage du tableau---
With [A2:H251] 'plage à adapter
    .Formula = f
    .Value = .Value 'supprime les formules
End With
MsgBox nfich & " fichiers consolidés en " & Format(Timer - t, "0.00 \s")
End Sub
Fichiers joints, consolidation des 4 fichiers en 0,11 seconde chez moi.

Bonne journée.
 

Pièces jointes

Vote positif 0 Vote négatif
Merci Job 75, C'est ce que je cherche à mon truc. avec qlqs adaptations, je suis arrivé à regler mon prblm.
 
Vote positif 0 Vote négatif
Je considère que mon truc est résoulu avec un grand merci à tous les intervenants.
 
Vote positif 0 Vote négatif
merci job75 pour votre aide, juste est il possible de proceder ainsi:
pour eviter que tous les classeurs (en realité j aurai une centaine de classeurs source identiques) soient ouverts en meme temps, est il possible:
- d'ouvrir en arrière plan le premier classeur source puis de copier les valeurs ds le classeur de destination,
- fermer le 1er classeur ouvet,
- ouvrir le 2eme classeur source,
- copier les valeurs du 2eme classeur source et les rajouter aux valeurs du classeur destination,
- fermer le 2eme classeur source,
- ouvrir le 3eme classeur source,
- copier les valeurs du 3eme classeur source et les rajouter aux valeurs du classeur destination,
- ainsi de suite....

comme ca la memoire ne sera pas trop occupée

Merci encore
 
Vote positif 0 Vote négatif
Bonjour fattah_5791, le forum,

100 classeurs ça commence à faire... Avec la macro du post #10 on n'ouvre pas les fichiers, c'est bien plus rapide.

Mais on peut en effet modifier la macro du post #9, fichier (1 bis) :
VB: 
Sub Consolider()
Dim t#, chemin$, fichier$, nfich%, f$, wb As Workbook
t = Timer
chemin = ThisWorkbook.Path & "\" 'dossier à adapter
fichier = Dir(chemin & "*.xls*") '1er fichier du dossier
Application.ScreenUpdating = False
'---ouverture des fichiers---
While fichier <> ""
    If fichier <> ThisWorkbook.Name Then
        nfich = nfich + 1
        With Workbooks.Open(chemin & fichier)
            f = f & IIf(f = "", "='", "+'") & chemin & "[" & fichier & "]" & .Sheets(1).Name & "'!A1"
            .Close False
        End With
    End If
    fichier = Dir 'fichier suivant
Wend
'--remplissage du tableau---
With [A2:H251] 'plage à adapter
    .Formula = f
    .Value = .Value 'supprime les formules
End With
Application.ScreenUpdating = True
MsgBox nfich & " fichiers consolidés en " & Format(Timer - t, "0.00 \s")
End Sub
Bonne journée.
 

Pièces jointes

Vote positif 0 Vote négatif
Excellent travail Job75, merci infiniment.
Comme ça mon prblm est résolu. merci encore
 
Vote positif 0 Vote négatif
Identifiez-vous ou inscrivez-vous pour participer.
Rejoins nos membres "Supporter XLD" et booste ton expérience Excel !
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD

Discussions similaires

S
  • Question Question
Microsoft 365 Consolider des données de plusieurs feuilles
Réponses
2
Affichages
338
Sissou71
S
K
  • Question Question
XL 2010 copier le contenu de plusieurs feuilles sur une seule
Réponses
3
Affichages
281
sylvanu
R
  • Question Question
XL 2010 Copier des lignes de données de plusieurs feuilles dans une seule
Réponses
6
Affichages
738
AtTheOne
  • Question Question
XL 2021 Comment supprimer des noms du gestionnaire de noms dans un classeur
Réponses
7
Affichages
750
jeff1494
A
  • Résolu(e)
XL 2019 VBA newbie
4 5 6
Réponses
80
Affichages
3 K
apocalypse
A
R
  • Question Question
XL 2010 Copie de données de plusieurs feuilles dans une seule
Réponses
5
Affichages
807
Renaud22
R
P
  • Question Question
XL 2019 Changer nom d'export en VBA
Réponses
3
Affichages
798
job75
Y
  • Résolu(e)
XL 2013 Consolider les données de plusieurs classeurs en un seul
2 3 4
Réponses
55
Affichages
3 K
Cousinhub
G
  • Question Question
Microsoft 365 Avoir des classeurs maitres et les procédures dans un autre classeur.
2
Réponses
19
Affichages
2 K
GClaire
G
C
  • Question Question
XL 2013 Copie de formules
Réponses
4
Affichages
516
Cattitude
C
B
  • Question Question
XL 2013 Transposition de filtres multiples sur plusieurs feuilles
Réponses
11
Affichages
818
BIROULIG
B
M
  • Question Question
XL 2019 VBA Valeur d'une cellule dont la feuille et la ligne est dans la feuille courante
Réponses
13
Affichages
854
job75
A
  • Question Question
Autres Remplir des feuilles a partir d'une autre feuille du même classeur
Réponses
4
Affichages
978
abdallah12
A
A
  • Question Question
VBA qui fonctionnait avant, mais ne fonctionne plus avec le 64 bits
Réponses
2
Affichages
587
patricktoulon
C
  • Résolu(e)
Microsoft 365 Amélioration Macro.
Réponses
7
Affichages
701
crazy
C
C
  • Résolu(e)
Microsoft 365 Mise en forme d'une ligne d'après listes déroulantes + clic sur un bouton
Réponses
2
Affichages
701
casualexcel
C
  • Question Question
XL 2013 Copier une même cellule de plusieurs feuilles Excel dans un autre classeur
Réponses
7
Affichages
962
job75
K
  • Résolu(e)
XL 2016 consolider tableau des données de plusieurs feuilles en un seul feuille
Réponses
3
Affichages
1 K
Phil69970
C
  • Résolu(e)
XL 2021 vba fusion lignes et colonnes pour cellules identiques
2
Réponses
24
Affichages
2 K
cbar
C
  • Question Question
XL 2016 Protection plusieurs feuilles d'un classeur
Réponses
3
Affichages
532
KTM
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…