Compter des mois en fonction d'un paramètre

[niiiiiiiiiico]

Bonjour à tous,

Je souhaiterais compter combien de fois j'ai les mots EVRP et AT en janvier, février, mars, etc.

J'ai fait un essai en PJ, mais ça ne marche pas...

Merci à tous pour votre aide

 

[Tibo]

Re : Compter des mois en fonction d'un paramètre

Bonjour,

Un essai avec SOMMEPROD :

=SOMMEPROD(((plage_cellules_1="EVRP")+(plage_cellules_1="AT"))*
(plage_dates<>"")*(MOIS(plage_dates)=1)

Je te laisse adapter

@+

Edit : sur base de ton fichier :

en C17 :

=SOMMEPROD(($B$4:$B$12=$B17)*($C$4:$C$12<>"")*(MOIS($C$4:$C$12)=
MOIS("1/"&C$16)))

à recopier vers la droite et vers le bas

le *($C$4:$C$12<>"") est destiné à traiter les cellules vides. Excel considère les cellules vides comme égales à zéro, et pour Excel, la date zéro est le 0 janvier 1900, date qui n'existe pas, mais qui retourne 1 avec la fonction MOIS

@+

 

[tototiti2008]

Re : Compter des mois en fonction d'un paramètre

Bonjour à tous,

une autre proposition :

=SOMMEPROD(($B$4:$B$12=$B17)*(TEXTE($C$4:$C$12;"mmmm")=C$16))

 

[niiiiiiiiiico]

Re : Compter des mois en fonction d'un paramètre

Bonjour à vous deux et merci pour vos réponses !

 

[niiiiiiiiiico]

Re : Compter des mois en fonction d'un paramètre

Re bonjour,

Je reviens encore avec une petite question... Si je veux compter dans ma colonne C le nombre de date en janvier 2009, quelle doit être la formule ? Dans le fichier toutes les dates sont en 2009, mais à terme non.

Merci !

 

[Tibo]

Re : Compter des mois en fonction d'un paramètre

re,

En reprenant la formule de tototiti, en en indiquant l'année en B16 (par ex. : 2009) :

en C17 :

=SOMMEPROD(($B$4:$B$12=$B17)*(TEXTE($C$4:$C$12;"mmmmaaaa")=
TEXTE("1/"&C$16&"/"&$B$16;"mmmmaaaa")))

à recopier vers la droite et vers le bas

Je te laisse tester

@+

 

[niiiiiiiiiico]

Re : Compter des mois en fonction d'un paramètre

Re,

Merci pour ta réponse. En fait, je n'ai pas besoin d'un sommeprod, je veux seulement compter le nombre de fois où j'ai des dates en janvier 2009 (ou 2008, etc.) dans ma colonne C

J'ai essayé celà :

=NB.SI(C4:C12;TEXTE(C4:C12;"mmmmaaaa")=TEXTE("1/"&C$16&"/"&$B$16;"mmmmaaaa"))

Mais ça ne marche pas !

 

[Tibo]

Re : Compter des mois en fonction d'un paramètre

re,

La fonction SOMMEPROD, malgré son nom, peut servir pour compter des données qui répondent à certaines critères.

Et dans ton cas, effectivement, la fonction NB.SI ne passe pas.

N'hésite pas à utiliser SOMMEPROD, tu vas découvrir au fil du temps la puissance de cette fonction magique

Si problème avec la formule que je t'ai proposé plus haut, reviens avec plus de détails.

@+

@+

 

[niiiiiiiiiico]

Re : Compter des mois en fonction d'un paramètre

Re,

En fait, je souhaiterai également compter le nombre de date d'un tel mois d'une telle année (imaginons janvier 2009) dans ma colonne C et ce quelquesoit les valeurs en colonne B

Merci !

 

[Tibo]

Re : Compter des mois en fonction d'un paramètre

Bonjour,

Pour compter uniquement les mois (sans tenir compte des codes AT ou EVRP) :

en C17 :

=SOMMEPROD((TEXTE($C$4:$C$12;"mmmmaaaa")=TEXTE("1/"&C$16&"/"&$B$16;
"mmmmaaaa"))*1)

Avec en B16 l'année

Je te laisse tester

@+

 

[niiiiiiiiiico]

Re : Compter des mois en fonction d'un paramètre

Un grand merci, ça marche !