XL 2013 changer de couleur au clic

[maval]

Bonjour6
J'ai un code pour changer de couleur sur un clic sur les cellules C6;D6 en cliquant sur les cellules H6:V60
Mais je n'arrive pas a le configurer
Voila mon code

'Couleur de cellule au clic de la colonne F

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Static LignePrécedente
    If Target.Column < 11 Or Target.Column > 25 Or Target.Count > 1 Or Target.Row < 4 Or Target.Row > 50 Then
        Exit Sub     ' 11 = 11éme colonne "K"  25 25éme colonne "Y"                 4= 4éme ligne 50= 50éme ligne
    End If
    If LignePrécedente <> "" Then
        If Cells(LignePrécedente, 6).Interior.ColorIndex = 3 Then '3 = couleur rouge au niveau du clic et 6 = a la colonne F
            Cells(LignePrécedente, 6).Interior.ColorIndex = 1 '1 =  Fond noir de la cellule et 6 = a la colonne F
        End If
    End If
    LignePrécedente = Target.Row
        Cells(Target.Row, 6).Interior.ColorIndex = 3 '3 = couleur rouge au niveau du clic et 6 = a la colonne F
End Sub

 

[riton00]

Bonsoir,

Mettre ton code dans la feuille même

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

et pas dans un module

Slts

 

[maval]

Bonsoir Peut etre j'ai oublier de le copier mais il y es

 

[patricktoulon]

Bonjour
c'est simple
dans le module de ta feuille tu met ceci
ici la cellule sélectionnée devient rouge et a la selection suivante celle qui a été précédemment sélectionnée reprend sa couleur initiale
on ne sort pas de K5:Y50
si tu sors de la plage , la cellule précédemment sélectionnée repend sa couleur mais il n'y a pas de nouvelle rouge

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Static Cellprevious As Range
    Static colorprevious
    If Target.Count > 1 Then Exit Sub
    If Not Cellprevious Is Nothing Then Cellprevious.Interior.Color = colorprevious
    If Not Intersect(Target, [K5:Y50]) Is Nothing Then
        colorprevious = Target.Interior.Color
        Target.Interior.ColorIndex = 3
        Set Cellprevious = Target
    End If
End Sub

 

[maval]

Bonjour Patrick Et merci beaucoup

J'ai du du mal m"exprimer et je m'excuse
Ce que je cherche a faire c'est sélectionné une cellule entre H6: V60 et que cellule sur la même ligne
ex.. je clic dans la cellule (L11) les cellules (C&D11) deviennent rouge
ou je clic dans la cellule ( R38) les cellules (C &D 38) deviennent rouge.
ici la cellule sélectionnée devient rouge et a la sélection suivante celle qui a été précédemment sélectionnée reprend sa couleur initiale
on ne sort pas de H6 V60
Je te remercie et excuse moi
Max

 

[patricktoulon]

re
et bien meme principe on prend les memes et on recommence
l'avantage avec celle méthode c'est que tu n'est pas bridé a une couleur
chaque ligne en C;D peut avoir sa couleur elle la retrouvera toujours

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Static Cellprevious As Range: Static colorprevious
    If Target.Count > 1 Then Exit Sub
    If Not Cellprevious Is Nothing Then Cellprevious.Interior.Color = colorprevious: Set Cellprevious = Nothing
    If Not Intersect(Target, [h6:v60]) Is Nothing Then
        colorprevious = [C:D].Rows(Target.Row).Interior.Color
        [C:D].Rows(Target.Row).Interior.ColorIndex = 3
        Set Cellprevious = [C:D].Rows(Target.Row)
    End If
End Sub

 

[maval]

Re
Nickel juste pourquoi lorsqu'il clique les autre cellules de C;D deviennent noir sinon tres bien

 

[patricktoulon]

Re
Nickel juste pourquoi lorsqu'il clique les autre cellules de C;D deviennent noir sinon tres bien

??? je ne sais pas normalement c'est impossible j'ai prevu ca avec
If Not Cellprevious Is Nothing Then Cellprevious.Interior.Color = colorprevious: Set Cellprevious = Nothing

donc en dehors des colonnes H;V ca ne devrait pas colorer une quelconque cellule ,tu dois avoir un autre code qui parasite

 

[maval]

Re
Je suis oblige de prendre les deux colonnes et faire aucune couleur

 

[patricktoulon]

re
comme je te l'ai dit c'est pas mon code qui bug
tu a autre chose dans ton classeur qui vient parasiter mon code
ci joint la demo tu verra que tu n'a pas ce problème

 

[maval]

Ok merci beaucoup nickel

 

[job75]

Bonjour maval, le fil,

Pourquoi aller chercher midi à 14 heures, il suffit de colorer par une MFC créée par cette macro :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
With [C6:D60]
    .FormatConditions.Delete
    If Intersect(ActiveCell, [H6:V60]) Is Nothing Then Exit Sub
    With .Rows(ActiveCell.Row - .Row + 1)
        .FormatConditions.Add xlExpression, Formula1:=1 'crée la MFC
        .FormatConditions(1).Interior.Color = vbRed
    End With
End With
End Sub

A+

 

[patricktoulon]

re
Bonsoir @job75
sincèrement pour une mise en couleur puis suppression de la couleur je vois vraiment pas pourquoi passer par une MFC
surtout que là il ne s'agit pas de valeur mais de selection