Code VBA dur pour moi, mais surement simple pour vous :)

[Pygouv]

Bonjour,
Je souhaiterai un code appliqué à un bouton qui me permetterait de supprimer les lignes SI les cellules de la colonne A comporte un "N" ET que les cellules de la colonne "E" comporte "Inventory Total Gross"

J'ai en effet des doublons que je souhaiterai supprimer. Il faut que les lignes comportant ces 2 notions dans ces 2 colonnes disparaissent pour régler mon problème... si vous avez un code je suis preneur 🙂

Merci de votre aide 🙂

 

[Orodreth]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

Bonjour,

A adapter.

    Dim WS_Doublon as Worksheet
    Set WS_Doublon = Worksheets("NOMDETAFEUILLE")

    Dim fin_Doublon as long
    fin_Doublon = WS_Doublon.Range("A65536").end(xlup).row

    Dim pcs_Doublon as long
    Dim val_colA as string
    Dim val_colE as string

    'On parcourt le tableau à l'inverse pour ne pas être géné par la suppression des lignes
    For pcs_Doublon = fin_Doublon to 1 Step - 1 '(le 1 est à remplacer par ta ligne de début)
        val_ColA = WS_Doublon.cells(pcs_Doublon, 1).value
        val_ColE = WS_Doublon.Cells(pcs_Doublon, 5).Value

        'On teste les conditions
        'On vérifie si le texte de la cellule en A CONTIENT "N", et si le texte de la cellule en E CONTIENT "Inventory Total Gross"
        '/!\ Le texte testé peut être plus grand que le critère de recherche
        If (val_ColA LIKE "*N*") And (val_ColE LIKE "*Inventory Total Gross*") Then
                WS_Doublon.Rows(cstr(pcs_Doublon) & ":" & cstr(pcs_Doublon)).delete shift:=xlup
        End if
    Next pcs_Doublon

Cordialement,
Orodreth

 

[Softmama]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

Bonjour,

la même chose en plus rapide, si tu as de grandes listes :

Sub à_tester()
Dim Z As Range
  Set Z = Range("IV1:IV" & Range("A65000").End(xlup).Row)
  Z.FormulaR1C1 = "=IF(ISERROR(FIND(""N"",RC1)*FIND(""Inventory Total Gross"",RC5)),"""",1"
  Z.Value = Z.Value
  On Error Resume Next
  Z.SpecialCells(xlCellTypeConstants, 1).EntireRow.Delete
  Z.clear
End Sub

à lancer depuis la feuille où sont les données.

 

[Orodreth]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

Re le fil, bonjour Softmama,

A priori, j'ai compris ton code, et si tu dis qu'il est plus rapide que le mien, je te crois sur parole (d'ailleurs, j'ai quelques idées du pourquoi 🙂 )

Juste une question:

z.value = z.value

???? A une valeur, tu affectes la même valeur. Pourquoi ? 😕

Cordialement,

 

[Modeste geedee]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

Bonsour®
cela fige la valeur de la cellule
en remplaçant la formule par le résultat
c'est l'équivalent de faire F9 dans la barre de formule

 

[Pygouv]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

Bonjour,

Merci de ta réponse, je ne suis pas en lumière en VBA j'ai essayé de l'adapter : j'ai mis ligne 7 car mon tableau commence sur cette ligne, j'ai affecté mon bouton à cette macri et rien ne se passe quand je clique dessus...

Une idée?

Code utilisé :

Sub Bouton3_Clic()

Dim WS_Doublon As Worksheet
Set WS_Doublon = Worksheets("QlikView")

Dim fin_Doublon As Long
fin_Doublon = WS_Doublon.Range("A65536").End(xlUp).Row

Dim pcs_Doublon As Long
Dim val_colA As String
Dim val_colE As String

'On parcourt le tableau à l'inverse pour ne pas être géné par la suppression des lignes
For pcs_Doublon = fin_Doublon To 7 Step -1 '(le 1 est à remplacer par ta ligne de début)
val_colA = WS_Doublon.Cells(pcs_Doublon, 1).Value
val_colE = WS_Doublon.Cells(pcs_Doublon, 5).Value

'On teste les conditions
'On vérifie si le texte de la cellule en A CONTIENT "N", et si le texte de la cellule en E CONTIENT "Inventory Total Gross"
'/!\ Le texte testé peut être plus grand que le critère de recherche
If (val_colA Like "*N*") And (val_colE Like "*13 -- Total Gross inventory (k€)*") Then
WS_Doublon.Rows(CStr(pcs_Doublon) & ":" & CStr(pcs_Doublon)).Delete shift:=xlUp
End If
Next pcs_Doublon
End Sub

 

[Orodreth]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

Ah ouais ... suis con, la ligne du dessus affecte une formula ...

Désolé, je suis fatigué, merci pour l'explication 🙂

Pygouv, plus qu'à faire ton choix 🙂

 

[Pygouv]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

Je vais essayer ton code Modeste geedee merci aussi pour ta réponse!

 

[Pygouv]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

C'est à dire affecte une formula? Peux tu m'expliquer brièvement?

 

[Softmama]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

re le fil,

@Orodreth, modeste t'a donné la réponse bien vite 😛
@Pygouv, sans ton fichier , c'est pas évident de te répondre.
Une piste peut-être : *13 -- Total Gross inventory (k€)* qui remplace *Inventory Total Gross*, c'est voulu ? Attention, l'opérateur LIKE est sensible à la casse.

 

[Pygouv]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

Oui softmama, c'est voulu je l'ai écris très vite tout à l'heure 🙂, c'est ce qui apparaît dans la colonne "E".

J'ai essayé avec le nouveau code et le soucis se situe à Z.FormulaR1C1 d'après le débogueur...

Sub à_tester()
Dim Z As Range
Set Z = Range("IV1:IV" & Range("A65000").End(xlUp).Row)
Z.FormulaR1C1 = "=IF(ISERROR(FIND(""N"",RC1)*FIND(""13 - INVENTORY -- Total Gross inventory (k€)"",RC5)),"""",1"
Z.Value = Z.Value
On Error Resume Next
Z.SpecialCells(xlCellTypeConstants, 1).EntireRow.Delete
Z.Clear
End Sub

 

