Microsoft 365 Changer couleur cellule par simple clic

[good57]

Bonjour le forum,
J'ai déjà parcouru le forum à ce sujet mais je ne trouve que des éléments de réponse à ma problématique ... et je ne suis pas un as de la marco donc je ne suis pas encore parvenu à mes fins.

Dans ce fichier, je souhaite pouvoir modifier la couleur d'UNE cellule par simple clic (ou double-clic si ça n'est pas possible autrement).
Je souhaite appliquer cela uniquement aux lignes 4, 6, 8 et 10.

Au chaque clic, je voudrais que la couleur de la cellule passe de sa couleur d'origine ("aucune" ou gris selon la cellule), à BLEU, puis VERT, puis couleur d'origine.

Merci d'avance pour votre aide !!!

 

[sylvanu]

Bonjour Good57,
Un essai en PJ avec :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    If Not Intersect(Target, Range("B3:BL11")) Is Nothing Then                          ' Si dans le tableau
        If Target.Row = 4 Or Target.Row = 6 Or Target.Row = 8 Or Target.Row = 10 Then   ' Si Col=4,6,8,10
            Couleur = Cells(Target.Row - 1, Target.Column).Interior.Color
            If Target.Interior.Color = Couleur Then                                     ' Si Couleur = blanc ou gris
                Target.Interior.Color = RGB(0, 176, 240)                                ' Mettre en bleau
            ElseIf Target.Interior.Color = RGB(0, 176, 240) Then
                Target.Interior.Color = RGB(146, 208, 80)                               ' Sinon mettre en vert
            ElseIf Target.Interior.Color = RGB(146, 208, 80) Then
                Target.Interior.Color = Couleur                                         ' Sinon mettre en blanc
            End If
        End If
        ' Selection cellule ligne-1 pour pouvoir recliquer sur la même cellule
        Application.EnableEvents = False
        Cells(Target.Row - 1, Target.Column).Select
        Application.EnableEvents = True
    End If
End Sub

A la fin la sélection de la cellule Ligne-1 permet de cliquer plusieurs fois sur une même cellule.
sans cela la cellule serait sélectionnée et il faudrait cliquer ailleurs puis revenir pour que la nouvelle sélection soit de nouveau active.

 

[job75]

Bonjour good57, sylvanu,

Attention Target.Count beugue si l'on sélectionne toutes les cellules de la feuille.

Utilisez Target.CountLarge

A+

 

[good57]

Merci Sylvanu et job57 !!
C'est PAR-FAIT. J'ai juste fait une toute petite modif pour pouvoir saisir du texte dans les cellules colorées.
Encore merci !