Calcul période d'un emprunt

C

CHALET53

XLDnaute Barbatruc

• 27 Juillet 2015

• #2

Re : Calcul période d'un emprunt

Bonsoir

comme ceci peut-être

voir en I2:J2

a+

 

Pièces jointes

• Phaum TA constant avec Date.xls

  133.5 KB · Affichages: 22

Vote positif 0 Vote négatif

CBernardT

XLDnaute Barbatruc

• 27 Juillet 2015

• #3

Re : Calcul période d'un emprunt

Bonsoir phaum, CHALET53 et le forum,

Ton questionnement a certainement sa solution dans les simulateurs sous Excel qui y sont présentés :

Simulation de prêts [Calcul de crédit]

A tester...

 

Vote positif 0 Vote négatif

P

phaum

Guest

• 27 Juillet 2015

• #4

Re : Calcul période d'un emprunt

Bonjour CHALET53
Merci beaucoup pour le tableau. En fait, pour te permettre de comprendre, je n'ai pas la colonne A dans mon tableau. Donc il faudrait arriver au resultat final sans recréer toutes les écheances et donc en utilisant autre chose que recherche...
🙂
CBernardT, Merci aussi, je regarde cela tout de suite

 

Vote positif 0 Vote négatif

P

phaum

Guest

• 27 Juillet 2015

• #5

Re : Calcul période d'un emprunt

CBernardT,
en fait je suis en train de faire un prévisionnel pour mon entreprise, donc je ne peux pas intègrer les outils proposés...

 

Vote positif 0 Vote négatif

O

ODVJ

XLDnaute Impliqué

• 27 Juillet 2015

• #6

Re : Calcul période d'un emprunt

Bonsoir à tous,

si le résultat suivant te convient :
alors utilises cette formule, en A2 :

Code:

=SI(SI($C3<=D$2;ENT(SOMMEPROD(--(MOIS.DECALER($C3;LIGNE($1:$300))<=D$2))/12*$B3)+1;0)>$A3;0;SI($C3<=D$2;ENT(SOMMEPROD(--(MOIS.DECALER($C3;LIGNE($1:$300))<=D$2))/12*$B3)+1;0))

Colonne A : nbre de période de l'emprunt
Colonne B : fréquence des échéances (donc période en mois = 12/fréquence )
Colonne C : date de départ d'amortissement, à comparer avec les dates de la
Ligne 2 : date d'arrêté. Date à partir de laquelle on calcule le n° d'échéance.

cordialement

 

Vote positif 0 Vote négatif

P

phaum

Guest

• 28 Juillet 2015

• #7

Re : Calcul période d'un emprunt

Bonjour,
Pour vous aider, je fournis le fichier joint Merci pour votre aide. Merci ODVJ mais je ne suis pas sur que cela soit la réponse à mon problème

 

Pièces jointes

• TestEmprunt.xlsx

  21.5 KB · Affichages: 33

Vote positif 0 Vote négatif

O

ODVJ

XLDnaute Impliqué

• 28 Juillet 2015

• #8

Re : Calcul période d'un emprunt

Bonjour,

j'ai pourtant l'impression que si.
met la formule suivante en I10 et recopie vers la droite. Ça devrait le faire.

Code:

=SI(SI($E$14<=I$7;ENT(SOMMEPROD(--(MOIS.DECALER($E$14;LIGNE($1:$300))<=I$7))/12*$E$18)+1;0)>$E$17*$E$18;0;SI($E$14<=I$7;ENT(SOMMEPROD(--(MOIS.DECALER($E$14;LIGNE($1:$300))<=I$7))/12*$E$18)+1;0))

cordialement

 

Vote positif 0 Vote négatif

P

phaum

Guest

• 28 Juillet 2015

• #9

Re : Calcul période d'un emprunt

bonjour,
Tu as raison, désolé ...ca Marche.

Par contre pourrais tu m'expliquer la formule ? J'aime bien comprendre ce que je fais 🙂
Merci en tout cas

 

Vote positif 0 Vote négatif

V

VIARD

XLDnaute Impliqué

• 28 Juillet 2015

• #10

Re : Calcul période d'un emprunt

Bonjour à tous

