Calcul prix suivant quantité (prix dégréssif)

[aguirre]

Bonjour,
je souhaite réaliser un document excel permettant à mes clients d'établir eux-même leur devis.
Le prix varie selon la quantité.
Pour 5 à 19 articles le prix est de 47
de 20 à 49 le prix est 37
de 50 à 99 le prix est 35
à partir de 100 le prix est 33



Je pensais établir mon tableau avec des conditions, mais la réponse est soit "vrai" soit "fausse" ce qui me donne que 2 choix.
En D2 j'ai ma quantité, le prix est en E2
J'aimerais donc un truc du genre
E2=SI(D2<20;D2*47)
E2=SI(20<D2<50;D2*37)
...

Merci de m'aiguiller.
Cordialement

 

[Creepy]

Re : Calcul prix suivant quantité (prix dégréssif)

Bonjour à tous,

Allez je te donen une piste, il faut imbriquer les si ...

Ta formule est si(A=1;si vrai;si faux). Donc dans ton cas ...

=SI(D2<20;D2*47;si faux ... ).... Je te laisse chercher ....


😀


Allez je te donne ....



😛



=SI(D2<20;D2*47;SI(20<D2<50;D2*37))

Et ainsi de suite ....

Creepy

 

[tototiti2008]

Re : Calcul prix suivant quantité (prix dégréssif)

Edit : je m'étais trompé de fichier, je reposte le bon

Bonjour à tous,

donc un exemple avec recherchev :

 

[abcd]

Re : Calcul prix suivant quantité (prix dégréssif)

Bonjour,

Formule sans tableau intermédiaire :

A1: la quantité
=RECHERCHEV(A1;{0\"sous le minimum";5\47;20\37;50\35;100\33};2)

abcd

 

[aguirre]

Re : Calcul prix suivant quantité (prix dégréssif)

Merci pour vos réponses.
JE ne comprend pas comment fonctionne "RECHERCHEV3. Dommage ça me semblait intéressant.
En effet si je mets :
=RECHERCHEV(A1;{0\"sous le minimum";5\47;20\37;50\35;100\33};2)
Excel me dit que la formule contient une erreur.

Je me suis donc penché sur les conditions mais sans franc succès. Le résultat est bon pour les valeur inférieures à 5 et supérieures à 100 seulement.
Voici ma formule :
=SI(D2<5;"5 minimum";SI(5<=D2<=20;D2*47;SI(20<D2<50;D2*37;SI(50<=D2<100;D2*35;SI(D2>=100;D2*33)))))

 

[tototiti2008]

Re : Calcul prix suivant quantité (prix dégréssif)

Bonjour à tous,

essaye peut-être :

=RECHERCHEV(A1;{0."sous le minimum";5.47;20.37;50.35;100.33};2)

pour une raison que je n'ai pas encore comprise, sur certains postes le séparateur de colonne doit être un "\" et sur d'autres un ".".

ouvre mon classeur, ça te permettra sans doute de mieux comprendre l'exemple d'abcd

 

[abcd]

Re : Calcul prix suivant quantité (prix dégréssif)

Re,

Je ne savais pas que le \ devait être remplacé, sur certains postes, par le.
Plus que probablement suivant la version d'Excel, peut-être pour une version US ?

Autre approche :
=SI(A<5;"quantité minimum = 5";33+(A1<100)*2+(A1<50)*2+(A1<20)*10)
ou bien :
=CHOISIR(EQUIV(A2;{0;5;20;50;100});"quantité minimum = 5";47;37;35;33)

abcd

 

[aguirre]

Re : Calcul prix suivant quantité (prix dégréssif)

Merci Tototiti2008,
je n'avais pas précisé que j'étais sur mac. Peut-être cela vient-il de là.

Une dernière question. Le résultat obtenu par cette formule doit être multiplié par la quantité.
=RECHERCHEV(A1;{0."sous le minimum";5.47;20.37;50.35;100.33};2)*A1
Mais multiplier du texte (sous le minimum) par une valeur donne #valeur!
Comment éviter cela ?

Merci

 

[tototiti2008]

Re : Calcul prix suivant quantité (prix dégréssif)

sans doute :

=si(esterreur(RECHERCHEV(A1;{0."sous le minimum";5.47;20.37;50.35;100.33};2)*A1);"5 minimum";RECHERCHEV(A1;{0."sous le minimum";5.47;20.37;50.35;100.33};2)*A1)

concernant le "." et le "\", je suis sur PC, Excel 2003 Multilangue et moi je dois mettre des ".".
ce qui est bizarre c'est que d'autres utilisateurs d'Excel 2003 Multilangue semblent utiliser le "\"....
peut-être à cause des paramètres régionaux... pas trés simple à décrypter.

 

[abcd]

Re : Calcul prix suivant quantité (prix dégréssif)

Re,

Un peu court :

=SI(A1<5;"sous le nunimum";RECHERCHEV(A1;{5.47;20.37;50.35;100.33};2)*A1)

abcd

 

[aguirre]

Re : Calcul prix suivant quantité (prix dégréssif)

Merci à vous pour votre réactivité.
Je n'imaginais pas qu'on pouvait faire autant avec excel
Cordialement

Aguire