Comparer 2 listes selon 2 critères

[Amilo]

Bonsoir le Forum,

Dans le fichier joint, je désire comparer la plage en A:B avec la plage en E:F,

Partant du principe que les données en E:F sont correctes, j'aurais souhaité une formule en C pour indiquer que chaque ligne de ma liste en A:B s'écrit de la même manière que dans la liste en E:F.

La formule que j'ai placée fonctionne à un détail près, c'est que je ne veux rien indiquer non plus si aucune des 2 cellules ne sont présentes dans E:F (comme par exemple pour les cellules Bordeaux et Nantes où je veux un résultat vide en C)

Merci d'avance pour votre aide

Cordialement

 

[R@chid]

Re : Comparer 2 listes selon 2 critères

Bonsoir,
en C1 :

=SI(ET(A1=E1;B1=F1);"")

@ tirer vers le bas
Amicalement

 

[Amilo]

Re : Comparer 2 listes selon 2 critères

Bonsoir Rachid_0661,

Après vérification de votre formule, cela donne exactement le même résultat que la mienne,

Les 2 exemples que j'ai repris ci-dessous, n'apparaissent pas du tout dans la liste E:F, aussi je souhaite rien afficher en C.
Bordeaux 33000
Nantes 44000

Merci quand même pour votre réponse

NB : dans mon exemple j'ai indiqué les listes dans le même ordre mais en réalité la 2ème liste est dans un tout autre ordre.


Cordialement

 

[R@chid]

Re : Comparer 2 listes selon 2 critères

Re,
Ahhhhhh, tu as déjà la formule en colonne C, j'ai pensé que que c'est le resultat souhaité que tu as mis manuellement et j'ai fait le test de ma formule a coté...
Donc pour quoi pas???
Bordeaux 33000
Nantes 44000
@ te relire

 

[R@chid]

Re : Comparer 2 listes selon 2 critères

Ok,
peut etre j'ai compris essayer en C1 avec :

=SI(NB.SI(E$1:E$18;A1);SI(OU(A1<>E1;B1<>F1);FAUX;"");"")

@ tirer vers le bas
Amicalement

 

[CISCO]

Re : Comparer 2 listes selon 2 critères

Bonsoir

Peut être avec

SI(ESTNUM(EQUIV(A1&B1;E$1:E$18&F$1:F$18;0));"";SI(ET(NON(ESTNUM(EQUIV(A1;E$1:E$18;0)));NON(ESTNUM(EQUIV(B1;F$1:F$18;0))));""))

en matriciel (à valider avec ctrl+maj+entrer)

@ plus

 

[Amilo]

Re : Comparer 2 listes selon 2 critères

Merci Rachid,

ça fonctionne trés bien à présent,

j'ai essayé avec une liste dans le désordre en E:F et ça marche trés bien aussi, alors que la mienne donne un résultat totalement erroné.

Bonsoir Cisco, votre formule qui est un peu plus compliquée donne également le résultat attendu et je vous remercie pour votre solution.

Merci encore à vous 2,

Bonne nuit à toutes et à tous.

 

[CISCO]

Re : Comparer 2 listes selon 2 critères

Bonsoir

La formule de Rachid fonctionne t'elle lorsque les deux listes ne sont pas dans le même ordre ?

@ plus

 

[Amilo]

Re : Comparer 2 listes selon 2 critères

Bien vu Cisco,

Merci pour cette remarque pertinente.

Finalement, je venais juste de m'en rende compte en même temps que la formule à Rachid ne fonctionne pas dans le désordre, je ne sais pas ce que j'ai fait précédemment pour annoncer que ça fonctionnait....!!


Je dois dire que votre formule marche dans tous les cas et qu'il semble utile d'avoir une formule matricielle pour résoudre ce cas (c'est pas trop mon point fort les formules surtout matricielles...)

En tout cas, merci pour cette formule.

Et désolé pour un 1er cas d'exemple à moitié exhaustif, qui vous a induit en erreur

Cordialement

 

[R@chid]

Re : Comparer 2 listes selon 2 critères

Bonsoir @ tous,
Moi de ma part j'ai pas compris que voulez-vous dire par "Désordre",
si tu peux m'expliquer ça sur le fichier ce sera agréable...
Amicalement

 

[CISCO]

Re : Comparer 2 listes selon 2 critères

Bonsoir

On dirait que cela fonctionne aussi avec

SI(ESTNA(RECHERCHEV(A1;E$1:F$18;2;0));"";SI(RECHERCHEV(A1;E$1:F$18;2;0)=B1;"";SI(ET(NON(ESTNUM(EQUIV(A1;E$2:E$18;0)));NON(ESTNUM(EQUIV(B1;F$2:F$18;0))));"")))

sans calcul matriciel. Toutefois, c'est à vérifier davantage, et peut être à simplifier un peu.

@ plus

 

[Amilo]

Re : Comparer 2 listes selon 2 critères

Rachid,

Effectivement, j'avoue que je n'ai pas été assez clair et pertinent dans mon exemple,

Je vous joins le fichier modifié avec les 2 formules (celle de Cisco en C et la vôtre en D), pour vous expliquer ce que je voulais dire par "Désordre"

Bonne nuit

 

[R@chid]

Re : Comparer 2 listes selon 2 critères

Re,
Tu n’étais pas clair dés le début,
en C1 :

=SI(OU(NB.SI(E$1:E$18;A1)=0;SOMMEPROD((E$1:E$18=A1)*(F$1:F$18=B1)));"")

Validation Classique
Amicalement

Edit :
une autre en C1 :

=SI(OU(NB.SI(E$1:E$18;A1)=0;ESTNUM(EQUIV(A1&B1;E$1:E$18&F$1:F$18;0)));"")

Validation Matricielle

Combien de "Likes" méritent-elles ??

Bonne Soirée @ tous

 

[Amilo]

Re : Comparer 2 listes selon 2 critères

Rachid,

Je confirme, je n'ai pas été clair dès le début et désolé pour ce désagrément...

Merci pour ces 2 nouvelles formules que je viens d'essayer, ça marche impeccable,

Bonne journée à tous

Cordialement

 

[CISCO]

Re : Comparer 2 listes selon 2 critères

Bonjour

Ma dernière proposition n'est pas très belle. Par contre, celles de Rachid sont beaucoup plus fines et conscises. Malheureusement, j'ai l'impression que ces 3 dernières ne donnent pas la bonne réponse. Cf. un test en pièce jointe. Que faut-il en ligne 10 : FAUX ou "" ?

@ plus