Code vba

[cyril.fernandez]

Bonjour la team,

j'aurai encore besoin de vous j'urais besoin d'un code VBA pour que lorsque dans ma colonne "J" je mets "FINI" la colone "K" se mette à la date du jour merci à vous.😛😕

 

[Pierrot93]

Re : Code vba

Bonjour,

essaye avec ceci :

Dim x As Range
Set x = Columns(10).Find("FINI", , xlValues, xlWhole, , , False)
If Not x Is Nothing Then x.Offset(0, 1).Value = Date

bon après midi
@+

 

[kjin]

Re : Code vba

Bonjour,

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Column = 10 And Target.Count = 1 Then
    If UCase(Target) = "FINI" Then Target.Offset(0, 1) = VBA.Date
End If
End Sub

A+
kjin

 

[Bernard_XLD]

Re : Code vba

Bonjour Cyril, Pierrot93, Kjin, le forum

un code pour traiter l'ensemble de la colonne sans événementielle.

Cordialement

Sub Poser_Date()
Const Valeur_a_trouver = "FINI", Colonne_a_tester = 10, Decal_pour_poser = 1
Dim Cellule_en_Cours As Range, Cellule_prime_Adresse As String
With Columns(Colonne_a_tester)
    Set Cellule_en_Cours = .Find(Valeur_a_trouver, LookIn:=xlValues)
    If Not Cellule_en_Cours Is Nothing Then
        Cellule_prime_Adresse = Cellule_en_Cours.Address
        Do
            Cellule_en_Cours.Offset(0, Decal_pour_poser).Value = Date
            Set Cellule_en_Cours = .FindNext(Cellule_en_Cours)
        Loop While Not Cellule_en_Cours Is Nothing And Cellule_en_Cours.Address <> Cellule_prime_Adresse
    End If
End With
End Sub