Microsoft 365 Calcul TTC Textbox

[eric72]

Bonjour 0 TOUS,
J'ai un userform avec 3 textbox
dans la 1ère je met le Montant H.T
dans la 2ème je met le Taux de T.V.A
dans la 3ème je voudrais avoir le montant T.T.C
C'est apparemment tout simple mais si je saisis 12,58 avec un taux de 20% Le résultat est 14.40 au lieu de 15.09
Il ne tient pas compte du "0.58" il le calcule sur 12 au lieu de 12.58
Auriez-vous une idée?
Merci pour votre aide.
Eric

 

[eric72]

Re,
Je crois avoir trouvé mais je dois tester tous les cas!!!

 

[natorp]

Bjr Eric

Bien vu, reste à voir quand il s'agit d'une TVA avec virgule...

Courage, cordialement, Gérard

 

[patricktoulon]

Bonjour
Sacré Eric72 va
le problème avec val en vba
msgbox val("12,58") ' va donner "12" car val ne supporte que le point
msgbox cdbl("12.58") donnera 12 car cddbl ne supporte que la virgule
conclusion il faut replacer le point par virgule et ce servir de CDbl
et ne faire le calcule uniquement quand il y a au moins un chiffre apres la virgule
donc passer par une variable ICI!!"percent" pour mettre le pourcentage soit à 0 soit a la valeur du textbox11 pour ne pas déclencher l'erreur cdbl(vide)
à cela tu ajoute l'arrondi automatique par VBA qui nous donne dans cet exemple 15,10
et pour info
pour 20% de sup c'est fois 1,2 donc ((20+100)/100)
pour 20% de moins c'est fois 0.8 donc fois ABS(((20-100)/100))

Function calc() As Double
    Dim percent#
    TextBox10 = Replace(TextBox10, ".", ",")
    TextBox11 = Replace(TextBox11, ".", ",")
    percent = IIf(TextBox11 = "", 0, TextBox11)
    If IsNumeric(TextBox10) And IsNumeric(percent) Then 'on teste les deux au cas ou en est a la virgule
        calc = Round(CDbl(TextBox10) * ((CDbl(percent) + 100) / 100), 3)
    End If
End Function
Private Sub TextBox10_AfterUpdate()
    TextBox10.Value = Format(TextBox10.Value, "0.00 €")
End Sub
Private Sub TextBox10_Change()
    TextBox12 = Format(calc, "0.00 €")
End Sub
Private Sub TextBox11_Change()
    TextBox12 = Format(calc, "0.00 €")
End Sub
Private Sub TextBox12_AfterUpdate()
    TextBox12.Value = Format(TextBox12.Value, "0.00 €")
End Sub
Public Sub Textbox10_KeyPress(ByVal keyascii As MSForms.ReturnInteger)
    With TextBox10
        If keyascii = 46 Then keyascii = 44
        If Chr(keyascii) Like "[!0-9|,-]" Then keyascii = 0
        If (Len(.Value) = 0 Or .Value Like "*,*") And Chr(keyascii) = "," Then keyascii = 0
        If Chr(keyascii) = "-" And .Value <> "" Then keyascii = 0
    End With
End Sub

 

[Dranreb]

Bonjour.
Avec une virgule dans le texte il faut utiliser CCur ou CDbl, pas Val.

 

[eric72]

Bonjour Patrick,
Merci encore une fois, ça parait si simple avec toi, que du bonheur!!!
Affaire résolue...
Bonne journée et à bientôt
Eric

 

[patricktoulon]

re
c'est simple par ce que j'ai en tète le comportement des fonctions (val et CDbl) qu'il ne faut pas oublier
comme le dit @Dranreb que je salut au passage tu peux utiliser aussi Ccur (c'est vrai que j'y pense jamais a celui là)

 

[eric72]

Merci a vous deux...
Passez de bonne fêtes de NOEL
Eric

 

[patricktoulon]

re
toi aussi bonne fêtes ( a tous d'ailleurs )

 

[dysorthographie]

Bonjour,
Cdbl prend en compte les paramètres régionaux pour séparateur décimal alors que val considère toujours le point comme séparateur !

Je suggère en conséquant d'utiliser val!

val(replace(TextBox10,",","."))