Je viens de voir votre sujet.
Il se trouve que j'ai déterré un ancien programme que j'ai adapté à mes besoins
(Merci à celui qui l'a créée je ne connais pas son nom)
en lui apportant ma touche personnel et imprimable.

A+ Jean-Paul

 

Pièces jointes

• Emprunt_Simu.xls

  137.5 KB · Affichages: 33

Vote positif 0 Vote négatif

P

phaum

Guest

• 30 Juillet 2015

• #11

Re : Calcul période d'un emprunt

Hello,
Merci beaucoup ODJV et Jean-Paul...

Pourriez vous me dire ce que veut dire -- après le sommeprod ?
Merci

 

Vote positif 0 Vote négatif

O

ODVJ

XLDnaute Impliqué

• 30 Juillet 2015

• #12

Re : Calcul période d'un emprunt

Bonjour,

Le -- dans un sommeprod permet de basculer des valeurs booléennes en valeurs numériques un peu comme si on faisait un *1.
Ici d'ailleurs ça n'est pas nécessaire. Ça fonctionne très bien sans.

Je le mets toujours par tranquillité d'esprit sans vérifier sa nécessité.

Tu t'en sors avec la formule?

Quelques explications :

LIGNE($1:$300) : génère une séquence de 1 à 300 en colonne. Pour tester, tu sélectionnes B10:C320 (dans une feuille quelconque) et tu saisis =LIGNE($1:$300) validé par CTRL+MAJ+ENTER et tu obtiens ta séquence de B10 à B309 puis des #N/A de B310 à B320 et l'identique pour C10:C320.
Si tu vérifies : LIGNES(LIGNE($1:$300)) vaut 300 et COLONNES(LIGNE($1:$300)) vaut 1

MOIS.DECALER($E$14,LIGNE($1:$300)) : génère une série chronologique mensuelle de 300 dates (toujours 300 lignes une colonne) à partir de $E$14 (en absolu car cette réf. est fixe) qui contient la date de départ d'amortissement du crédit.

MOIS.DECALER($G$5,LIGNE(1:300))<=I$7 : génère un vecteur booléen (toujours 300 x 1) qui affiche VRAI si la série chronologique est inf ou égale à la date d'appréciation du nbre de périodes (I$7, en absolu ligne car cette réf. est fixe par rapport à la ligne 7 et relative en terme de colonne vu qu'on veut qu'une recopie vers la droite prenne en compte les dates d'à côté) et FAUX dans le cas contraire.

SOMMEPROD((MOIS.DECALER($E$14,LIGNE($1:$300))<=I$7)) : là, ça te fait la somme des VRAI/FAUX et tu obtiens le nombre de mois entre $E$14 et I$7.

ENT(SOMMEPROD((MOIS.DECALER($E$14,LIGNE($1:$300))<=I$7))/12*$E$18)+1 : tu divises le nombre de mois par la période (12/$E$18) liée à la fréquence ($E$18) de remboursement et le ENT te permet d'obtenir le nbre de périodes entières entre tes 2 dates.
Le +1 est là pour démarrer à partir de 1 au lieu du 0 que ENT fournit.

A : SI($E$14<=I$7,ENT(SOMMEPROD((MOIS.DECALER($E$14,LIGNE($1:$300))<=I$7))/12*$E$18)+1,0) : juste au cas où... si la date d'appréciation est inférieure à celle de départ d'amortissement alors 0 sinon le calcul précédent.

SI(A>$E$17*$E$18,0,A) : $E$17*$E$18 est le nombre de périodes du crédit. Si on le dépasse alors 0 sinon on garde A.


cdlt

 

Vote positif 0 Vote négatif

P

phaum

Guest

• 30 Juillet 2015

• #13

Re : Calcul période d'un emprunt

Salut
Merci pour l'explication....
Oui ça fonctionne très bien 🙂

 

Vote positif 0 Vote négatif

ROGER2327

XLDnaute Barbatruc

• 31 Juillet 2015

• #14

Re : Calcul période d'un emprunt

Bonsoir à tous.

Autres propositions :​

• Code:

  =SI($F$14>I7;ENT((ANNEE(I7)-ANNEE($E$14)+(MOIS(I7)-MOIS($E$14))/12)*$E$18)+1;0)

  ou même, si les dates en ligne 7 sont toujours des dates de fin de mois et les dates en E14:F14 des dates de début de mois :
• Code:

  =SI($F$14>I7;ENT((I$7-$E14-15)*$E$18/365,2425)+1;0)

Bonne nuit.


ℝOGER2327
#7980

Mardi 17 Tatane 142 (Sainte Flamberge, voyante - fête Suprême Quarte)
12 Thermidor An CCXXIII, 9,7526h - salicot
2015-W31-4T23:24:23Z

 

Dernière édition: 31 Juillet 2015

Vote positif 0 Vote négatif