[Pygouv]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

Je vais réessayer avec la formule de Orodreth, j'ai oublié INVENTORY

 

[Softmama]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

Ben, tu as essayé comme ceci ?

Sub à_tester()
Dim Z As Range
Set Z = Range("IV1:IV" & Range("A65000").End(xlUp).Row)
Z.FormulaR1C1 = "=IF(ISERROR(FIND(""N"",RC1)*FIND(""13 - INVENTORY -- Total Gross inventory (k€)"",RC5)),"""",1)"
Z.Value = Z.Value
On Error Resume Next
Z.SpecialCells(xlCellTypeConstants, 1).EntireRow.Delete
Z.Clear
End Sub

En fermant la parenthèse à la fin de la formule juste ?
Z.FormulaR1C1 = "=IF(ISERROR(FIND(""N"",RC1)*FIND(""13 - INVENTORY -- Total Gross inventory (k€)"",RC5)),"""",1)"

 

[Pygouv]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

C'est bon cela fonctionne avec le code d'Orodreth merci à tous 🙂

J'ai une autre question si je peux abuser de votre générosité et de votre savoir 🙂

J'aimerai copier des cellules de mon onglet "DB" vers mon "onglet 2" après avoir fait cette suppression en utilisant le même bouton. Mais je ne veux pas les copier dans le même ordre...

Pour le moment j'ai en intitulé de colonnes: Designation/Area/Plant/KPI designation/2010/Jan/Fev/Mar/May/Jun etc... jusqu'en 2013 avec en dessous de chaque moi la valeur qui correspond...

J'aimerai que ces données apparaissent avec une valeur pour chaque ligne dans mon deuxième onglet sous forme :
Area/Plant/KPI designation/ Year/ Month/Valeur du mois...

J'ai créé un fichier sans donnés confidentielles si vous le voulez en PJ!
ne me faites pas le code pour tout ca risque d'être long juste le début après j'essaierai de l'appliquer moi même!

Merci beaucoup 🙂

 

[Pygouv]

Re : Code VBA dur pour moi, mais surement simple pour vous 🙂

@ Softmama : Oui j'ai essayé de cette façon aussi mais c'est bon celle d'orodreth fonctionne, je vous remercie 🙂