Compter le nombre de valeurs différentes dans une plage

[Mary]

Bonjour,

J'ai besoin de compter le nombre de valeurs différentes dans une plage donnée.
J'ai essayé la formule :
=somme(1/NB.SI(maplage)) en validant par ctrl+maj+entrée

mais j'obtiens le message d'erreur #DIV/0! qui peut s'expliquer par la présence de quelques cellules vides au sein de ma plage

Auriez-vous une autre piste ? j'utilise excel 2000.
merci beaucoup

Mary

 

[Monique]

Bonjour,

Si tu as des vides dans ta plage :
=SOMME(SI(ESTVIDE(Plage);"";1/NB.SI(Plage;Plage)))
=SOMME(SI((Plage<>"");1/NB.SI(Plage;Plage)))
Le texte seulement :
=SOMME(SI(ESTTEXTE(Plage);1/NB.SI(Plage;Plage)))
Les valeurs numériques seulement :
=SOMME(SI(ESTNUM(Plage);1/NB.SI(Plage;Plage)))
Formules à valider par ctrl, maj et entrée

S'il n'y a pas de vide, non matriciel :
=SOMMEPROD(1/NB.SI(Plage;Plage))

 

[Jean-Marie]

Bonsoir Mary, Monique


Une autre possibilité =SOMME((FREQUENCE(A:A;A:A)>0)*1) pas besoin de la valider par Crtl+Shift+Entrer. Cette formule ne totalise que les valeurs numériques.

Bonne soirée

@+Jean-Marie

PS. J'avais il y a quelque mois, mise cette formule sur le forum. La manière utilisée dans mon post et au cours du fil était peu cavalière.

 

[Mary]

Bonjour et merci pour vos solutions qui ont marché.

 

[Mary]

Bonjour et merci pour votre réponse qui fonctionne effectivement sur des valeurs numériques. Or mes valeurs contiennent aussi du texte, il me faut donc utiliser les formules de Monique.
Grâce à vous 2 j'ai pu épater mes collègues, encore merci. ;-)

 

[Christian]

Bonjour,
Peut on intégrer la fonction ET ou OU avec SOMME.SI.

Cordialement

 

[Michael]

Ceci permet de compter le nombre de cellules remplies (autrement dit valeurs non-vides) d'une plage :

=NBVAL(.... : .....)

ça fonctionne aussi bien avec un contenu numérique qu'avec de l'alpha-num.