Microsoft 365 Comment indiquer une valeur en fonction de plusieurs cellules à valeurs multiple ?

[nikodème]

Bonjour,

Je rencontre une difficulté lors de l'établissement d'un tableau
je souhaite récupérer une valeur en fonction de 3 critères.
J'ai pu l'établir en utilisant la fonction ET en complément de SI, cependant je suis limité par le nombre de valeur pouvant être insérer dans la formule et cela reste assez fastidieux.
Y aurait-il une autre possibilité plus aisé pour intégré plus de références ?

Je joint un tableur test pour une meilleur compréhension.

Merci de votre aide.

 

[shinozak]

Salut, essaie ça :

=SI(ESTNA(INDEX(D7:D18;EQUIV(A3&B3&C3;A7:A18&B7:B18&C7:C18;0)))=VRAI;"";INDEX(D7:D18;EQUIV(A3&B3&C3;A7:A18&B7:B18&C7:C18;0)))

ps: je te conseil de mettre une liste sur tes critères pour eviter de les saisir a la main

 

[mapomme]

Bonjour à tous,

Vous utilisez Office 365 (ou 2021), on peut donc le faire à la mode 365 qui s'adaptera automatiquement à vos données source et à leurs modifications (ajout de ligne, suppression de ligne, modification des valeurs).

En tout premier lieu, on transforme la base de données en tableau structuré:

• sélectionner la plage de données A6 à D18
• choisir le menu Insérer / Tableau
• assurez-vous que l'option "Mon tableau comporte des en-têtes" est cochée
• cliquer sur OK

Dans une base de données, ne jamais laisser des cellules vides en laissant supposer que dans ces cas, il faut prendre la première valeur en "remontant". C'est une aberration !
Les champs d'une base de données doivent être remplis par leur vraie valeur.

• donc remplir les champs vides de la colonne "Catégorie" (si vous le demandez, il existe une façon rapide de le faire)

Pour les listes de choix des trois cellules critères :

• en K1, mettre la formule suivante: =UNIQUE(FILTRE(A7:A9999;A7:A9999<>""))
• copier cette formule à droite jusqu'à M1
• => on obtient la liste sans doublon de chaque critère

se placer sur la cellule A3

• choisir le menu Données / Validations des données / Validations des données...
• sélectionner Liste dans la liste de choix Autoriser
• dans la zone Source saisir la formule : =DECALER($K:$K;0;0;NB.SI($K:$K;"><"))
• cliquer sur OK
• recommencer la même chose pour les cellules B3 et C3 (en adaptant la formule bien entendu)

Le résultat en cellule E3 :

on utilise la formule Filtre() de Excel 365 combinée avec la fonction Index() pour ne garder que la première ligne de résultat au cas où Filtre() renverrait plusieurs lignes (ce qui ne devrait pas être la cas, me semble-t-t’il)
Mettre en cellule E3, la formule suivante :

=INDEX(FILTRE(Tableau1[Résultat];(Tableau1[Catégorie]=A3)*(Tableau1[Taille]=B3)*(Tableau1[Style]=C3));1)

Tout est fait dans fichier joint.

 

[nikodème]

Merci pour vos réponses très rapide.
L'analyse des réponses pour comprendre m'a pris un peu de temps.

Il y a une chose que je n'ai pas réussi à cerné, dans les formules :
"=UNIQUE(FILTRE(A7:A9999;A7:A9999<>""))" et "=DECALER($K:$K;0;0;NB.SI($K:$K;"><"))"

Que veut dire les symboles <>"" et "><" ?
Est-ce respectivement "différents de 0" et "comme 0" ?

J'ai ajouté les différentes formules utilisées en mots-clefs.

 

[mapomme]

Que veut dire les symboles <>"" et "><" ?
Est-ce respectivement "différents de 0" et "comme 0" ?

<> "" est la condition 'différent de la chaine vide'.
"><" à peu près la même chose mais peut être utilisé dans la fonction NB.SI() comme condition à remplir

 

[nikodème]

Merci pour tout ces renseignements.